Menu Close

Números poligonales y sus propiedades en Haskell

Un número poligonal es aquel que puede ser representado como puntos dispuestos en forma de polígono regular, empezando por el 1. Los primeros números poligonales son los números triangulares, estos se forman a partir de triángulos.
triangulares
Los siguientes son los números cuadrangulares
cuadrados
Los siguientes son los números pentagonales
pentagonales

Los números triangulares son 1, 3, 6, 10, 15, 21, … Sus diferencias son 2, 3, 4, 5, 6, … Por tanto, se obtienen como sigue

1 = 1
3 = 1+2
6 = 1+2+3
10 = 1+2+3+4
15 = 1+2+3+4+5
21 = 1+2+3+4+5+6

Los números cuadrangulares son 1, 4, 9, 16, 25, 36, 49, … Sus diferencias son 3, 5, 7, 9, … Por tanto, se obtienen como sigue

1 = 1
4 = 1+3
9 = 1+3+5
16 = 1+3+5+7
25 = 1+3+5+7+9
36 = 1+3+5+7+9+11
49 = 1+3+5+7+9+11+13

Los números pentagonales son 1, 5, 12, 22, 35, … Sus diferencias son 4, 7, 10, 13, … Por tanto, se obtienen como sigue

1 = 1
5 = 1+4
12 = 1+4+7
22 = 1+4+7+10
35 = 1+4+7+10+13

Siguiendo el mismo patrón, las diferencias entre los números hexagonales son 5, 9, 13, 17, … Por tanto, los primeros números hexagonales son

1 = 1
6 = 1+5
15 = 1+5+9
28 = 1+5+9+13
45 = 1+5+9+13+17

Continuando con este patrón se obtienen los número poligonales con k lados. Los siguientes son

k=7 Heptagonal: 1, 7, 18, 34, 55, 81, 112, 148, 189, 235, …
k=8 Octagonal: 1, 8, 21, 40, 65, 96, 133, 176, 225, 280, …
k=9 Nonagonal: 1, 9, 24, 46, 75, 111, 154, 204, 261, 325, …

En la siguiente relación de ejercicios (elaborada para I1M) se muestran distintas definiciones de los números poligonales y algunas de sus propiedades, como el teorema de Fermat, en Haskell.

-- ---------------------------------------------------------------------
-- § Librerías auxiliares                                             --
-- ---------------------------------------------------------------------
 
import Test.QuickCheck
 
-- ---------------------------------------------------------------------
-- Ejercicio 1. Definir, por recursión, la función 
--    poligonalR :: Integer -> Integer -> Integer
-- tal que (poligonalR k n) es el n-ésimo número poligonal con k
-- lados. Por ejemplo,
--    [poligonalR 3 n | n <- [1..5]]  ==  [1,3,6,10,15]
--    [poligonalR 4 n | n <- [1..5]]  ==  [1,4,9,16,25]
--    [poligonalR 5 n | n <- [1..5]]  ==  [1,5,12,22,35]
--    [poligonalR 6 n | n <- [1..5]]  ==  [1,6,15,28,45]
-- ---------------------------------------------------------------------
 
poligonalR :: Integer -> Integer -> Integer
poligonalR _ 1 = 1
poligonalR k n = (1+(k-2)*(n-1)) + poligonalR k (n-1)
 
-- ---------------------------------------------------------------------
-- Ejercicio 2. Definir, por recursión, la función 
--    poligonalC :: Integer -> Integer -> Integer
-- tal que (poligonalC k n) es el n-ésimo número poligonal con k
-- lados. Por ejemplo,
--    [poligonalC 3 n | n <- [1..5]]  ==  [1,3,6,10,15]
--    [poligonalC 4 n | n <- [1..5]]  ==  [1,4,9,16,25]
--    [poligonalC 5 n | n <- [1..5]]  ==  [1,5,12,22,35]
--    [poligonalC 6 n | n <- [1..5]]  ==  [1,6,15,28,45]
-- ---------------------------------------------------------------------
 
poligonalC :: Integer -> Integer -> Integer
poligonalC k n =
    sum [1+(k-2)*(m-1) | m <- [1..n]]
 
-- ---------------------------------------------------------------------
-- Ejercicio 3. A partir de la sucesión de los 5 primeros números
-- poligonales, para k entre 3 y 9, conjeturar una fórmula para calcular
-- el n-ésimo número poligonal con k lados.
-- ---------------------------------------------------------------------
 
-- Usando Wolfram Alpha se obtienen las siguientes fórmulas
--    k=3   a(n) = n*(n+1)/2       http://wolfr.am/1b3qmaE
--    k=4   a(n) = n^2             http://wolfr.am/1fvqPlX
--    k=5   a(n) = n*(3*n-1)/2     http://wolfr.am/1llp3uF
--    k=6   a(n) = 2*n^2-n         http://wolfr.am/1k5nYTD
--    k=7   a(n) = (5*n^2-3*n)/2   http://wolfr.am/1aGSjrl
--    k=8   a(n) = 3*n^2-2*n       http://wolfr.am/1llppRM
--    k=9   a(n) = (7*n^2-5*n)/2   http://wolfr.am/1k5oT6w
-- En general,
--          a(n) = ((k-2)*n^2-(k-4)*n)/2 
 
-- ---------------------------------------------------------------------
-- Ejercicio 4. Comprobar con QuickCheck la fórmula para calcular el
-- n-ésimo número poligonal con k lados conjeturada en el ejercicio
-- anterior. 
-- ---------------------------------------------------------------------
 
-- La conjetura es
prop_poligonal :: Integer -> Integer -> Property
prop_poligonal k n =
    k > 0 && n > 0 ==> poligonalR k n == ((k-2)*n^2-(k-4)*n) `div` 2
 
-- La comprobación es
--    ghci> quickCheck prop_poligonal
--    +++ OK, passed 100 tests.
 
-- ---------------------------------------------------------------------
-- Ejercicio 25. Definir, con la fórmula de ejercicio anterior, la
-- función  
--    poligonal :: Integer -> Integer -> Integer
-- tal que (poligonal k n) es el n-ésimo número poligonal con k
-- lados. Por ejemplo,
--    [poligonal 3 n | n <- [1..5]]  ==  [1,3,6,10,15]
--    [poligonal 4 n | n <- [1..5]]  ==  [1,4,9,16,25]
--    [poligonal 5 n | n <- [1..5]]  ==  [1,5,12,22,35]
--    [poligonal 6 n | n <- [1..5]]  ==  [1,6,15,28,45]
-- ---------------------------------------------------------------------
 
poligonal :: Integer -> Integer -> Integer
poligonal k n = ((k-2)*n^2-(k-4)*n) `div` 2
 
-- ---------------------------------------------------------------------
-- Ejercicio 6. Comprobar con QuickCheck que las tres definiciones de
-- poligonal son equivalentes.
-- ---------------------------------------------------------------------
 
-- La propiedad es
prop_equivalencia_poligonal :: Integer -> Integer -> Property
prop_equivalencia_poligonal k n =
    k > 0 && n > 0 ==> poligonalR k n == x &&
                       poligonalC k n == x 
    where x = poligonal k n
 
-- La comprobación es
--    ghci> quickCheck prop_equivalencia_poligonal
--    +++ OK, passed 100 tests.
 
-- ---------------------------------------------------------------------
-- Ejercicio 7. Comparar el tiempo y espacio utilizado en los
-- siguientes cálculos
--    poligonalR 3 100000
--    poligonalC 3 100000
--    poligonal  3 100000
-- ---------------------------------------------------------------------
 
-- El cálculo es
--    ghci> :set +s
--    ghci> poligonalR 3 100000
--    5000050000
--    (0.32 secs, 30522312 bytes)
--    ghci> poligonalC 3 100000
--    5000050000
--    (0.30 secs, 28852176 bytes)
--    ghci> poligonal 3 100000
--    5000050000
--    (0.00 secs, 519272 bytes)
--    ghci> :unset +s
 
-- ---------------------------------------------------------------------
-- § La sucesión de números poligonales                               --
-- ---------------------------------------------------------------------
 
-- ---------------------------------------------------------------------
-- Ejercicio 8. Definir, usando triangular, la función
--    poligonales1 :: Integer -> [Integer]
-- tal que (poligonales1 k) es la lista de los números poligonales de k
-- lados. Por ejemplo,  
--    take 10 (poligonales1 3)  ==  [1,3,6,10,15,21,28,36,45,55]
--    take 10 (poligonales1 4)  ==  [1,4,9,16,25,36,49,64,81,100]
--    take 10 (poligonales1 5)  ==  [1,5,12,22,35,51,70,92,117,145]
-- ---------------------------------------------------------------------
 
poligonales1 :: Integer -> [Integer]
poligonales1 k = [poligonal k n | n <- [1..]]
 
-- ---------------------------------------------------------------------
-- Ejercicio 9. Definir, usando poligonales1, la función
--   diferencias1 :: Integer -> [Integer]
-- tal que (diferencias1 k) es la lista de las diferencias entre el
-- n-ésimo número poligonal y su anterior, para n > 1. Por ejemplo,
--    take 5 (diferencias1 3)  ==  [2,3,4,5,6]
--    take 5 (diferencias1 4)  ==  [3,5,7,9,11]
--    take 5 (diferencias1 5)  ==  [4,7,10,13,16]
-- ---------------------------------------------------------------------
 
diferencias1 :: Integer -> [Integer]
diferencias1 k = zipWith (-) (tail xs) xs
    where xs = poligonales1 k
 
-- ---------------------------------------------------------------------
-- Ejercicio 10. Definir, por comprensión, la función
--   diferencias :: Integer -> [Integer]
-- tal que (diferencias k) es la lista de las diferencias entre el
-- n-ésimo número poligonal y su anterior, para n > 1. Por ejemplo,
--    take 5 (diferencias 3)  ==  [2,3,4,5,6]
--    take 5 (diferencias 4)  ==  [3,5,7,9,11]
--    take 5 (diferencias 5)  ==  [4,7,10,13,16]
-- ---------------------------------------------------------------------
 
diferencias :: Integer -> [Integer]
diferencias k = [k-1,2*k-3..]
 
-- ---------------------------------------------------------------------
-- Ejercicio 11. Definir, por recursión, la función
--    poligonales2 :: Integer -> [Integer]
-- tal que (poligonales2 k) es la lista de los números poligonales de k
-- lados. Por ejemplo, 
--    take 10 (poligonales2 3)  ==  [1,3,6,10,15,21,28,36,45,55]
--    take 10 (poligonales2 4)  ==  [1,4,9,16,25,36,49,64,81,100]
--    take 10 (poligonales2 5)  ==  [1,5,12,22,35,51,70,92,117,145]
-- ---------------------------------------------------------------------
 
poligonales2 :: Integer -> [Integer]
poligonales2 k = 1 : zipWith (+) (diferencias k) (poligonales2 k)
 
-- ---------------------------------------------------------------------
-- Ejercicio 12. Definir, usando scanl, la función
--    poligonales3 :: Integer -> [Integer]
-- tal que (poligonales3 k) es la lista de los números poligonales de k
-- lados. Por ejemplo, 
--    take 10 (poligonales3 3)  ==  [1,3,6,10,15,21,28,36,45,55]
--    take 10 (poligonales3 4)  ==  [1,4,9,16,25,36,49,64,81,100]
--    take 10 (poligonales3 5)  ==  [1,5,12,22,35,51,70,92,117,145]
-- ---------------------------------------------------------------------
 
poligonales3 :: Integer -> [Integer]
poligonales3 k = scanl (+) 1 (diferencias k)
 
-- ---------------------------------------------------------------------
-- Ejercicio 13. Definir la función
--    prop_equivalentes_poligonales :: Integer -> Int -> Bool
-- tal que (prop_equivalentes_poligonales k n) se verifica si las tres
-- definiciones de poligonales de k lados coinciden para todos los
-- números entre 1 y n. 
--
-- Comprobar si coinciden para los números entre 1 y 1000 y k entre 3 y
-- 5. 
-- ---------------------------------------------------------------------
 
prop_equivalentes_poligonales :: Integer -> Int -> Bool
prop_equivalentes_poligonales k n =
    take n (poligonales2 k) == xs && 
    take n (poligonales3 k) == xs
    where xs = take n (poligonales1 k)
 
-- La comprobación  es
--    ghci> prop_equivalentes_poligonales 1000
--    True
 
-- ---------------------------------------------------------------------
-- § Relación entre números poligonales y triangulares                --
-- ---------------------------------------------------------------------
 
-- ---------------------------------------------------------------------
-- Nota 1. En lo que sigue usaremos la siguiente notación
--    P(k,n) es el n-ésimo número poligonal de k lados
--    T(n)   es el n-ésimo número triangular.
-- ---------------------------------------------------------------------
 
-- ---------------------------------------------------------------------
-- Ejercicio 14. Definir la función
--    triangular :: Integer -> Integer
-- tal que (triangular n) es el n-ésimo número triangular. Por ejemplo, 
--    [triangular n | n <- [1..5]]  ==  [1,3,6,10,15]
-- ---------------------------------------------------------------------
 
triangular :: Integer -> Integer
triangular = poligonal 3
 
-- ---------------------------------------------------------------------
-- Ejercicio 15. Comprobar con QuickCheck que
--    P(k,n) = n + (k-2)T(n-1)
-- ---------------------------------------------------------------------
 
-- La propiedad es
prop_poligonal_triangular1 :: Integer -> Integer -> Property
prop_poligonal_triangular1 k n =
    k > 0 && n > 0 ==>
    poligonal k n == n + (k-2) * triangular (n-1)
 
-- La comprobación es
--    ghci> quickCheck prop_poligonal_triangular1
--    +++ OK, passed 100 tests.
 
-- ---------------------------------------------------------------------
-- Ejercicio 16. Comprobar con QuickCheck que
--    P(k+1,n) - P(k,n) = T(n-1)
-- ---------------------------------------------------------------------
 
-- La propiedad es
prop_poligonal_triangular2 :: Integer -> Integer -> Property
prop_poligonal_triangular2 k n =
    k > 0 && n > 0 ==>
    poligonal (k+1) n - poligonal k n == triangular (n-1)
 
-- La comprobación es
--    ghci> quickCheck prop_poligonal_triangular2
--    +++ OK, passed 100 tests.
 
-- ---------------------------------------------------------------------
-- § Combinaciones de números poligonales                             --
-- ---------------------------------------------------------------------
 
-- ---------------------------------------------------------------------
-- Ejercicio 17. Definir la función
--    interseccion :: Ord a => [a] -> [a] -> [a]
-- tal que (interseccion xs ys) es la intersección de las dos listas,
-- posiblemente infinitas, ordenadas de menor a mayor xs e ys. Por ejemplo,
--    take 5 (interseccion [2,4..] [3,6..])  ==  [6,12,18,24,30]
-- ---------------------------------------------------------------------
 
interseccion :: Ord a => [a] -> [a] -> [a]
interseccion [] _ = []
interseccion _ [] = []
interseccion (x:xs) (y:ys)
    | x == y    = x : interseccion xs ys
    | x < y     = interseccion (dropWhile (<y) xs) (y:ys)
    | otherwise = interseccion (x:xs) (dropWhile (<x) ys)
 
-- ---------------------------------------------------------------------
-- Ejercicio 18. Definir la función
--    poligonalesDobles :: Integer -> Integer -> [Integer]
-- tal que (poligonalesDobles s t) es la lista de los números
-- poligonales de s lados que también son poligonales de t lados. Por
-- ejemplo, 
--    take 4 (poligonalesDobles 3 4)  ==  [1,36,1225,41616]
--    take 4 (poligonalesDobles 3 5)  ==  [1,210,40755,7906276]
--    take 4 (poligonalesDobles 3 6)  ==  [1,6,15,28]
--    take 4 (poligonalesDobles 4 5)  ==  [1,9801,94109401,903638458801]
--    take 4 (poligonalesDobles 4 6)  ==  [1,1225,1413721,1631432881]
-- ---------------------------------------------------------------------
 
poligonalesDobles :: Integer -> Integer -> [Integer]
poligonalesDobles s t =
    interseccion (poligonales3 s) (poligonales3 t)
 
-- ---------------------------------------------------------------------
-- § Teorema de Fermat de números poligonales                         --
-- ---------------------------------------------------------------------
 
-- ---------------------------------------------------------------------
-- Ejercicio 19. Definir la función 
--    sumas :: [Integer] -> Integer -> Integer -> [[Integer]]
-- tal que (sumas xs m n) es la lista de las de listas crecientes de,
-- como máximo, m elementos de la lista ordenada creciente xs cuya suma
-- es n. Por ejemplo, 
--    ghci> sumas [1..9] 2 7
--    [[1,6],[2,5],[3,4],[7]]
--    ghci> sumas [1..9] 3 7
--    [[1,1,5],[1,2,4],[1,3,3],[1,6],[2,2,3],[2,5],[3,4],[7]]
-- ---------------------------------------------------------------------
 
sumas :: [Integer] -> Integer -> Integer -> [[Integer]]
sumas _  _ 0 = [[]]
sumas [] _ _ = []
sumas _  0 _ = []
sumas (x:xs) m n
    | x > n     = []
    | otherwise = [x:ys | ys <- sumas (x:xs) (m-1) (n-x)] ++ 
                  sumas xs m n
 
-- ---------------------------------------------------------------------
-- Ejercicio 20. Definir la función
--    descomposicionesPoligonales :: Integer -> Integer -> Integer -> [[Integer]]
-- tal que (descomposicionesPoligonales k m n) es la lista crecientes de,
-- como máximo m números poligonales de k lados, cuya suma es n. Por
-- ejemplo, 
--    descomposicionesPoligonales 4 4 20  ==  [[1,1,9,9],[4,16]]
--    descomposicionesPoligonales 4 2 20  ==  [[4,16]]
-- ---------------------------------------------------------------------
 
descomposicionesPoligonales :: Integer -> Integer -> Integer -> [[Integer]]
descomposicionesPoligonales k m n = 
    sumas (takeWhile (<=n) (poligonales3 k)) m n
 
-- ---------------------------------------------------------------------
-- Ejercicio 21. Definir 
--    gradoPoligonal :: Integer -> Integer -> Integer
-- tal que (gradoPoligonal k n) es el menor cantidad de números
-- poligonales de k lados cuya suma es n. Por ejemplo,
--    gradoPoligonal 3 5  ==  3
--    gradoPoligonal 3 7  ==  2
--    gradoPoligonal 4 5  ==  2
--    gradoPoligonal 4 7  ==  4
-- ---------------------------------------------------------------------
 
gradoPoligonal :: Integer -> Integer -> Integer
gradoPoligonal k n = 
    minimum [m | m <- [1..n], 
                 not (null (descomposicionesPoligonales k m n))]
 
-- ---------------------------------------------------------------------
-- Ejercicio 22. Calcular el número mínimo de sumandos para expresar
-- cualquiera de los 20 primeros números naturales usando números
-- poligonales de 3, 4 ó 5 lados, respectivamente.
-- ---------------------------------------------------------------------
 
-- El cálculo es
--    ghci> [gradoPoligonal 3 n | n <- [1..20]]
--    [1,2,1,2,3,1,2,3,2,1,2,2,2,3,1,2,3,2,3,2]
--    ghci> [gradoPoligonal 4 n | n <- [1..20]]
--    [1,2,3,1,2,3,4,2,1,2,3,3,2,3,4,1,2,2,3,2]
--    ghci> [gradoPoligonal 5 n | n <- [1..20]]
--    [1,2,3,4,1,2,3,4,5,2,3,1,2,3,3,4,2,3,4,4]
 
-- ---------------------------------------------------------------------
-- Ejercicio 23. A la vista del cálculo del ejercicio anterior,
-- conjeturar la menor cota superior del número mínimo de sumandos para
-- expresar cualquiera número natural como suma de números poligonales
-- de k lados y comprobar la conjetura con QuickCheck. 
-- ---------------------------------------------------------------------
 
-- La conjetura es que todos los números naturales se pueden expresar
-- como suma de k, o menos, números poligonales de k lados (no
-- necesariamente distintos). 
 
-- La expresión de la conjetura
prop_gradoPoligonal :: Integer -> Integer -> Property
prop_gradoPoligonal k n =
    n >= 0 && k > 2 ==> not (null (descomposicionesPoligonales k k n))
 
-- La comprobación es
--    ghci> quickCheck prop_gradoPoligonal
--    +++ OK, passed 100 tests.
 
-- ---------------------------------------------------------------------
-- Nota 1. En 1796, el matemático y científico alemán Carl Friedrich
-- Gauss descubrió que todo entero positivo puede representarse como la
-- suma de un máximo de tres números triangulares, hecho que describió
-- en su diario con la misma palabra que usara Arquímedes en su famoso
-- descubrimiento: "¡Eureka! num= Δ + Δ + Δ". Posteriormente, Fermat la
-- generalizó para todos los números poligonales.
-- ---------------------------------------------------------------------

Fuente

Destino
La anterior relación de ejercicios la ha elaborado para

PeH, Sin categoría