I1M2015: Aplicaciones de la programación funcional con listas infinitas

En clase de hoy de Informática de 1º del Grado en Matemáticas hemos comentando las soluciones de los 8 primeros ejercicios de evaluación de la 14ª relación sobre aplicaciones de la programación funcional con listas infinitas.

Los ejercicios, y sus soluciones, se muestran a continuación.

-- ---------------------------------------------------------------------
-- Introducción                                                       --
-- ---------------------------------------------------------------------

-- En esta relación se estudia distintas aplicaciones de la programación
-- funcional que usan listas infinitas
-- + la sucesión de Hamming,
-- + problemas 10 y 12 del proyecto Euler,
-- + enumeración de los números enteros,
-- + el problema de la bicicleta de Turing,
-- + la sucesión de Golomb,
-- + la codificación por longitud,
-- + la sucesión de Kolakoski y
-- + el triángulo de Floyd.

-- ---------------------------------------------------------------------
-- Importación de librerías                                           --
-- ---------------------------------------------------------------------

import Data.Char 
import Data.List
import Data.Numbers.Primes
import Test.QuickCheck

-- ---------------------------------------------------------------------
-- § Sucesión de Hamming                                              --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 1.1. Definir la función
--    divisoresPrimosEn :: Integer -> [Integer] -> Bool
-- tal que (divisoresPrimosEn x ys) se verifica si x puede expresarse
-- como un producto de potencias de elementos de la lista de números
-- primos ys. Por ejemplo, 
--    divisoresPrimosEn 12 [2,3,5]  ==  True
--    divisoresPrimosEn 14 [2,3,5]  ==  False
-- ---------------------------------------------------------------------

-- 1ª definición (por recursión)
divisoresPrimosEn1 :: Integer -> [Integer] -> Bool
divisoresPrimosEn1 1 _  = True
divisoresPrimosEn1 x [] = False
divisoresPrimosEn1 x (y:ys) 
    | mod x y == 0 = divisoresPrimosEn1 (div x y) (y:ys)
    | otherwise    = divisoresPrimosEn1 x ys   

-- 2ª definición (por comprensión)
divisoresPrimosEn2 :: Integer -> [Integer] -> Bool
divisoresPrimosEn2 x ys = and [elem y ys | y <- primeFactors x] 

-- 3ª definición (por cuantificación)
divisoresPrimosEn :: Integer -> [Integer] -> Bool
divisoresPrimosEn x ys = all (`elem` ys) (primeFactors x) 

-- ---------------------------------------------------------------------
-- Ejercicio 1.2. Los números de Hamming forman una sucesión 
-- estrictamente creciente de números que cumplen las siguientes 
-- condiciones: 
--    1. El número 1 está en la sucesión.
--    2. Si x está en la sucesión, entonces 2x, 3x y 5x también están.
--    3. Ningún otro número está en la sucesión.
-- Definir, usando divisoresPrimosEn, la constante
--    hamming :: [Integer]
-- tal que hamming es la sucesión de Hamming. Por ejemplo,
--    take 12 hamming  ==  [1,2,3,4,5,6,8,9,10,12,15,16]
-- ---------------------------------------------------------------------

hamming :: [Integer]
hamming = [x | x <- [1..], divisoresPrimosEn x [2,3,5]]

-- ---------------------------------------------------------------------
-- Ejercicio 1.3. Definir la función
--    cantidadHammingMenores :: Integer -> Int
-- tal que (cantidadHammingMenores x) es la cantidad de números de
-- Hamming menores que x. Por ejemplo,
--    cantidadHammingMenores 6  ==  5
--    cantidadHammingMenores 7  ==  6
--    cantidadHammingMenores 8  ==  6
-- ---------------------------------------------------------------------

cantidadHammingMenores :: Integer -> Int
cantidadHammingMenores x = length (takeWhile (<x) hamming)

-- ---------------------------------------------------------------------
-- Ejercicio 1.4. Definir la función
--    siguienteHamming :: Integer -> Integer
-- tal que (siguienteHamming x) es el menor número de la sucesión de
-- Hamming mayor que x. Por ejemplo,
--    siguienteHamming 6  ==  8
--    siguienteHamming 21  ==  24
-- ---------------------------------------------------------------------

siguienteHamming :: Integer -> Integer
siguienteHamming x = head (dropWhile (<=x) hamming)

-- ---------------------------------------------------------------------
-- Ejercicio 1.5. Definir la función
--    huecoHamming :: Integer -> [(Integer,Integer)]
-- tal que (huecoHamming n) es la lista de pares de números consecutivos
-- en la sucesión de Hamming cuya distancia es mayor que n. Por ejemplo,  
--    take 4 (huecoHamming 2)   ==  [(12,15),(20,24),(27,30),(32,36)]
--    take 3 (huecoHamming 2)   ==  [(12,15),(20,24),(27,30)]
--    take 2 (huecoHamming 3)   ==  [(20,24),(32,36)]
--    head (huecoHamming 10)    ==  (108,120)
--    head (huecoHamming 1000)  ==  (34992,36000)
-- ---------------------------------------------------------------------

huecoHamming :: Integer -> [(Integer,Integer)]
huecoHamming n = [(x,y) | x <- hamming, 
                          let y = siguienteHamming x,
                          y-x > n]

-- ---------------------------------------------------------------------
-- Ejercicio 1.6. Comprobar con QuickCheck que para todo n, existen
-- pares de números consecutivos en la sucesión de Hamming cuya
-- distancia es mayor que n.
-- ---------------------------------------------------------------------

-- La propiedad es
prop_Hamming :: Integer -> Bool
prop_Hamming n = huecoHamming n' /= []
    where n' = abs n

-- La comprobación es
--    ghci> quickCheck prop_Hamming
--    OK, passed 100 tests.

-- ---------------------------------------------------------------------
-- § Problema 10 del Proyecto Euler                                   --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 2. Definir la función 
--    sumaPrimoMenores :: Integer -> Integer
-- tal que (sumaPrimoMenores n) es la suma de los primos menores que
-- n. Por ejemplo,
--    sumaPrimoMenores 10  ==  17
--    sumaPrimoMenores 7   ==  10                       
-- ---------------------------------------------------------------------

-- 1ª definición (por recursión y la criba de Erastótenes)
-- =======================================================

sumaPrimoMenores1 :: Integer -> Integer
sumaPrimoMenores1 n = sumaMenores n primos 0
   where sumaMenores n (x:xs) a | n <= x    = a
                                | otherwise = sumaMenores n xs (a+x)

-- primos es la lista de los número primos obtenida mediante la criba de 
-- Erastótenes. Por ejemplo,
--    primos  =>  [2,3,5,7,11,13,17,19,23,29,31,37,41,43,47,53,59,...
primos :: [Integer]
primos = criba [2..]
         where criba (p:ps) = p : criba [n | n<-ps, mod n p /= 0]

-- 2ª definición (por comprensión y la criba de Erastótenes)
-- =========================================================

sumaPrimoMenores2 :: Integer -> Integer
sumaPrimoMenores2 n = sum (takeWhile (<n) primos)

-- 3ª definición (por comprensión y la librería de primos)
-- =======================================================

sumaPrimoMenores3 :: Integer -> Integer
sumaPrimoMenores3 n = sum (takeWhile (<n) primes)

-- Comparación de eficiencia 
-- =========================

--    λ> sumaPrimoMenores1 20000
--    21171191
--    (5.11 secs, 922,508,496 bytes)
--    
--    λ> sumaPrimoMenores2 20000
--    21171191
--    (5.05 secs, 898,081,952 bytes)
--    
--    λ> sumaPrimoMenores3 20000
--    21171191
--    (0.02 secs, 0 bytes)

-- ---------------------------------------------------------------------
-- § Problema 12 del Proyecto Euler                                   --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 3.1. Los números triangulares se forman como sigue
--    *     *      * 
--         * *    * *
--               * * *
--    1     3      6
-- 
-- La sucesión de los números triangulares se obtiene sumando los
-- números naturales. Así, los 5 primeros números triangulares son
--     1 = 1
--     3 = 1+2
--     6 = 1+2+3
--    10 = 1+2+3+4
--    15 = 1+2+3+4+5
-- 
-- Definir la función
--    triangulares :: [Integer]
-- tal que triangulares es la lista de los números triangulares. Por
-- ejemplo, 
--    take 10 triangulares     ==  [1,3,6,10,15,21,28,36,45,55]
--    triangulares !! 2000000  ==  2000003000001
-- ---------------------------------------------------------------------

-- 1ª definición
triangulares1 :: [Integer]
triangulares1 = 1 : [x+y | (x,y) <- zip [2..] triangulares]

-- 2ª definición
triangulares2 :: [Integer]
triangulares2 = scanl (+) 1 [2..]

-- 3ª definición (usando la fórmula de la suma de la progresión):
triangulares3 :: [Integer]
triangulares3 = [(n*(n+1)) `div` 2 | n <- [1..]]

-- Comparación de eficiencia
--    λ> triangulares1 !! 1000000
--    500001500001
--    (3.07 secs, 484,321,192 bytes)
--    λ> triangulares2 !! 1000000
--    500001500001
--    (0.04 secs, 0 bytes)
--    λ> triangulares3 !! 1000000
--    500001500001
--    (1.23 secs, 186,249,472 bytes)

-- En lo sucesivo, usaremos como triangulares la segunda definición.
triangulares :: [Integer]
triangulares = triangulares2

-- ---------------------------------------------------------------------
-- Ejercicio 3.2. Definir la función
--    nDivisores :: Integer -> Integer
-- tal que (nDivisores n) es el número de los divisores de n. Por
-- ejemplo, 
--    nDivisores 28                 ==  6
--    nDivisores (product [1..200]) == 139503973313460993785856000000
-- ---------------------------------------------------------------------

-- 1ª definición
-- =============

nDivisores1 :: Integer -> Integer
nDivisores1 = genericLength . divisores 

-- (divisores n) es la lista de los divisores de n. Por ejemplo,
--    divisores 28  ==  [1,2,4,7,14,28]
divisores :: Integer -> [Integer]
divisores x = [y | y <- [1..x], mod x y == 0]

-- 2ª definición (con primeFactors y group)
-- ========================================

nDivisores2 :: Integer -> Integer
nDivisores2 n = 
    product [1 + genericLength xs | xs <- group (primeFactors n)]

-- Comparación de eficiencia
-- =========================

--    λ> nDivisores1 (product [1..10])
--    270
--    (5.18 secs, 763,249,336 bytes)
--    λ> nDivisores2 (product [1..10])
--    270
--    (0.01 secs, 0 bytes)

-- En lo sucesivo usaremos la 2ª definición de nDivisores
nDivisores :: Integer -> Integer
nDivisores = nDivisores2

-- ---------------------------------------------------------------------
-- Ejercicio 3.3. Los divisores de los primeros 7 números triangulares
-- son: 
--     1: 1
--     3: 1,3
--     6: 1,2,3,6
--    10: 1,2,5,10
--    15: 1,3,5,15
--    21: 1,3,7,21
--    28: 1,2,4,7,14,28
-- Como se puede observar, 28 es el menor número triangular con más de 5
-- divisores. 
-- 
-- Definir la función 
--    euler12 :: Int -> Integer
-- tal que (euler12 n) es el menor número triangular con más de n
-- divisores. Por ejemplo,
--    euler12 5    ==  28
--    euler12 500  ==  76576500
-- ---------------------------------------------------------------------

euler12 :: Integer -> Integer
euler12 n = head [x | x <- triangulares, nDivisores x > n]

-- ---------------------------------------------------------------------
-- § Enumeración de los números enteros                               --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 4.1. Los números enteros se pueden ordenar como sigue 
--    0, -1, 1, -2, 2, -3, 3, -4, 4, -5, 5, -6, 6, -7, 7, ...
-- Definir, por comprensión, la constante
--    enteros :: [Int]
-- tal que enteros es la lista de los enteros con la ordenación
-- anterior. Por ejemplo,
--    take 10 enteros  ==  [0,-1,1,-2,2,-3,3,-4,4,-5]
-- ---------------------------------------------------------------------

enteros :: [Int]
enteros = 0 : concat [[-x,x] | x <- [1..]]

-- ---------------------------------------------------------------------
-- Ejercicio 4.2. Definir, por iteración, la constante
--    enteros' :: [Int]
-- tal que enteros' es la lista de los enteros con la ordenación
-- anterior. Por ejemplo,
--    take 10 enteros  ==  [0,-1,1,-2,2,-3,3,-4,4,-5]
-- ---------------------------------------------------------------------

enteros' :: [Int]
enteros' = iterate siguiente 0
    where siguiente x | x >= 0    = -x-1
                      | otherwise = -x

-- ---------------------------------------------------------------------
-- Ejercicio 4.3. Definir, por selección con takeWhile, la función
--    posicion :: Int -> Int
-- tal que (posicion x) es la posición del entero x en la ordenación
-- anterior. Por ejemplo,
--    posicion 2  ==  4
-- ---------------------------------------------------------------------

posicion :: Int -> Int
posicion x = length (takeWhile (/=x) enteros)

-- ---------------------------------------------------------------------
-- Ejercicio 4.4. Definir, por recursión, la función
--    posicionR :: Int -> Int
-- tal que (posicionR x) es la posición del entero x en la ordenación
-- anterior. Por ejemplo,
--    posicionR 2  ==  4
-- ---------------------------------------------------------------------

posicionR :: Int -> Int
posicionR x = aux enteros 0
    where aux (y:ys) n | x == y    = n
                       | otherwise = aux ys (n+1)

-- ---------------------------------------------------------------------
-- Ejercicio 4.5. Definir, por comprensión, la función
--    posicionC :: Int -> Int
-- tal que (posicionC x) es la posición del entero x en la ordenación
-- anterior. Por ejemplo,
--    posicionC 2  ==  4
-- ---------------------------------------------------------------------

posicionC :: Int -> Int
posicionC x = head [n | (n,y) <- zip [0..] enteros, y == x]

-- ---------------------------------------------------------------------
-- Ejercicio 4.6. Definir, sin búsqueda, la función
--    posicion2 :: Int -> Int
-- tal que (posicion2 x) es la posición del entero x en la ordenación
-- anterior. Por ejemplo,
--    posicion2 2  ==  4
-- ---------------------------------------------------------------------

-- Definición directa
posicion2 :: Int -> Int
posicion2 x | x >= 0    = 2*x
            | otherwise = 2*(-x)-1

-- ---------------------------------------------------------------------
-- § El problema de la bicicleta de Turing                            --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 5.1. Cuentan que Alan Turing tenía una bicicleta vieja,
-- que tenía una cadena con un eslabón débil y además uno de los radios
-- de la rueda estaba doblado. Cuando el radio doblado coincidía con el
-- eslabón débil, entonces la cadena se rompía.   
--
-- La bicicleta se identifica por los parámetros (i,d,n) donde 
-- - i es el número del eslabón que coincide con el radio doblado al
--   empezar a andar,
-- - d es el número de eslabones que se desplaza la cadena en cada
--   vuelta de la rueda y  
-- - n es el número de eslabones de la cadena (el número n es el débil).
-- Si i=2 y d=7 y n=25, entonces la lista con el número de eslabón que 
-- toca el radio doblado en cada vuelta es 
--    [2,9,16,23,5,12,19,1,8,15,22,4,11,18,0,7,14,21,3,10,17,24,6,...
-- Con lo que la cadena se rompe en la vuelta número 14.
-- 
-- Definir la función
--    eslabones :: Int -> Int -> Int -> [Int]
-- tal que (eslabones i d n) es la lista con los números de eslabones 
-- que tocan el radio doblado en cada vuelta en una bicicleta de tipo 
-- (i,d,n). Por ejemplo, 
--    take 10 (eslabones 2 7 25)  ==  [2,9,16,23,5,12,19,1,8,15]
-- ---------------------------------------------------------------------

eslabones :: Int -> Int -> Int -> [Int]
eslabones i d n = [(i+d*j) `mod` n | j <- [0..]]

-- 2ª definición (con iterate):
eslabones2 :: Int -> Int -> Int -> [Int]
eslabones2 i d n = map (\x-> mod x n) (iterate (+d) i)

-- ---------------------------------------------------------------------
-- Ejercicio 5.2. Definir la función
--    numeroVueltas :: Int -> Int -> Int -> Int 
-- tal que (numeroVueltas i d n) es el número de vueltas que pasarán 
-- hasta que la cadena se rompa en una bicicleta de tipo (i,d,n). Por 
-- ejemplo,
--    numeroVueltas 2 7 25  ==  14
-- ---------------------------------------------------------------------

numeroVueltas :: Int -> Int -> Int -> Int
numeroVueltas i d n = length (takeWhile (/=0) (eslabones i d n)) 

-- ---------------------------------------------------------------------
-- § La sucesión de Golomb                                            --
-- ---------------------------------------------------------------------

-- ---------------------------------------------------------------------
-- Ejercicio 6.1. [Basado en el problema 341 del proyecto Euler]. La
-- sucesión de Golomb {G(n)} es una sucesión auto descriptiva: es la
-- única sucesión no decreciente de números naturales tal que el número
-- n aparece G(n) veces en la sucesión. Los valores de G(n) para los
-- primeros números son los siguientes:
--    n       1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 ...
--    G(n)    1 2 2 3 3 4 4 4 5  5  5  6  6  6  6 ...
-- En los apartados de este ejercicio se definirá una función para
-- calcular los términos de la sucesión de Golomb. 
-- 
-- Definir la función
--    golomb :: Int -> Int
-- tal que (golomb n) es el n-ésimo término de la sucesión de Golomb. 
-- Por ejemplo,
--    golomb 5  ==  3
--    golomb 9  ==  5
-- Indicación: Se puede usar la función sucGolomb del apartado 2.
-- ---------------------------------------------------------------------

golomb :: Int -> Int
golomb n = sucGolomb !! (n-1)

-- ---------------------------------------------------------------------
-- Ejercicio 6.2. Definir la función
--    sucGolomb :: [Int]
-- tal que sucGolomb es la lista de los términos de la sucesión de
-- Golomb. Por ejemplo,
--    take 15 sucGolomb  ==  [1,2,2,3,3,4,4,4,5,5,5,6,6,6,6]
-- Indicación: Se puede usar la función subSucGolomb del apartado 3.
-- ---------------------------------------------------------------------

sucGolomb :: [Int]
sucGolomb = subSucGolomb 1

-- ---------------------------------------------------------------------
-- Ejercicio 6.3. Definir la función
--    subSucGolomb :: Int -> [Int]
-- tal que (subSucGolomb x) es la lista de los términos de la sucesión
-- de Golomb a partir de la primera ocurrencia de x. Por ejemplo,
--    take 10 (subSucGolomb 4)  ==  [4,4,4,5,5,5,6,6,6,6]
-- Indicación: Se puede usar la función golomb del apartado 1.
-- ---------------------------------------------------------------------

subSucGolomb :: Int -> [Int]
subSucGolomb 1 = [1] ++ subSucGolomb 2
subSucGolomb 2 = [2,2] ++ subSucGolomb 3
subSucGolomb x = (replicate (golomb x) x) ++ subSucGolomb (x+1) 

-- Nota: La sucesión de Golomb puede definirse de forma más compacta
-- como se muestra a continuación.
sucGolomb2 :: [Int]
sucGolomb2 = 1 : 2 : 2 : g 3
    where g x      = replicate (golomb x) x ++ g (x+1) 
          golomb n = sucGolomb !! (n-1)


sucGolomb3 :: [Int]
sucGolomb3 = 1 : 2 : 2 : 
              concat [replicate n k | (n,k) <-zip (drop 2 sucGolomb3) [3..]]

-- ---------------------------------------------------------------------
-- § La codificación por longitud                                     --
-- ---------------------------------------------------------------------

-- La codificación por longitud, o comprensión RLE (del inglés,
-- "Run-length encoding"), es una compresión de datos en la que
-- secuencias de datos con el mismo valor consecutivas son almacenadas
-- como un único valor más su recuento. Por ejemplo, la cadena 
--    BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBBBBBBBBBBBBBBBNBBBBBBBBBBBBBB
-- se codifica por 
--    12B1N12B3N24B1N14B
-- Interpretado esto como 12 letras B, 1 letra N , 12 letras B, 3 letras
-- N, etc.
-- 
-- En los siguientes ejercicios se definirán funciones para codificar y
-- descodificar por longitud.

-- ---------------------------------------------------------------------
-- Ejercicio 7.1. Una lista se puede comprimir indicando el número de
-- veces consecutivas que aparece cada elemento. Por ejemplo, la lista 
-- comprimida de [1,1,7,7,7,5,5,7,7,7,7] es [(2,1),(3,7),(2,5),(4,7)],
-- indicando que comienza con dos 1, seguido de tres 7, dos 5 y cuatro
-- 7. 
-- 
-- Definir la función
--    comprimida :: Eq a => [a] -> [(Int,a)]
-- tal que (comprimida xs) es la lista obtenida al comprimir por
-- longitud la lista xs. Por ejemplo, 
--    ghci> comprimida [1,1,7,7,7,5,5,7,7,7,7]
--    [(2,1),(3,7),(2,5),(4,7)]
--    ghci> comprimida "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBBBBBBBBBB"
--    [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(19,'B')]
-- ---------------------------------------------------------------------

-- 1ª definición (por recursión)
comprimida :: Eq a => [a] -> [(Int,a)]
comprimida xs = aux xs 1
    where aux (x:y:zs) n | x == y    = aux (y:zs) (n+1)
                         | otherwise = (n,x) : aux (y:zs) 1
          aux [x]      n             = [(n,x)]

-- 2ª definición (por recursión usando takeWhile):
comprimida2 :: Eq a => [a] -> [(Int,a)]
comprimida2 [] = []
comprimida2 (x:xs) = 
    (1 + length (takeWhile (==x) xs),x) : comprimida2 (dropWhile (==x) xs)

-- 3ª definición (por comprensión usando group):
comprimida3 :: Eq a => [a] -> [(Int,a)]
comprimida3 xs = [(length ys, head ys) | ys <- group xs]

-- 4ª definición (usando map y group):
comprimida4 :: Eq a => [a] -> [(Int,a)]
comprimida4 = map (\xs -> (length xs, head xs)) . group

-- ---------------------------------------------------------------------
-- Ejercicio 7.2. Definir la función
--    expandida :: [(Int,a)] -> [a]
-- tal que (expandida ps) es la lista expandida correspondiente a ps (es
-- decir, es la lista xs tal que la comprimida de xs es ps). Por
-- ejemplo, 
--    expandida [(2,1),(3,7),(2,5),(4,7)]  ==  [1,1,7,7,7,5,5,7,7,7,7]
-- ---------------------------------------------------------------------

-- 1ª definición (por comprensión)
expandida :: [(Int,a)] -> [a]
expandida ps = concat [replicate k x | (k,x) <- ps]

-- 2ª definición (por concatMap)
expandida2 :: [(Int,a)] -> [a]
expandida2 = concatMap (\(k,x) -> replicate k x) 

-- 3ª definición (por recursión)
expandida3 :: [(Int,a)] -> [a]
expandida3 [] = []
expandida3 ((n,x):ps) = replicate n x ++ expandida3 ps

-- ---------------------------------------------------------------------
-- Ejercicio 7.3. Comprobar con QuickCheck que dada una lista de enteros,
-- si se la comprime y después se expande se obtiene la lista inicial. 
-- ---------------------------------------------------------------------

-- La propiedad es
prop_expandida_comprimida :: [Int] -> Bool 
prop_expandida_comprimida xs = expandida (comprimida xs) == xs

-- La comprobación es
--    ghci> quickCheck prop_expandida_comprimida
--    +++ OK, passed 100 tests.

-- ---------------------------------------------------------------------
-- Ejercicio 7.4. Comprobar con QuickCheck que dada una lista de pares
-- de enteros, si se la expande y después se comprime se obtiene la
-- lista inicial.  
-- ---------------------------------------------------------------------

-- La propiedad es
prop_comprimida_expandida :: [(Int,Int)] -> Bool 
prop_comprimida_expandida xs = expandida (comprimida xs) == xs

-- La comprobación es
--    ghci> quickCheck prop_comprimida_expandida
--    +++ OK, passed 100 tests.

-- ---------------------------------------------------------------------
-- Ejercicio 7.5. Definir la función
--    listaAcadena :: [(Int,Char)] -> String
-- tal que (listaAcadena xs) es la cadena correspondiente a la lista de
-- pares de xs. Por ejemplo,
--    ghci> listaAcadena [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(19,'B')]
--    "12B1N12B3N19B"
-- ---------------------------------------------------------------------

listaAcadena :: [(Int,Char)] -> String
listaAcadena xs = concat [show n ++ [c] | (n,c) <- xs]

-- ---------------------------------------------------------------------
-- Ejercicio 7.6. Definir la función
--    cadenaComprimida :: String -> String
-- tal que (cadenaComprimida cs) es la cadena obtenida comprimiendo por
-- longitud la cadena cs. Por ejemplo,
--    ghci> cadenaComprimida "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBNNN"
--    "12B1N12B3N10B3N"
-- ---------------------------------------------------------------------

cadenaComprimida :: String -> String
cadenaComprimida = listaAcadena . comprimida

-- ---------------------------------------------------------------------
-- Ejercicio 7.7. Definir la función 
--    cadenaAlista :: String -> [(Int,Char)]
-- tal que (cadenaAlista cs) es la lista de pares correspondientes a la
-- cadena cs. Por ejemplo,
--    ghci> cadenaAlista "12B1N12B3N10B3N"
--    [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(10,'B'),(3,'N')]
-- ---------------------------------------------------------------------

cadenaAlista :: String -> [(Int,Char)]
cadenaAlista [] = []
cadenaAlista cs = (read ns,x) : cadenaAlista xs
    where (ns,(x:xs)) = span isNumber cs

-- ---------------------------------------------------------------------
-- Ejercicio 7.8. Definir la función
--    cadenaExpandida :: String -> String
-- tal que (cadenaExpandida cs) es la cadena expandida correspondiente a
-- cs (es decir, es la cadena xs que al comprimirse por longitud da cs). 
-- Por ejemplo, 
--    ghci> cadenaExpandida "12B1N12B3N10B3N"
--    "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBNNN"
-- ---------------------------------------------------------------------

cadenaExpandida :: String -> String
cadenaExpandida = expandida . cadenaAlista

-- ---------------------------------------------------------------------
-- § La sucesión de Kolakoski                                         --
-- ---------------------------------------------------------------------

-- Dada una sucesión, su contadora es la sucesión de las longitudes de
-- de sus bloque de elementos consecutivos iguales. Por ejemplo, la
-- sucesión contadora de abbaaabbba es 12331; es decir; 1 vez la a,
-- 2 la b, 3 la a, 3 la b y 1 la a.
-- 
-- La sucesión de Kolakoski es una sucesión infinita de los símbolos 1 y
-- 2 que es su propia contadora. Los primeros términos de la sucesión
-- de Kolakoski son 1221121221221... que coincide con su contadora (es
-- decir, 1 vez el 1, 2 veces el 2, 2 veces el 1, ...). 
-- 
-- En esta sección se define la sucesión de Kolakoski.

-- ---------------------------------------------------------------------
-- Ejercicio 8.1. Dados los símbolos a y b, la sucesión contadora de
--    abbaaabbba... =  a bb aaa bbb a ...  
-- es
--    1233...       =  1 2  3   3...
-- es decir; 1 vez la a, 2 la b, 3 la a, 3 la b, 1 la a, ...
-- 
-- Definir la función
--    contadora :: Eq a => [a] -> [Int]
-- tal que (contadora xs) es la sucesión contadora de xs. Por ejemplo,
--    contadora "abbaaabbb"        ==  [1,2,3,3]
--    contadora "122112122121121"  ==  [1,2,2,1,1,2,1,1,2,1,1]
-- ---------------------------------------------------------------------

-- 1ª definición (usando group definida en Data.List)
contadora :: Eq a => [a] -> [Int]
contadora xs = map length (group xs)

-- 2ª definición (por recursión sin group):
contadora2 :: Eq a => [a] -> [Int]
contadora2 [] = []
contadora2 ys@(x:xs) = 
    length (takeWhile (==x) ys) : contadora2 (dropWhile (==x) xs)

-- ---------------------------------------------------------------------
-- Ejercicio 8.2. Definir la función
--    contada :: [Int] -> [a] -> [a]
-- tal que (contada ns xs) es la sucesión formada por los símbolos de xs
-- cuya contadora es ns. Por ejemplo,
--    contada [1,2,3,3] "ab"                ==  "abbaaabbb"
--    contada [1,2,3,3] "abc"               ==  "abbcccaaa"
--    contada [1,2,2,1,1,2,1,1,2,1,1] "12"  ==  "122112122121121"
-- ---------------------------------------------------------------------

contada :: [Int] -> [a] -> [a]
contada (n:ns) (x:xs) = replicate n x ++ contada ns (xs++[x])
contada []     _      = []

-- ---------------------------------------------------------------------
-- Ejercicio 8.3. La sucesión autocontadora (o sucesión de  Kolakoski) es
-- la sucesión xs formada por 1 y 2 tal que coincide con su contada; es
-- decir (contadora xs) == xs. Los primeros términos de la función
-- autocontadora son
--    1221121221221... = 1 22 11 2 1 22 1 22 11 ...
-- y su contadora es
--    122112122...     = 1 2  2  1 1 2  1 2  2...
-- que coincide con la inicial. 
-- 
-- Definir la función
--    autocontadora :: [Int]
-- tal que autocontadora es la sucesión autocondadora con los números 1
-- y 2. Por ejemplo,
--    take 11 autocontadora  ==  [1,2,2,1,1,2,1,2,2,1,2]
--    take 12 autocontadora  ==  [1,2,2,1,1,2,1,2,2,1,2,2]
--    take 18 autocontadora  ==  [1,2,2,1,1,2,1,2,2,1,2,2,1,1,2,1,1,2]
-- ---------------------------------------------------------------------

-- 1ª solución
autocontadora :: [Int]
autocontadora = [1,2] ++ siguiente [2] 2

-- Los pasos lo da la función siguiente. Por ejemplo,
--    take 3 (siguiente [2] 2)            ==  [2,1,1]
--    take 4 (siguiente [2,1,1] 1)        ==  [2,1,1,2]
--    take 6 (siguiente [2,1,1,2] 2)      ==  [2,1,1,2,1,1]
--    take 7 (siguiente [2,1,1,2,1,1] 1)  ==  [2,1,1,2,1,1,2]
siguiente (x:xs) y = x : siguiente (xs ++ (nuevos x)) y'
    where contrario 1 = 2
          contrario 2 = 1
          y'          = contrario y              
          nuevos 1    = [y']
          nuevos 2    = [y',y'] 

-- 2ª solución (usando contada)
autocontadora2 :: [Int]
autocontadora2 = 1 : 2: xs 
    where xs = 2 : contada xs [1,2]

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

219

220

221

222

223

224

225

226

227

228

229

230

231

232

233

234

235

236

237

238

239

240

241

242

243

244

245

246

247

248

249

250

251

252

253

254

255

256

257

258

259

260

261

262

263

264

265

266

267

268

269

270

271

272

273

274

275

276

277

278

279

280

281

282

283

284

285

286

287

288

289

290

291

292

293

294

295

296

297

298

299

300

301

302

303

304

305

306

307

308

309

310

311

312

313

314

315

316

317

318

319

320

321

322

323

324

325

326

327

328

329

330

331

332

333

334

335

336

337

338

339

340

341

342

343

344

345

346

347

348

349

350

351

352

353

354

355

356

357

358

359

360

361

362

363

364

365

366

367

368

369

370

371

372

373

374

375

376

377

378

379

380

381

382

383

384

385

386

387

388

389

390

391

392

393

394

395

396

397

398

399

400

401

402

403

404

405

406

407

408

409

410

411

412

413

414

415

416

417

418

419

420

421

422

423

424

425

426

427

428

429

430

431

432

433

434

435

436

437

438

439

440

441

442

443

444

445

446

447

448

449

450

451

452

453

454

455

456

457

458

459

460

461

462

463

464

465

466

467

468

469

470

471

472

473

474

475

476

477

478

479

480

481

482

483

484

485

486

487

488

489

490

491

492

493

494

495

496

497

498

499

500

501

502

503

504

505

506

507

508

509

510

511

512

513

514

515

516

517

518

519

520

521

522

523

524

525

526

527

528

529

530

531

532

533

534

535

536

537

538

539

540

541

542

543

544

545

546

547

548

549

550

551

552

553

554

555

556

557

558

559

560

561

562

563

564

565

566

567

568

569

570

571

572

573

574

575

576

577

578

579

580

581

582

583

584

585

586

587

588

589

590

591

592

593

594

595

596

597

598

599

600

601

602

603

604

605

606

607

608

609

610

611

612

613

614

615

616

617

618

619

620

621

622

623

624

625

626

627

628

629

630

631

632

633

634

635

636

637

638

639

640

641

642

643

644

645

646

647

648

649

650

651

652

653

654

655

656

657

658

659

660

661

662

663

664

665

666

667

668

669

670

671

672

673

674

675

676

677

678

679

680

681

682

683

684

685

686

687

688

689

690

691

692

693

694

695

696

697

698

699

700

701

702

703

704

705

706

707

708

709

710

711

712

713

714

715

716

717

718

719

720

721

722

723

724

725

726

727

728

729

730

731

732

733

734

735

736

737

738

739

740

-- ---------------------------------------------------------------------

-- Introducción --

-- ---------------------------------------------------------------------

-- En esta relación se estudia distintas aplicaciones de la programación

-- funcional que usan listas infinitas

-- + la sucesión de Hamming,

-- + problemas 10 y 12 del proyecto Euler,

-- + enumeración de los números enteros,

-- + el problema de la bicicleta de Turing,

-- + la sucesión de Golomb,

-- + la codificación por longitud,

-- + la sucesión de Kolakoski y

-- + el triángulo de Floyd.

-- ---------------------------------------------------------------------

-- Importación de librerías --

-- ---------------------------------------------------------------------

import Data.Char

import Data.List

import Data.Numbers.Primes

import Test.QuickCheck

-- ---------------------------------------------------------------------

-- § Sucesión de Hamming --

-- ---------------------------------------------------------------------

-- Ejercicio 1.1. Definir la función

-- divisoresPrimosEn :: Integer -> [Integer] -> Bool

-- tal que (divisoresPrimosEn x ys) se verifica si x puede expresarse

-- como un producto de potencias de elementos de la lista de números

-- primos ys. Por ejemplo,

-- divisoresPrimosEn 12 [2,3,5] == True

-- divisoresPrimosEn 14 [2,3,5] == False

-- ---------------------------------------------------------------------

-- 1ª definición (por recursión)

divisoresPrimosEn1 :: Integer -> [Integer] -> Bool

divisoresPrimosEn1 1 _ = True

divisoresPrimosEn1 x [] = False

divisoresPrimosEn1 x (y:ys)

| mod x y == 0 = divisoresPrimosEn1 (div x y) (y:ys)

| otherwise = divisoresPrimosEn1 x ys

-- 2ª definición (por comprensión)

divisoresPrimosEn2 :: Integer -> [Integer] -> Bool

divisoresPrimosEn2 x ys = and [elem y ys | y <- primeFactors x]

-- 3ª definición (por cuantificación)

divisoresPrimosEn :: Integer -> [Integer] -> Bool

divisoresPrimosEn x ys = all (`elem` ys) (primeFactors x)

-- ---------------------------------------------------------------------

-- Ejercicio 1.2. Los números de Hamming forman una sucesión

-- estrictamente creciente de números que cumplen las siguientes

-- condiciones:

-- 1. El número 1 está en la sucesión.

-- 2. Si x está en la sucesión, entonces 2x, 3x y 5x también están.

-- 3. Ningún otro número está en la sucesión.

-- Definir, usando divisoresPrimosEn, la constante

-- hamming :: [Integer]

-- tal que hamming es la sucesión de Hamming. Por ejemplo,

-- take 12 hamming == [1,2,3,4,5,6,8,9,10,12,15,16]

-- ---------------------------------------------------------------------

hamming :: [Integer]

hamming = [x | x <- [1..], divisoresPrimosEn x [2,3,5]]

-- ---------------------------------------------------------------------

-- Ejercicio 1.3. Definir la función

-- cantidadHammingMenores :: Integer -> Int

-- tal que (cantidadHammingMenores x) es la cantidad de números de

-- Hamming menores que x. Por ejemplo,

-- cantidadHammingMenores 6 == 5

-- cantidadHammingMenores 7 == 6

-- cantidadHammingMenores 8 == 6

-- ---------------------------------------------------------------------

cantidadHammingMenores :: Integer -> Int

cantidadHammingMenores x = length (takeWhile (<x) hamming)

-- ---------------------------------------------------------------------

-- Ejercicio 1.4. Definir la función

-- siguienteHamming :: Integer -> Integer

-- tal que (siguienteHamming x) es el menor número de la sucesión de

-- Hamming mayor que x. Por ejemplo,

-- siguienteHamming 6 == 8

-- siguienteHamming 21 == 24

-- ---------------------------------------------------------------------

siguienteHamming :: Integer -> Integer

siguienteHamming x = head (dropWhile (<=x) hamming)

-- ---------------------------------------------------------------------

-- Ejercicio 1.5. Definir la función

-- huecoHamming :: Integer -> [(Integer,Integer)]

-- tal que (huecoHamming n) es la lista de pares de números consecutivos

-- en la sucesión de Hamming cuya distancia es mayor que n. Por ejemplo,

-- take 4 (huecoHamming 2) == [(12,15),(20,24),(27,30),(32,36)]

-- take 3 (huecoHamming 2) == [(12,15),(20,24),(27,30)]

-- take 2 (huecoHamming 3) == [(20,24),(32,36)]

-- head (huecoHamming 10) == (108,120)

-- head (huecoHamming 1000) == (34992,36000)

-- ---------------------------------------------------------------------

huecoHamming :: Integer -> [(Integer,Integer)]

huecoHamming n = [(x,y) | x <- hamming,

let y = siguienteHamming x,

y-x > n]

-- ---------------------------------------------------------------------

-- Ejercicio 1.6. Comprobar con QuickCheck que para todo n, existen

-- pares de números consecutivos en la sucesión de Hamming cuya

-- distancia es mayor que n.

-- ---------------------------------------------------------------------

-- La propiedad es

prop_Hamming :: Integer -> Bool

prop_Hamming n = huecoHamming n' /= []

where n' = abs n

-- La comprobación es

-- ghci> quickCheck prop_Hamming

-- OK, passed 100 tests.

-- ---------------------------------------------------------------------

-- § Problema 10 del Proyecto Euler --

-- ---------------------------------------------------------------------

-- Ejercicio 2. Definir la función

-- sumaPrimoMenores :: Integer -> Integer

-- tal que (sumaPrimoMenores n) es la suma de los primos menores que

-- n. Por ejemplo,

-- sumaPrimoMenores 10 == 17

-- sumaPrimoMenores 7 == 10

-- ---------------------------------------------------------------------

-- 1ª definición (por recursión y la criba de Erastótenes)

-- =======================================================

sumaPrimoMenores1 :: Integer -> Integer

sumaPrimoMenores1 n = sumaMenores n primos 0

where sumaMenores n (x:xs) a | n <= x = a

| otherwise = sumaMenores n xs (a+x)

-- primos es la lista de los número primos obtenida mediante la criba de

-- Erastótenes. Por ejemplo,

-- primos => [2,3,5,7,11,13,17,19,23,29,31,37,41,43,47,53,59,...

primos :: [Integer]

primos = criba [2..]

where criba (p:ps) = p : criba [n | n<-ps, mod n p /= 0]

-- 2ª definición (por comprensión y la criba de Erastótenes)

-- =========================================================

sumaPrimoMenores2 :: Integer -> Integer

sumaPrimoMenores2 n = sum (takeWhile (<n) primos)

-- 3ª definición (por comprensión y la librería de primos)

-- =======================================================

sumaPrimoMenores3 :: Integer -> Integer

sumaPrimoMenores3 n = sum (takeWhile (<n) primes)

-- Comparación de eficiencia

-- =========================

-- λ> sumaPrimoMenores1 20000

-- 21171191

-- (5.11 secs, 922,508,496 bytes)

-- λ> sumaPrimoMenores2 20000

-- 21171191

-- (5.05 secs, 898,081,952 bytes)

-- λ> sumaPrimoMenores3 20000

-- 21171191

-- (0.02 secs, 0 bytes)

-- ---------------------------------------------------------------------

-- § Problema 12 del Proyecto Euler --

-- ---------------------------------------------------------------------

-- Ejercicio 3.1. Los números triangulares se forman como sigue

-- * * *

-- * * * *

-- * * *

-- 1 3 6

-- La sucesión de los números triangulares se obtiene sumando los

-- números naturales. Así, los 5 primeros números triangulares son

-- 1 = 1

-- 3 = 1+2

-- 6 = 1+2+3

-- 10 = 1+2+3+4

-- 15 = 1+2+3+4+5

-- Definir la función

-- triangulares :: [Integer]

-- tal que triangulares es la lista de los números triangulares. Por

-- ejemplo,

-- take 10 triangulares == [1,3,6,10,15,21,28,36,45,55]

-- triangulares !! 2000000 == 2000003000001

-- ---------------------------------------------------------------------

-- 1ª definición

triangulares1 :: [Integer]

triangulares1 = 1 : [x+y | (x,y) <- zip [2..] triangulares]

-- 2ª definición

triangulares2 :: [Integer]

triangulares2 = scanl (+) 1 [2..]

-- 3ª definición (usando la fórmula de la suma de la progresión):

triangulares3 :: [Integer]

triangulares3 = [(n*(n+1)) `div` 2 | n <- [1..]]

-- Comparación de eficiencia

-- λ> triangulares1 !! 1000000

-- 500001500001

-- (3.07 secs, 484,321,192 bytes)

-- λ> triangulares2 !! 1000000

-- 500001500001

-- (0.04 secs, 0 bytes)

-- λ> triangulares3 !! 1000000

-- 500001500001

-- (1.23 secs, 186,249,472 bytes)

-- En lo sucesivo, usaremos como triangulares la segunda definición.

triangulares :: [Integer]

triangulares = triangulares2

-- ---------------------------------------------------------------------

-- Ejercicio 3.2. Definir la función

-- nDivisores :: Integer -> Integer

-- tal que (nDivisores n) es el número de los divisores de n. Por

-- ejemplo,

-- nDivisores 28 == 6

-- nDivisores (product [1..200]) == 139503973313460993785856000000

-- ---------------------------------------------------------------------

-- 1ª definición

-- =============

nDivisores1 :: Integer -> Integer

nDivisores1 = genericLength . divisores

-- (divisores n) es la lista de los divisores de n. Por ejemplo,

-- divisores 28 == [1,2,4,7,14,28]

divisores :: Integer -> [Integer]

divisores x = [y | y <- [1..x], mod x y == 0]

-- 2ª definición (con primeFactors y group)

-- ========================================

nDivisores2 :: Integer -> Integer

nDivisores2 n =

product [1 + genericLength xs | xs <- group (primeFactors n)]

-- Comparación de eficiencia

-- =========================

-- λ> nDivisores1 (product [1..10])

-- 270

-- (5.18 secs, 763,249,336 bytes)

-- λ> nDivisores2 (product [1..10])

-- 270

-- (0.01 secs, 0 bytes)

-- En lo sucesivo usaremos la 2ª definición de nDivisores

nDivisores :: Integer -> Integer

nDivisores = nDivisores2

-- ---------------------------------------------------------------------

-- Ejercicio 3.3. Los divisores de los primeros 7 números triangulares

-- son:

-- 1: 1

-- 3: 1,3

-- 6: 1,2,3,6

-- 10: 1,2,5,10

-- 15: 1,3,5,15

-- 21: 1,3,7,21

-- 28: 1,2,4,7,14,28

-- Como se puede observar, 28 es el menor número triangular con más de 5

-- divisores.

-- Definir la función

-- euler12 :: Int -> Integer

-- tal que (euler12 n) es el menor número triangular con más de n

-- divisores. Por ejemplo,

-- euler12 5 == 28

-- euler12 500 == 76576500

-- ---------------------------------------------------------------------

euler12 :: Integer -> Integer

euler12 n = head [x | x <- triangulares, nDivisores x > n]

-- ---------------------------------------------------------------------

-- § Enumeración de los números enteros --

-- ---------------------------------------------------------------------

-- Ejercicio 4.1. Los números enteros se pueden ordenar como sigue

-- 0, -1, 1, -2, 2, -3, 3, -4, 4, -5, 5, -6, 6, -7, 7, ...

-- Definir, por comprensión, la constante

-- enteros :: [Int]

-- tal que enteros es la lista de los enteros con la ordenación

-- anterior. Por ejemplo,

-- take 10 enteros == [0,-1,1,-2,2,-3,3,-4,4,-5]

-- ---------------------------------------------------------------------

enteros :: [Int]

enteros = 0 : concat [[-x,x] | x <- [1..]]

-- ---------------------------------------------------------------------

-- Ejercicio 4.2. Definir, por iteración, la constante

-- enteros' :: [Int]

-- tal que enteros' es la lista de los enteros con la ordenación

-- anterior. Por ejemplo,

-- take 10 enteros == [0,-1,1,-2,2,-3,3,-4,4,-5]

-- ---------------------------------------------------------------------

enteros' :: [Int]

enteros' = iterate siguiente 0

where siguiente x | x >= 0 = -x-1

| otherwise = -x

-- ---------------------------------------------------------------------

-- Ejercicio 4.3. Definir, por selección con takeWhile, la función

-- posicion :: Int -> Int

-- tal que (posicion x) es la posición del entero x en la ordenación

-- anterior. Por ejemplo,

-- posicion 2 == 4

-- ---------------------------------------------------------------------

posicion :: Int -> Int

posicion x = length (takeWhile (/=x) enteros)

-- ---------------------------------------------------------------------

-- Ejercicio 4.4. Definir, por recursión, la función

-- posicionR :: Int -> Int

-- tal que (posicionR x) es la posición del entero x en la ordenación

-- anterior. Por ejemplo,

-- posicionR 2 == 4

-- ---------------------------------------------------------------------

posicionR :: Int -> Int

posicionR x = aux enteros 0

where aux (y:ys) n | x == y = n

| otherwise = aux ys (n+1)

-- ---------------------------------------------------------------------

-- Ejercicio 4.5. Definir, por comprensión, la función

-- posicionC :: Int -> Int

-- tal que (posicionC x) es la posición del entero x en la ordenación

-- anterior. Por ejemplo,

-- posicionC 2 == 4

-- ---------------------------------------------------------------------

posicionC :: Int -> Int

posicionC x = head [n | (n,y) <- zip [0..] enteros, y == x]

-- ---------------------------------------------------------------------

-- Ejercicio 4.6. Definir, sin búsqueda, la función

-- posicion2 :: Int -> Int

-- tal que (posicion2 x) es la posición del entero x en la ordenación

-- anterior. Por ejemplo,

-- posicion2 2 == 4

-- ---------------------------------------------------------------------

-- Definición directa

posicion2 :: Int -> Int

posicion2 x | x >= 0 = 2*x

| otherwise = 2*(-x)-1

-- ---------------------------------------------------------------------

-- § El problema de la bicicleta de Turing --

-- ---------------------------------------------------------------------

-- Ejercicio 5.1. Cuentan que Alan Turing tenía una bicicleta vieja,

-- que tenía una cadena con un eslabón débil y además uno de los radios

-- de la rueda estaba doblado. Cuando el radio doblado coincidía con el

-- eslabón débil, entonces la cadena se rompía.

-- La bicicleta se identifica por los parámetros (i,d,n) donde

-- - i es el número del eslabón que coincide con el radio doblado al

-- empezar a andar,

-- - d es el número de eslabones que se desplaza la cadena en cada

-- vuelta de la rueda y

-- - n es el número de eslabones de la cadena (el número n es el débil).

-- Si i=2 y d=7 y n=25, entonces la lista con el número de eslabón que

-- toca el radio doblado en cada vuelta es

-- [2,9,16,23,5,12,19,1,8,15,22,4,11,18,0,7,14,21,3,10,17,24,6,...

-- Con lo que la cadena se rompe en la vuelta número 14.

-- Definir la función

-- eslabones :: Int -> Int -> Int -> [Int]

-- tal que (eslabones i d n) es la lista con los números de eslabones

-- que tocan el radio doblado en cada vuelta en una bicicleta de tipo

-- (i,d,n). Por ejemplo,

-- take 10 (eslabones 2 7 25) == [2,9,16,23,5,12,19,1,8,15]

-- ---------------------------------------------------------------------

eslabones :: Int -> Int -> Int -> [Int]

eslabones i d n = [(i+d*j) `mod` n | j <- [0..]]

-- 2ª definición (con iterate):

eslabones2 :: Int -> Int -> Int -> [Int]

eslabones2 i d n = map (\x-> mod x n) (iterate (+d) i)

-- ---------------------------------------------------------------------

-- Ejercicio 5.2. Definir la función

-- numeroVueltas :: Int -> Int -> Int -> Int

-- tal que (numeroVueltas i d n) es el número de vueltas que pasarán

-- hasta que la cadena se rompa en una bicicleta de tipo (i,d,n). Por

-- ejemplo,

-- numeroVueltas 2 7 25 == 14

-- ---------------------------------------------------------------------

numeroVueltas :: Int -> Int -> Int -> Int

numeroVueltas i d n = length (takeWhile (/=0) (eslabones i d n))

-- ---------------------------------------------------------------------

-- § La sucesión de Golomb --

-- ---------------------------------------------------------------------

-- Ejercicio 6.1. [Basado en el problema 341 del proyecto Euler]. La

-- sucesión de Golomb {G(n)} es una sucesión auto descriptiva: es la

-- única sucesión no decreciente de números naturales tal que el número

-- n aparece G(n) veces en la sucesión. Los valores de G(n) para los

-- primeros números son los siguientes:

-- n 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 ...

-- G(n) 1 2 2 3 3 4 4 4 5 5 5 6 6 6 6 ...

-- En los apartados de este ejercicio se definirá una función para

-- calcular los términos de la sucesión de Golomb.

-- Definir la función

-- golomb :: Int -> Int

-- tal que (golomb n) es el n-ésimo término de la sucesión de Golomb.

-- Por ejemplo,

-- golomb 5 == 3

-- golomb 9 == 5

-- Indicación: Se puede usar la función sucGolomb del apartado 2.

-- ---------------------------------------------------------------------

golomb :: Int -> Int

golomb n = sucGolomb !! (n-1)

-- ---------------------------------------------------------------------

-- Ejercicio 6.2. Definir la función

-- sucGolomb :: [Int]

-- tal que sucGolomb es la lista de los términos de la sucesión de

-- Golomb. Por ejemplo,

-- take 15 sucGolomb == [1,2,2,3,3,4,4,4,5,5,5,6,6,6,6]

-- Indicación: Se puede usar la función subSucGolomb del apartado 3.

-- ---------------------------------------------------------------------

sucGolomb :: [Int]

sucGolomb = subSucGolomb 1

-- ---------------------------------------------------------------------

-- Ejercicio 6.3. Definir la función

-- subSucGolomb :: Int -> [Int]

-- tal que (subSucGolomb x) es la lista de los términos de la sucesión

-- de Golomb a partir de la primera ocurrencia de x. Por ejemplo,

-- take 10 (subSucGolomb 4) == [4,4,4,5,5,5,6,6,6,6]

-- Indicación: Se puede usar la función golomb del apartado 1.

-- ---------------------------------------------------------------------

subSucGolomb :: Int -> [Int]

subSucGolomb 1 = [1] ++ subSucGolomb 2

subSucGolomb 2 = [2,2] ++ subSucGolomb 3

subSucGolomb x = (replicate (golomb x) x) ++ subSucGolomb (x+1)

-- Nota: La sucesión de Golomb puede definirse de forma más compacta

-- como se muestra a continuación.

sucGolomb2 :: [Int]

sucGolomb2 = 1 : 2 : 2 : g 3

where g x = replicate (golomb x) x ++ g (x+1)

golomb n = sucGolomb !! (n-1)

sucGolomb3 :: [Int]

sucGolomb3 = 1 : 2 : 2 :

concat [replicate n k | (n,k) <-zip (drop 2 sucGolomb3) [3..]]

-- ---------------------------------------------------------------------

-- § La codificación por longitud --

-- ---------------------------------------------------------------------

-- La codificación por longitud, o comprensión RLE (del inglés,

-- "Run-length encoding"), es una compresión de datos en la que

-- secuencias de datos con el mismo valor consecutivas son almacenadas

-- como un único valor más su recuento. Por ejemplo, la cadena

-- BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBBBBBBBBBBBBBBBNBBBBBBBBBBBBBB

-- se codifica por

-- 12B1N12B3N24B1N14B

-- Interpretado esto como 12 letras B, 1 letra N , 12 letras B, 3 letras

-- N, etc.

-- En los siguientes ejercicios se definirán funciones para codificar y

-- descodificar por longitud.

-- ---------------------------------------------------------------------

-- Ejercicio 7.1. Una lista se puede comprimir indicando el número de

-- veces consecutivas que aparece cada elemento. Por ejemplo, la lista

-- comprimida de [1,1,7,7,7,5,5,7,7,7,7] es [(2,1),(3,7),(2,5),(4,7)],

-- indicando que comienza con dos 1, seguido de tres 7, dos 5 y cuatro

-- 7.

-- Definir la función

-- comprimida :: Eq a => [a] -> [(Int,a)]

-- tal que (comprimida xs) es la lista obtenida al comprimir por

-- longitud la lista xs. Por ejemplo,

-- ghci> comprimida [1,1,7,7,7,5,5,7,7,7,7]

-- [(2,1),(3,7),(2,5),(4,7)]

-- ghci> comprimida "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBBBBBBBBBB"

-- [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(19,'B')]

-- ---------------------------------------------------------------------

-- 1ª definición (por recursión)

comprimida :: Eq a => [a] -> [(Int,a)]

comprimida xs = aux xs 1

where aux (x:y:zs) n | x == y = aux (y:zs) (n+1)

| otherwise = (n,x) : aux (y:zs) 1

aux [x] n = [(n,x)]

-- 2ª definición (por recursión usando takeWhile):

comprimida2 :: Eq a => [a] -> [(Int,a)]

comprimida2 [] = []

comprimida2 (x:xs) =

(1 + length (takeWhile (==x) xs),x) : comprimida2 (dropWhile (==x) xs)

-- 3ª definición (por comprensión usando group):

comprimida3 :: Eq a => [a] -> [(Int,a)]

comprimida3 xs = [(length ys, head ys) | ys <- group xs]

-- 4ª definición (usando map y group):

comprimida4 :: Eq a => [a] -> [(Int,a)]

comprimida4 = map (\xs -> (length xs, head xs)) . group

-- ---------------------------------------------------------------------

-- Ejercicio 7.2. Definir la función

-- expandida :: [(Int,a)] -> [a]

-- tal que (expandida ps) es la lista expandida correspondiente a ps (es

-- decir, es la lista xs tal que la comprimida de xs es ps). Por

-- ejemplo,

-- expandida [(2,1),(3,7),(2,5),(4,7)] == [1,1,7,7,7,5,5,7,7,7,7]

-- ---------------------------------------------------------------------

-- 1ª definición (por comprensión)

expandida :: [(Int,a)] -> [a]

expandida ps = concat [replicate k x | (k,x) <- ps]

-- 2ª definición (por concatMap)

expandida2 :: [(Int,a)] -> [a]

expandida2 = concatMap (\(k,x) -> replicate k x)

-- 3ª definición (por recursión)

expandida3 :: [(Int,a)] -> [a]

expandida3 [] = []

expandida3 ((n,x):ps) = replicate n x ++ expandida3 ps

-- ---------------------------------------------------------------------

-- Ejercicio 7.3. Comprobar con QuickCheck que dada una lista de enteros,

-- si se la comprime y después se expande se obtiene la lista inicial.

-- ---------------------------------------------------------------------

-- La propiedad es

prop_expandida_comprimida :: [Int] -> Bool

prop_expandida_comprimida xs = expandida (comprimida xs) == xs

-- La comprobación es

-- ghci> quickCheck prop_expandida_comprimida

-- +++ OK, passed 100 tests.

-- ---------------------------------------------------------------------

-- Ejercicio 7.4. Comprobar con QuickCheck que dada una lista de pares

-- de enteros, si se la expande y después se comprime se obtiene la

-- lista inicial.

-- ---------------------------------------------------------------------

-- La propiedad es

prop_comprimida_expandida :: [(Int,Int)] -> Bool

prop_comprimida_expandida xs = expandida (comprimida xs) == xs

-- La comprobación es

-- ghci> quickCheck prop_comprimida_expandida

-- +++ OK, passed 100 tests.

-- ---------------------------------------------------------------------

-- Ejercicio 7.5. Definir la función

-- listaAcadena :: [(Int,Char)] -> String

-- tal que (listaAcadena xs) es la cadena correspondiente a la lista de

-- pares de xs. Por ejemplo,

-- ghci> listaAcadena [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(19,'B')]

-- "12B1N12B3N19B"

-- ---------------------------------------------------------------------

listaAcadena :: [(Int,Char)] -> String

listaAcadena xs = concat [show n ++ [c] | (n,c) <- xs]

-- ---------------------------------------------------------------------

-- Ejercicio 7.6. Definir la función

-- cadenaComprimida :: String -> String

-- tal que (cadenaComprimida cs) es la cadena obtenida comprimiendo por

-- longitud la cadena cs. Por ejemplo,

-- ghci> cadenaComprimida "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBNNN"

-- "12B1N12B3N10B3N"

-- ---------------------------------------------------------------------

cadenaComprimida :: String -> String

cadenaComprimida = listaAcadena . comprimida

-- ---------------------------------------------------------------------

-- Ejercicio 7.7. Definir la función

-- cadenaAlista :: String -> [(Int,Char)]

-- tal que (cadenaAlista cs) es la lista de pares correspondientes a la

-- cadena cs. Por ejemplo,

-- ghci> cadenaAlista "12B1N12B3N10B3N"

-- [(12,'B'),(1,'N'),(12,'B'),(3,'N'),(10,'B'),(3,'N')]

-- ---------------------------------------------------------------------

cadenaAlista :: String -> [(Int,Char)]

cadenaAlista [] = []

cadenaAlista cs = (read ns,x) : cadenaAlista xs

where (ns,(x:xs)) = span isNumber cs

-- ---------------------------------------------------------------------

-- Ejercicio 7.8. Definir la función

-- cadenaExpandida :: String -> String

-- tal que (cadenaExpandida cs) es la cadena expandida correspondiente a

-- cs (es decir, es la cadena xs que al comprimirse por longitud da cs).

-- Por ejemplo,

-- ghci> cadenaExpandida "12B1N12B3N10B3N"

-- "BBBBBBBBBBBBNBBBBBBBBBBBBNNNBBBBBBBBBBNNN"

-- ---------------------------------------------------------------------

cadenaExpandida :: String -> String

cadenaExpandida = expandida . cadenaAlista

-- ---------------------------------------------------------------------

-- § La sucesión de Kolakoski --

-- ---------------------------------------------------------------------

-- Dada una sucesión, su contadora es la sucesión de las longitudes de

-- de sus bloque de elementos consecutivos iguales. Por ejemplo, la

-- sucesión contadora de abbaaabbba es 12331; es decir; 1 vez la a,

-- 2 la b, 3 la a, 3 la b y 1 la a.

-- La sucesión de Kolakoski es una sucesión infinita de los símbolos 1 y

-- 2 que es su propia contadora. Los primeros términos de la sucesión

-- de Kolakoski son 1221121221221... que coincide con su contadora (es

-- decir, 1 vez el 1, 2 veces el 2, 2 veces el 1, ...).

-- En esta sección se define la sucesión de Kolakoski.

-- ---------------------------------------------------------------------

-- Ejercicio 8.1. Dados los símbolos a y b, la sucesión contadora de

-- abbaaabbba... = a bb aaa bbb a ...

-- es

-- 1233... = 1 2 3 3...

-- es decir; 1 vez la a, 2 la b, 3 la a, 3 la b, 1 la a, ...

-- Definir la función

-- contadora :: Eq a => [a] -> [Int]

-- tal que (contadora xs) es la sucesión contadora de xs. Por ejemplo,

-- contadora "abbaaabbb" == [1,2,3,3]

-- contadora "122112122121121" == [1,2,2,1,1,2,1,1,2,1,1]

-- ---------------------------------------------------------------------

-- 1ª definición (usando group definida en Data.List)

contadora :: Eq a => [a] -> [Int]

contadora xs = map length (group xs)

-- 2ª definición (por recursión sin group):

contadora2 :: Eq a => [a] -> [Int]

contadora2 [] = []

contadora2 ys@(x:xs) =

length (takeWhile (==x) ys) : contadora2 (dropWhile (==x) xs)

-- ---------------------------------------------------------------------

-- Ejercicio 8.2. Definir la función

-- contada :: [Int] -> [a] -> [a]

-- tal que (contada ns xs) es la sucesión formada por los símbolos de xs

-- cuya contadora es ns. Por ejemplo,

-- contada [1,2,3,3] "ab" == "abbaaabbb"

-- contada [1,2,3,3] "abc" == "abbcccaaa"

-- contada [1,2,2,1,1,2,1,1,2,1,1] "12" == "122112122121121"

-- ---------------------------------------------------------------------

contada :: [Int] -> [a] -> [a]

contada (n:ns) (x:xs) = replicate n x ++ contada ns (xs++[x])

contada [] _ = []

-- ---------------------------------------------------------------------

-- Ejercicio 8.3. La sucesión autocontadora (o sucesión de Kolakoski) es

-- la sucesión xs formada por 1 y 2 tal que coincide con su contada; es

-- decir (contadora xs) == xs. Los primeros términos de la función

-- autocontadora son

-- 1221121221221... = 1 22 11 2 1 22 1 22 11 ...

-- y su contadora es

-- 122112122... = 1 2 2 1 1 2 1 2 2...

-- que coincide con la inicial.

-- Definir la función

-- autocontadora :: [Int]

-- tal que autocontadora es la sucesión autocondadora con los números 1

-- y 2. Por ejemplo,

-- take 11 autocontadora == [1,2,2,1,1,2,1,2,2,1,2]

-- take 12 autocontadora == [1,2,2,1,1,2,1,2,2,1,2,2]

-- take 18 autocontadora == [1,2,2,1,1,2,1,2,2,1,2,2,1,1,2,1,1,2]

-- ---------------------------------------------------------------------

-- 1ª solución

autocontadora :: [Int]

autocontadora = [1,2] ++ siguiente [2] 2

-- Los pasos lo da la función siguiente. Por ejemplo,

-- take 3 (siguiente [2] 2) == [2,1,1]

-- take 4 (siguiente [2,1,1] 1) == [2,1,1,2]

-- take 6 (siguiente [2,1,1,2] 2) == [2,1,1,2,1,1]

-- take 7 (siguiente [2,1,1,2,1,1] 1) == [2,1,1,2,1,1,2]

siguiente (x:xs) y = x : siguiente (xs ++ (nuevos x)) y'

where contrario 1 = 2

contrario 2 = 1

y' = contrario y

nuevos 1 = [y']

nuevos 2 = [y',y']

-- 2ª solución (usando contada)

autocontadora2 :: [Int]

autocontadora2 = 1 : 2: xs

where xs = 2 : contada xs [1,2]

Se puede imprimir o compartir con