Menu Close

I1M2019: El patrón de búsqueda por primero el mejor en Haskell

En la clase de hoy de del curso Informática de 1º del Grado en Matemáticas hemos estudiado la técnica de resolución de problemas mediante búsqueda informada en espacios de estados.

En primer lugar se estudiaron los algoritmos búsqueda con información (coste, heurística y A*). A continuación se estudió cómo adaptar el patrón de búsqueda ciega a búsqueda informada usando las colas de prioridad. Finalmente, se aplicó el patrón de búsqueda por primero el mejor a la resolución del problema del 8 puzzle.

La clase se ha dado mediante videoconferencia los correspondientes vídeos son

  • Algoritmos de búsqueda informada en espacios de estados

  • El patrón de búsqueda por primero el mejor en Haskell

Los apuntes correspondientes a la clase es la sección 3 del tema 23

Una versión interactiva de los apuntes en IHaskell se encuentra aquí.

El código de la primera solución del problema del 8 puzzle usado en la clase es

import I1M.BusquedaPrimeroElMejor
import Data.List
import Data.Matrix 
 
-- Representación del problema:
-- ============================
 
-- Una posición es un par de enteros.
type Posicion = (Int,Int)
 
-- Un tablero es un una matriz 
type Tablero = Matrix Int
 
-- inicial1 e inicial2 son ejemplos de estados iniciales del 8 puzzle. 
--      +---+---+---+      +---+---+---+
--      | 2 | 6 | 3 |      | 2 | 8 | 3 |
--      +---+---+---+      +---+---+---+
--      | 5 |   | 4 |      | 1 | 6 | 4 |
--      +---+---+---+      +---+---+---+
--      | 1 | 7 | 8 |      | 7 |   | 5 |
--      +---+---+---+      +---+---+---+
inicial1, inicial2 :: Tablero 
inicial1 = fromLists [[2,6,3],[5,0,4],[1,7,8]]
inicial2 = fromLists [[2,8,3],[1,6,4],[7,0,5]]
 
-- final es el estado final del 8 puzzle. En el ejemplo es
--      +---+---+---+
--      | 1 | 2 | 3 | 
--      +---+---+---+ 
--      | 8 |   | 4 | 
--      +---+---+---+ 
--      | 7 | 6 | 5 | 
--      +---+---+---+ 
final :: Tablero
final = fromLists [[1,2,3],[8,0,4],[7,6,5]]
 
-- (posicion t x) es la posición de x en el tablero t. Por ejemplo,
--    posicion inicial1 0  ==  (2,2)
--    posicion inicial1 7  ==  (3,2)
posicion :: Tablero -> Int -> Posicion
posicion t x =
  head [(i,j) | i <- [1..3],
                j <- [1..3],
                t ! (i,j) == x]     
 
 
-- (intercambia t p1 p2) es el tablero obtenido intercambiando los
-- elementos que se encuentran en las posiciones p1 y p2. Por ejemplo,
--    λ> inicial1
--    ┌       ┐
--    │ 2 6 3 │
--    │ 5 0 4 │
--    │ 1 7 8 │
--    └       ┘
--    λ> intercambia inicial1 (2,2) (2,3)
--    ┌       ┐
--    │ 2 6 3 │
--    │ 5 4 0 │
--    │ 1 7 8 │
--    └       ┘
intercambia :: Tablero -> Posicion -> Posicion -> Tablero
intercambia t p1 p2 =
  matrix 3 3 f
  where f p | p == p1   = t ! p2
            | p == p2   = t ! p1
            | otherwise = t ! p
 
-- (todosMovimientos t) es la lista de los tableros obtenidos
-- aplicándole al tablero t todos los posibles movimientos; es decir,
-- intercambiando la posición del hueco con sus adyacentes. Por ejemplo, 
--    λ> inicial1
--    ┌       ┐
--    │ 2 6 3 │
--    │ 5 0 4 │
--    │ 1 7 8 │
--    └       ┘
--    λ> mapM_ print (todosMovimientos inicial1)
--    ┌       ┐
--    │ 2 6 3 │
--    │ 0 5 4 │
--    │ 1 7 8 │
--    └       ┘
--    ┌       ┐
--    │ 2 0 3 │
--    │ 5 6 4 │
--    │ 1 7 8 │
--    └       ┘
--    ┌       ┐
--    │ 2 6 3 │
--    │ 5 4 0 │
--    │ 1 7 8 │
--    └       ┘
--    ┌       ┐
--    │ 2 6 3 │
--    │ 5 7 4 │
--    │ 1 0 8 │
--    └       ┘
--    λ> mapM_ print (todosMovimientos (fromLists [[0,6,3],[2,5,4],[1,7,8]]))
--    ┌       ┐
--    │ 6 0 3 │
--    │ 2 5 4 │
--    │ 1 7 8 │
--    └       ┘
--    ┌       ┐
--    │ 2 6 3 │
--    │ 0 5 4 │
--    │ 1 7 8 │
--    └       ┘
todosMovimientos :: Tablero -> [Tablero]
todosMovimientos t =
  [intercambia t (i,j) (i,j-1) | j > 1] ++   -- Izquierda
  [intercambia t (i,j) (i-1,j) | i > 1] ++   -- Arriba
  [intercambia t (i,j) (i,j+1) | j < 3] ++   -- Derecha
  [intercambia t (i,j) (i+1,j) | i < 3]      -- Abajo
  where (i,j) = posicion t 0
 
-- Los nodos del espacio de estados son listas de tableros [t_n,...,t_1]
-- tal que t_i es un sucesor de t_(i-1).
newtype Nodo = Est [Tablero]
  deriving (Show, Eq)
 
-- (sucesores e) es la lista de sucesores del estado e. Por ejemplo,
--    λ> sucesores (Est [inicial1])
--    [Est [┌       ┐ ┌       ┐
--          │ 2 6 3 │ │ 2 6 3 │
--          │ 0 5 4 │ │ 5 0 4 │
--          │ 1 7 8 │ │ 1 7 8 │
--          └       ┘,└       ┘ ],
--     Est [┌       ┐ ┌       ┐ 
--          │ 2 0 3 │ │ 2 6 3 │ 
--          │ 5 6 4 │ │ 5 0 4 │ 
--          │ 1 7 8 │ │ 1 7 8 │ 
--          └       ┘,└       ┘],
--     Est [┌       ┐ ┌       ┐  
--          │ 2 6 3 │ │ 2 6 3 │  
--          │ 5 4 0 │ │ 5 0 4 │  
--          │ 1 7 8 │ │ 1 7 8 │  
--          └       ┘,└       ┘],
--     Est [┌       ┐ ┌       ┐ 
--          │ 2 6 3 │ │ 2 6 3 │ 
--          │ 5 7 4 │ │ 5 0 4 │ 
--          │ 1 0 8 │ │ 1 7 8 │ 
--          └       ┘,└       ┘]]
--    λ> sucesores (head it)
--    [Est [┌       ┐ ┌       ┐ ┌       ┐  
--          │ 0 6 3 │ │ 2 6 3 │ │ 2 6 3 │  
--          │ 2 5 4 │ │ 0 5 4 │ │ 5 0 4 │  
--          │ 1 7 8 │ │ 1 7 8 │ │ 1 7 8 │  
--          └       ┘,└       ┘,└       ┘],
--     Est [┌       ┐ ┌       ┐ ┌       ┐  
--          │ 2 6 3 │ │ 2 6 3 │ │ 2 6 3 │  
--          │ 1 5 4 │ │ 0 5 4 │ │ 5 0 4 │  
--          │ 0 7 8 │ │ 1 7 8 │ │ 1 7 8 │  
--          └       ┘,└       ┘,└       ┘]]
sucesores :: Nodo -> [Nodo]
sucesores (Est (n@(t:ts))) = 
  [Est (t':n) | t' <- todosMovimientos t, 
                t' `notElem` n]
 
-- (esFinal n) se verifica si n es un nodo final.
esFinal :: Nodo -> Bool
esFinal (Est (t:_)) = t == final
 
-- (heuristica t) es la suma de la distancia Manhatan desde la posición de
-- cada objeto del tablero a su posición en el estado final. Por
-- ejemplo,
--    heuristica inicial1  ==  12
--    heuristica inicial2  ==  6
heuristica :: Tablero  -> Int
heuristica t =
  sum [distancia (posicion t x) (posicion final x) | x <- [0..8]]
 
-- (distancia p1 p2) es la distancia Manhatan entre las posiciones p1 y
-- p2. Por ejemplo,
--    distancia (2,7) (4,1)  ==  8
distancia :: Posicion -> Posicion -> Int
distancia (x1,y1) (x2,y2) = abs (x1-x2) + abs (y1-y2)
 
-- Un nodo n1 es menor o igual n2 la heurística del estado actual de n1
-- es menor o igual que la del estado actual de n2. 
instance Ord Nodo where 
  Est (t1:_) <= Est (t2:_) = heuristica t1 <= heuristica t2
 
-- (soluciones i) es la lista de las soluciones del 8 puzzle por búsqueda
-- primero el mejor a partir del estado inicial i. Por ejemplo,
--    λ> mapM_ print (head (soluciones inicial2))
--    ┌       ┐
--    │ 2 8 3 │
--    │ 1 6 4 │
--    │ 7 0 5 │
--    └       ┘
--    ┌       ┐
--    │ 2 8 3 │
--    │ 1 0 4 │
--    │ 7 6 5 │
--    └       ┘
--    ┌       ┐
--    │ 2 0 3 │
--    │ 1 8 4 │
--    │ 7 6 5 │
--    └       ┘
--    ┌       ┐
--    │ 0 2 3 │
--    │ 1 8 4 │
--    │ 7 6 5 │
--    └       ┘
--    ┌       ┐
--    │ 1 2 3 │
--    │ 0 8 4 │
--    │ 7 6 5 │
--    └       ┘
--    ┌       ┐
--    │ 1 2 3 │
--    │ 8 0 4 │
--    │ 7 6 5 │
--    └       ┘
soluciones :: Tablero -> [[Tablero]]
soluciones inicial =
  [reverse ts | (Est ts) <- buscaPM sucesores esFinal (Est [inicial])]
I1M2019