I1M2013: Ejercicios de evaluación perezosa y listas infinitas en Haskell (2)

En la clase de hoy de Informática de 1º del Grado en Matemáticas hemos comentando las soluciones de ejercicios de evaluación perezosa y listas infinitas de las relaciones 15 y 16.

Los ejercicios de la relación 15, y sus soluciones, se muestran a continuación.

-- ---------------------------------------------------------------------
-- Importación de librerías auxiliares                                  
-- ---------------------------------------------------------------------

import Test.QuickCheck

-- ---------------------------------------------------------------------
-- Ejercicio 4. Definir, usando takeWhile y map, la función
--    potenciasMenores :: Int -> Int -> [Int]
-- tal que (potenciasMenores x y) es la lista de las potencias de x
-- menores que y. Por ejemplo,
--    potenciasMenores 2 1000  ==  [2,4,8,16,32,64,128,256,512]
-- ---------------------------------------------------------------------

potenciasMenores :: Int -> Int -> [Int]
potenciasMenores x y = takeWhile (<y) (map (x^) [1..])

-- ---------------------------------------------------------------------
-- Ejercicio 5a. (Problema 303 del proyecto Euler) Definir la función
--    multiplosRestringidos :: Int -> (Int -> Bool) -> [Int]
-- tal que (multiplosRestringidos n x) es la lista de los múltiplos de n
-- tales que todas sus dígitos verifican la propiedad p. Por ejemplo, 
--    take 4 (multiplosRestringidos 5 (<=3))  ==  [10,20,30,100]
--    take 5 (multiplosRestringidos 3 (<=4))  ==  [3,12,21,24,30]
--    take 5 (multiplosRestringidos 3 even)   ==  [6,24,42,48,60]
-- ---------------------------------------------------------------------

multiplosRestringidos :: Int -> (Int -> Bool) -> [Int]
multiplosRestringidos n p = 
    [y | y <- [n,2*n..], all p (digitos y)]

-- (digitos n) es la lista de las dígitos de n, Por ejemplo, 
--    digitos 327  ==  [3,2,7]
digitos :: Int -> [Int]
digitos n = [read [x] | x <- show n]

-- ---------------------------------------------------------------------
-- Ejercicio 5b. Definir, por recursión, la función
--    itera :: (a -> a) -> a -> [a]
-- tal que (itera f x) es la lista cuyo primer elemento es x y los
-- siguientes elementos se calculan aplicando la función f al elemento
-- anterior. Por ejemplo, 
--    ghci> itera (+1) 3
--    [3,4,5,6,7,8,9,10,11,12,{Interrupted!}
--    ghci> itera (*2) 1
--    [1,2,4,8,16,32,64,{Interrupted!}
--    ghci> itera (`div` 10) 1972
--    [1972,197,19,1,0,0,0,0,0,0,{Interrupted!}
-- Nota: La función repite es equivalente a la función iterate definida
-- en el preludio de Haskell.
-- ---------------------------------------------------------------------

itera :: (a -> a) -> a -> [a]
itera f x = x : itera f (f x)

-- ----------------------------------------------------------------------------
-- Ejercicio 6.1. Definir, por recursión, la función
--    agrupa :: Int -> [a] -> [[a]]
-- tal que (agrupa n xs) es la lista formada por listas de n elementos
-- consecutivos de la lista xs (salvo posiblemente la última que puede
-- tener menos de n elementos). Por ejemplo, 
--    ghci> agrupa 2 [3,1,5,8,2,7]
--    [[3,1],[5,8],[2,7]]
--    ghci> agrupa 2 [3,1,5,8,2,7,9] 
--    [[3,1],[5,8],[2,7],[9]]
--    ghci> agrupa 5 "todo necio confunde valor y precio"
--    ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]
-- ---------------------------------------------------------------------------- 

agrupa :: Int -> [a] -> [[a]]
agrupa n [] = []
agrupa n xs = take n xs : agrupa n (drop n xs)

-- ----------------------------------------------------------------------------
-- Ejercicio 6.2. Definir, de manera no recursiva, la función
--    agrupa' :: Int -> [a] -> [[a]]
-- tal que (agrupa' n xs) es la lista formada por listas de n elementos
-- consecutivos de la lista xs (salvo posiblemente la última que puede
-- tener menos de n elementos). Por ejemplo, 
--    ghci> agrupa' 2 [3,1,5,8,2,7]
--    [[3,1],[5,8],[2,7]]
--    ghci> agrupa' 2 [3,1,5,8,2,7,9] 
--    [[3,1],[5,8],[2,7],[9]]
--    ghci> agrupa' 5 "todo necio confunde valor y precio"
--    ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]
-- ---------------------------------------------------------------------------- 

agrupa' :: Int -> [a] -> [[a]]
agrupa' n = takeWhile (not . null)
          . map (take n)
          . iterate (drop n)

-- Puede verse su funcionamiento en el siguiente ejemplo,
--    iterate (drop 2) [5..10]  
--    ==> [[5,6,7,8,9,10],[7,8,9,10],[9,10],[],[],...
--    map (take 2) (iterate (drop 2) [5..10])
--    ==> [[5,6],[7,8],[9,10],[],[],[],[],...
--    takeWhile (not . null) (map (take 2) (iterate (drop 2) [5..10]))
--    ==> [[5,6],[7,8],[9,10]]

-- ----------------------------------------------------------------------------
-- Ejercicio 6.3. Definir, y comprobar, con QuickCheck las dos propiedades
-- que caracterizan a la función agrupa:
-- * todos los grupos tienen que tener la longitud determinada (salvo el
--   último que puede tener una longitud menor) y
-- * combinando todos los grupos se obtiene la lista inicial.
-- ---------------------------------------------------------------------------- 

-- La primera propiedad es
prop_AgrupaLongitud :: Int -> [Int] -> Property
prop_AgrupaLongitud n xs =
    n > 0 && not (null gs) ==>
      and [length g == n | g <- init gs] &&
      0 < length (last gs) && length (last gs) <= n
    where gs = agrupa n xs

-- La comprobación es
--    ghci> quickCheck prop_AgrupaLongitud
--    OK, passed 100 tests.

-- La segunda propiedad es
prop_AgrupaCombina :: Int -> [Int] -> Property
prop_AgrupaCombina n xs =
    n > 0 ==> concat (agrupa n xs) == xs 

-- La comprobación es
--    ghci> quickCheck prop_AgrupaCombina
--    OK, passed 100 tests.

-- ---------------------------------------------------------------------
-- Ejercicio 7.1. Sea la siguiente operación, aplicable a cualquier
-- número entero positivo:  
--    * Si el número es par, se divide entre 2.
--    * Si el número es impar, se multiplica por 3 y se suma 1.
-- Dado un número cualquiera, podemos considerar su órbita, es decir,
-- las imágenes sucesivas al iterar la función. Por ejemplo, la órbita
-- de 13 es
--    13, 40, 20, 10, 5, 16, 8, 4, 2, 1, 4, 2, 1,...
-- Si observamos este ejemplo, la órbita de 13 es periódica, es decir,
-- se repite indefinidamente a partir de un momento dado). La conjetura
-- de Collatz dice que siempre alcanzaremos el 1 para cualquier número
-- con el que comencemos. Ejemplos:  
--    * Empezando en n = 6 se obtiene 6, 3, 10, 5, 16, 8, 4, 2, 1.
--    * Empezando en n = 11 se obtiene: 11, 34, 17, 52, 26, 13, 40, 20,
--      10, 5, 16, 8, 4, 2, 1. 
--    * Empezando en n = 27, la sucesión tiene 112 pasos, llegando hasta
--      9232 antes de descender a 1:  27, 82, 41, 124, 62, 31, 94, 47,
--      142, 71, 214, 107, 322, 161, 484, 242, 121, 364, 182, 91, 274,
--      137, 412, 206, 103, 310, 155, 466, 233, 700, 350, 175, 526, 263,
--      790, 395, 1186, 593, 1780, 890, 445, 1336, 668, 334, 167, 502,
--      251, 754, 377, 1132, 566, 283, 850, 425, 1276, 638, 319, 958,
--      479, 1438, 719, 2158, 1079, 3238, 1619, 4858, 2429, 7288, 3644,
--      1822, 911, 2734, 1367, 4102, 2051, 6154, 3077, 9232, 4616, 2308,
--      1154, 577, 1732, 866, 433, 1300, 650, 325, 976, 488, 244, 122,
--      61, 184, 92, 46, 23, 70, 35, 106, 53, 160, 80, 40, 20, 10, 5,
--      16, 8, 4, 2, 1. 
-- 
-- Definir la función
--    siguiente :: Integer -> Integer
-- tal que (siguiente n) es el siguiente de n en la sucesión de
-- Collatz. Por ejemplo,
--    siguiente 13  ==  40
--    siguiente 40  ==  20
-- ---------------------------------------------------------------------

siguiente n | even n    = n `div` 2
            | otherwise = 3*n+1

-- ---------------------------------------------------------------------
-- Ejercicio 7.2. Definir, por recursión, la función 
--    collatz :: Integer -> [Integer]
-- tal que (collatz n) es la órbita de Collatz de n hasta alcanzar el
-- 1. Por ejemplo,
--    collatz 13  ==  [13,40,20,10,5,16,8,4,2,1]
-- ---------------------------------------------------------------------

collatz :: Integer -> [Integer]
collatz 1 = [1]
collatz n = n : collatz (siguiente n)

-- ---------------------------------------------------------------------
-- Ejercicio 7.3. Definir, sin recursión, la función 
--    collatz' :: Integer -> [Integer]
-- tal que (collatz' n) es la órbita de Collatz d n hasta alcanzar el
-- 1. Por ejemplo,
--    collatz' 13  ==  [13,40,20,10,5,16,8,4,2,1]
-- Indicación: Usar takeWhile e iterate.
-- ---------------------------------------------------------------------

collatz' :: Integer -> [Integer]
collatz' n = takeWhile (/=1) (iterate siguiente n) ++ [1]

-- ---------------------------------------------------------------------
-- Ejercicio 7.4. Definir la función
--    menorCollatzMayor :: Int -> Integer
-- tal que (menorCollatzMayor x) es el menor número cuya órbita de
-- Collatz tiene más de x elementos. Por ejemplo,
--    menorCollatzMayor 100  ==  27
-- ---------------------------------------------------------------------

menorCollatzMayor :: Int -> Integer
menorCollatzMayor x = head [y | y <- [1..], length (collatz y) > x]

-- ---------------------------------------------------------------------
-- Ejercicio 7.5. Definir la función
--    menorCollatzSupera :: Integer -> Integer
-- tal que (menorCollatzSupera x) es el menor número cuya órbita de
-- Collatz tiene algún elemento mayor que x. Por ejemplo,
--    menorCollatzSupera 100  ==  15
-- ---------------------------------------------------------------------

menorCollatzSupera :: Integer -> Integer
menorCollatzSupera x = 
    head [y | y <- [1..], maximum (collatz y) > x]

-- Otra definición alternativa es
menorCollatzSupera' :: Integer -> Integer
menorCollatzSupera' x = head [n | n <- [1..], t <- collatz' n, t > x]

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

-- ---------------------------------------------------------------------

-- Importación de librerías auxiliares

-- ---------------------------------------------------------------------

import Test.QuickCheck

-- ---------------------------------------------------------------------

-- Ejercicio 4. Definir, usando takeWhile y map, la función

-- potenciasMenores :: Int -> Int -> [Int]

-- tal que (potenciasMenores x y) es la lista de las potencias de x

-- menores que y. Por ejemplo,

-- potenciasMenores 2 1000 == [2,4,8,16,32,64,128,256,512]

-- ---------------------------------------------------------------------

potenciasMenores :: Int -> Int -> [Int]

potenciasMenores x y = takeWhile (<y) (map (x^) [1..])

-- ---------------------------------------------------------------------

-- Ejercicio 5a. (Problema 303 del proyecto Euler) Definir la función

-- multiplosRestringidos :: Int -> (Int -> Bool) -> [Int]

-- tal que (multiplosRestringidos n x) es la lista de los múltiplos de n

-- tales que todas sus dígitos verifican la propiedad p. Por ejemplo,

-- take 4 (multiplosRestringidos 5 (<=3)) == [10,20,30,100]

-- take 5 (multiplosRestringidos 3 (<=4)) == [3,12,21,24,30]

-- take 5 (multiplosRestringidos 3 even) == [6,24,42,48,60]

-- ---------------------------------------------------------------------

multiplosRestringidos :: Int -> (Int -> Bool) -> [Int]

multiplosRestringidos n p =

[y | y <- [n,2*n..], all p (digitos y)]

-- (digitos n) es la lista de las dígitos de n, Por ejemplo,

-- digitos 327 == [3,2,7]

digitos :: Int -> [Int]

digitos n = [read [x] | x <- show n]

-- ---------------------------------------------------------------------

-- Ejercicio 5b. Definir, por recursión, la función

-- itera :: (a -> a) -> a -> [a]

-- tal que (itera f x) es la lista cuyo primer elemento es x y los

-- siguientes elementos se calculan aplicando la función f al elemento

-- anterior. Por ejemplo,

-- ghci> itera (+1) 3

-- [3,4,5,6,7,8,9,10,11,12,{Interrupted!}

-- ghci> itera (*2) 1

-- [1,2,4,8,16,32,64,{Interrupted!}

-- ghci> itera (`div` 10) 1972

-- [1972,197,19,1,0,0,0,0,0,0,{Interrupted!}

-- Nota: La función repite es equivalente a la función iterate definida

-- en el preludio de Haskell.

-- ---------------------------------------------------------------------

itera :: (a -> a) -> a -> [a]

itera f x = x : itera f (f x)

-- ----------------------------------------------------------------------------

-- Ejercicio 6.1. Definir, por recursión, la función

-- agrupa :: Int -> [a] -> [[a]]

-- tal que (agrupa n xs) es la lista formada por listas de n elementos

-- consecutivos de la lista xs (salvo posiblemente la última que puede

-- tener menos de n elementos). Por ejemplo,

-- ghci> agrupa 2 [3,1,5,8,2,7]

-- [[3,1],[5,8],[2,7]]

-- ghci> agrupa 2 [3,1,5,8,2,7,9]

-- [[3,1],[5,8],[2,7],[9]]

-- ghci> agrupa 5 "todo necio confunde valor y precio"

-- ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]

-- ----------------------------------------------------------------------------

agrupa :: Int -> [a] -> [[a]]

agrupa n [] = []

agrupa n xs = take n xs : agrupa n (drop n xs)

-- ----------------------------------------------------------------------------

-- Ejercicio 6.2. Definir, de manera no recursiva, la función

-- agrupa' :: Int -> [a] -> [[a]]

-- tal que (agrupa' n xs) es la lista formada por listas de n elementos

-- consecutivos de la lista xs (salvo posiblemente la última que puede

-- tener menos de n elementos). Por ejemplo,

-- ghci> agrupa' 2 [3,1,5,8,2,7]

-- [[3,1],[5,8],[2,7]]

-- ghci> agrupa' 2 [3,1,5,8,2,7,9]

-- [[3,1],[5,8],[2,7],[9]]

-- ghci> agrupa' 5 "todo necio confunde valor y precio"

-- ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]

-- ----------------------------------------------------------------------------

agrupa' :: Int -> [a] -> [[a]]

agrupa' n = takeWhile (not . null)

. map (take n)

. iterate (drop n)

-- Puede verse su funcionamiento en el siguiente ejemplo,

-- iterate (drop 2) [5..10]

-- ==> [[5,6,7,8,9,10],[7,8,9,10],[9,10],[],[],...

-- map (take 2) (iterate (drop 2) [5..10])

-- ==> [[5,6],[7,8],[9,10],[],[],[],[],...

-- takeWhile (not . null) (map (take 2) (iterate (drop 2) [5..10]))

-- ==> [[5,6],[7,8],[9,10]]

-- ----------------------------------------------------------------------------

-- Ejercicio 6.3. Definir, y comprobar, con QuickCheck las dos propiedades

-- que caracterizan a la función agrupa:

-- * todos los grupos tienen que tener la longitud determinada (salvo el

-- último que puede tener una longitud menor) y

-- * combinando todos los grupos se obtiene la lista inicial.

-- ----------------------------------------------------------------------------

-- La primera propiedad es

prop_AgrupaLongitud :: Int -> [Int] -> Property

prop_AgrupaLongitud n xs =

n > 0 && not (null gs) ==>

and [length g == n | g <- init gs] &&

0 < length (last gs) && length (last gs) <= n

where gs = agrupa n xs

-- La comprobación es

-- ghci> quickCheck prop_AgrupaLongitud

-- OK, passed 100 tests.

-- La segunda propiedad es

prop_AgrupaCombina :: Int -> [Int] -> Property

prop_AgrupaCombina n xs =

n > 0 ==> concat (agrupa n xs) == xs

-- La comprobación es

-- ghci> quickCheck prop_AgrupaCombina

-- OK, passed 100 tests.

-- ---------------------------------------------------------------------

-- Ejercicio 7.1. Sea la siguiente operación, aplicable a cualquier

-- número entero positivo:

-- * Si el número es par, se divide entre 2.

-- * Si el número es impar, se multiplica por 3 y se suma 1.

-- Dado un número cualquiera, podemos considerar su órbita, es decir,

-- las imágenes sucesivas al iterar la función. Por ejemplo, la órbita

-- de 13 es

-- 13, 40, 20, 10, 5, 16, 8, 4, 2, 1, 4, 2, 1,...

-- Si observamos este ejemplo, la órbita de 13 es periódica, es decir,

-- se repite indefinidamente a partir de un momento dado). La conjetura

-- de Collatz dice que siempre alcanzaremos el 1 para cualquier número

-- con el que comencemos. Ejemplos:

-- * Empezando en n = 6 se obtiene 6, 3, 10, 5, 16, 8, 4, 2, 1.

-- * Empezando en n = 11 se obtiene: 11, 34, 17, 52, 26, 13, 40, 20,

-- 10, 5, 16, 8, 4, 2, 1.

-- * Empezando en n = 27, la sucesión tiene 112 pasos, llegando hasta

-- 9232 antes de descender a 1: 27, 82, 41, 124, 62, 31, 94, 47,

-- 142, 71, 214, 107, 322, 161, 484, 242, 121, 364, 182, 91, 274,

-- 137, 412, 206, 103, 310, 155, 466, 233, 700, 350, 175, 526, 263,

-- 790, 395, 1186, 593, 1780, 890, 445, 1336, 668, 334, 167, 502,

-- 251, 754, 377, 1132, 566, 283, 850, 425, 1276, 638, 319, 958,

-- 479, 1438, 719, 2158, 1079, 3238, 1619, 4858, 2429, 7288, 3644,

-- 1822, 911, 2734, 1367, 4102, 2051, 6154, 3077, 9232, 4616, 2308,

-- 1154, 577, 1732, 866, 433, 1300, 650, 325, 976, 488, 244, 122,

-- 61, 184, 92, 46, 23, 70, 35, 106, 53, 160, 80, 40, 20, 10, 5,

-- 16, 8, 4, 2, 1.

-- Definir la función

-- siguiente :: Integer -> Integer

-- tal que (siguiente n) es el siguiente de n en la sucesión de

-- Collatz. Por ejemplo,

-- siguiente 13 == 40

-- siguiente 40 == 20

-- ---------------------------------------------------------------------

siguiente n | even n = n `div` 2

| otherwise = 3*n+1

-- ---------------------------------------------------------------------

-- Ejercicio 7.2. Definir, por recursión, la función

-- collatz :: Integer -> [Integer]

-- tal que (collatz n) es la órbita de Collatz de n hasta alcanzar el

-- 1. Por ejemplo,

-- collatz 13 == [13,40,20,10,5,16,8,4,2,1]

-- ---------------------------------------------------------------------

collatz :: Integer -> [Integer]

collatz 1 = [1]

collatz n = n : collatz (siguiente n)

-- ---------------------------------------------------------------------

-- Ejercicio 7.3. Definir, sin recursión, la función

-- collatz' :: Integer -> [Integer]

-- tal que (collatz' n) es la órbita de Collatz d n hasta alcanzar el

-- 1. Por ejemplo,

-- collatz' 13 == [13,40,20,10,5,16,8,4,2,1]

-- Indicación: Usar takeWhile e iterate.

-- ---------------------------------------------------------------------

collatz' :: Integer -> [Integer]

collatz' n = takeWhile (/=1) (iterate siguiente n) ++ [1]

-- ---------------------------------------------------------------------

-- Ejercicio 7.4. Definir la función

-- menorCollatzMayor :: Int -> Integer

-- tal que (menorCollatzMayor x) es el menor número cuya órbita de

-- Collatz tiene más de x elementos. Por ejemplo,

-- menorCollatzMayor 100 == 27

-- ---------------------------------------------------------------------

menorCollatzMayor :: Int -> Integer

menorCollatzMayor x = head [y | y <- [1..], length (collatz y) > x]

-- ---------------------------------------------------------------------

-- Ejercicio 7.5. Definir la función

-- menorCollatzSupera :: Integer -> Integer

-- tal que (menorCollatzSupera x) es el menor número cuya órbita de

-- Collatz tiene algún elemento mayor que x. Por ejemplo,

-- menorCollatzSupera 100 == 15

-- ---------------------------------------------------------------------

menorCollatzSupera :: Integer -> Integer

menorCollatzSupera x =

head [y | y <- [1..], maximum (collatz y) > x]

-- Otra definición alternativa es

menorCollatzSupera' :: Integer -> Integer

menorCollatzSupera' x = head [n | n <- [1..], t <- collatz' n, t > x]

Los ejercicios de la relación 16, y sus soluciones, se muestran a continuación.

-- ---------------------------------------------------------------------
-- Ejercicio 1.1. Definir, usando la criba de Eratóstenes, la constante
--    primos :: Integral a => [a]
-- cuyo valor es la lista de los números primos. Por ejemplo,
--    take 10 primos  ==  [2,3,5,7,11,13,17,19,23,29]
-- ---------------------------------------------------------------------

primos :: Integral a => [a]
primos = criba [2..]
    where criba []     = []
          criba (n:ns) = n : criba (elimina n ns)
          elimina n xs = [x | x <- xs, x `mod` n /= 0]

-- ---------------------------------------------------------------------
-- Ejercicio 1.2. Definir la función
--    primo :: Integral a => a -> Bool
-- tal que (primo n) se verifica si n es primo. Por ejemplo,
--    primo 7  ==  True
--    primo 9  ==  False
-- ---------------------------------------------------------------------

primo :: Int -> Bool
primo n = head (dropWhile (<n) primos) == n

-- ---------------------------------------------------------------------
-- Ejercicio 6. Definir la función
--    sumaDeDosPrimos :: Int -> [(Int,Int)]
-- tal que (sumaDeDosPrimos n) es la lista de las distintas
-- descomposiciones de n como suma de dos números primos. Por ejemplo, 
--    sumaDeDosPrimos 30  ==  [(7,23),(11,19),(13,17)]
--    sumaDeDosPrimos 10  ==  [(3,7),(5,5)]
-- Calcular, usando la función sumaDeDosPrimos, el menor número que
-- puede escribirse de 10 formas distintas como suma de dos primos.
-- ---------------------------------------------------------------------

sumaDeDosPrimos :: Int -> [(Int,Int)]
sumaDeDosPrimos n = 
    [(x,n-x) | x <- primosN, x <= n-x, elem (n-x) primosN]
    where primosN = takeWhile (<=n) primos

-- El cálculo es
--    ghci> head [x | x <- [1..], length (sumaDeDosPrimos x) == 10]
--    114

-- ---------------------------------------------------------------------
-- Ejercicio 3. Definir la función
--    esProductoDeDosPrimos :: Int -> Bool
-- tal que (esProductoDeDosPrimos n) se verifica si n es el producto de
-- dos primos distintos. Por ejemplo,
--    esProductoDeDosPrimos 6  ==  True
--    esProductoDeDosPrimos 9  ==  False
-- ---------------------------------------------------------------------

esProductoDeDosPrimos :: Int -> Bool
esProductoDeDosPrimos n =
    [x | x <- primosN, 
         mod n x == 0, 
         div n x /= x, 
         elem (div n x) primosN] /= []
    where primosN = takeWhile (<=n) primos

-- ---------------------------------------------------------------------
-- Ejercicio 4.1. [Problema 37 del proyecto Euler] Un número primo es
-- truncable si los números que se obtienen eliminado cifras, de derecha
-- a izquierda, son primos. Por ejemplo, 599 es un primo truncable
-- porque 599, 59 y 5 son primos; en cambio, 577 es un primo no
-- truncable porque 57 no es primo.   
-- 
-- Definir la función 
--    primoTruncable :: Int -> Bool
-- tal que (primoTruncable x) se verifica si x es un primo truncable. 
-- Por ejemplo,
--    primoTruncable 599  ==  True
--    primoTruncable 577  ==  False
-- ---------------------------------------------------------------------

primoTruncable :: Int -> Bool
primoTruncable x 
    | x < 10    = primo x
    | otherwise = primo x && primoTruncable (x `div` 10)

-- ---------------------------------------------------------------------
-- Ejercicio 4.2. Definir la función
--    sumaPrimosTruncables :: Int -> Int
-- tal que (sumaPrimosTruncables n) es la suma de los n primeros primos
-- truncables. Por ejemplo,
--    sumaPrimosTruncables 10  ==  249
-- Calcular la suma de los 20 primos truncables.
-- ---------------------------------------------------------------------

sumaPrimosTruncables :: Int -> Int
sumaPrimosTruncables n = 
    sum (take n [x | x <- primos, primoTruncable x])

-- El cálculo es
--    ghci> sumaPrimosTruncables 20
--    2551

-- ---------------------------------------------------------------------

-- Ejercicio 1.1. Definir, usando la criba de Eratóstenes, la constante

-- primos :: Integral a => [a]

-- cuyo valor es la lista de los números primos. Por ejemplo,

-- take 10 primos == [2,3,5,7,11,13,17,19,23,29]

-- ---------------------------------------------------------------------

primos :: Integral a => [a]

primos = criba [2..]

where criba [] = []

criba (n:ns) = n : criba (elimina n ns)

elimina n xs = [x | x <- xs, x `mod` n /= 0]

-- ---------------------------------------------------------------------

-- Ejercicio 1.2. Definir la función

-- primo :: Integral a => a -> Bool

-- tal que (primo n) se verifica si n es primo. Por ejemplo,

-- primo 7 == True

-- primo 9 == False

-- ---------------------------------------------------------------------

primo :: Int -> Bool

primo n = head (dropWhile (<n) primos) == n

-- ---------------------------------------------------------------------

-- Ejercicio 6. Definir la función

-- sumaDeDosPrimos :: Int -> [(Int,Int)]

-- tal que (sumaDeDosPrimos n) es la lista de las distintas

-- descomposiciones de n como suma de dos números primos. Por ejemplo,

-- sumaDeDosPrimos 30 == [(7,23),(11,19),(13,17)]

-- sumaDeDosPrimos 10 == [(3,7),(5,5)]

-- Calcular, usando la función sumaDeDosPrimos, el menor número que

-- puede escribirse de 10 formas distintas como suma de dos primos.

-- ---------------------------------------------------------------------

sumaDeDosPrimos :: Int -> [(Int,Int)]

sumaDeDosPrimos n =

[(x,n-x) | x <- primosN, x <= n-x, elem (n-x) primosN]

where primosN = takeWhile (<=n) primos

-- El cálculo es

-- ghci> head [x | x <- [1..], length (sumaDeDosPrimos x) == 10]

-- 114

-- ---------------------------------------------------------------------

-- Ejercicio 3. Definir la función

-- esProductoDeDosPrimos :: Int -> Bool

-- tal que (esProductoDeDosPrimos n) se verifica si n es el producto de

-- dos primos distintos. Por ejemplo,

-- esProductoDeDosPrimos 6 == True

-- esProductoDeDosPrimos 9 == False

-- ---------------------------------------------------------------------

esProductoDeDosPrimos :: Int -> Bool

esProductoDeDosPrimos n =

[x | x <- primosN,

mod n x == 0,

div n x /= x,

elem (div n x) primosN] /= []

where primosN = takeWhile (<=n) primos

-- ---------------------------------------------------------------------

-- Ejercicio 4.1. [Problema 37 del proyecto Euler] Un número primo es

-- truncable si los números que se obtienen eliminado cifras, de derecha

-- a izquierda, son primos. Por ejemplo, 599 es un primo truncable

-- porque 599, 59 y 5 son primos; en cambio, 577 es un primo no

-- truncable porque 57 no es primo.

-- Definir la función

-- primoTruncable :: Int -> Bool

-- tal que (primoTruncable x) se verifica si x es un primo truncable.

-- Por ejemplo,

-- primoTruncable 599 == True

-- primoTruncable 577 == False

-- ---------------------------------------------------------------------

primoTruncable :: Int -> Bool

primoTruncable x

| x < 10 = primo x

| otherwise = primo x && primoTruncable (x `div` 10)

-- ---------------------------------------------------------------------

-- Ejercicio 4.2. Definir la función

-- sumaPrimosTruncables :: Int -> Int

-- tal que (sumaPrimosTruncables n) es la suma de los n primeros primos

-- truncables. Por ejemplo,

-- sumaPrimosTruncables 10 == 249

-- Calcular la suma de los 20 primos truncables.

-- ---------------------------------------------------------------------

sumaPrimosTruncables :: Int -> Int

sumaPrimosTruncables n =

sum (take n [x | x <- primos, primoTruncable x])

-- El cálculo es

-- ghci> sumaPrimosTruncables 20

-- 2551

Se puede imprimir o compartir con