I1M2011: Operaciones con el TAD de los polinomios en Haskell (3)

En la clase de hoy de Informática de 1º del Grado en Matemáticas hemos continuado estudiando la implementación en Haskell de operaciones con los polinomios utilizando las implementaciones del TAD de los polinomios estudiadas en las clases anteriores.

En los ejercicios se usan las siguientes librerías:

PolRepTDA: Implementación de los polinomios mediante tipos de datos algebraicos.
PolRepDispersa: Implementación de los polinomios mediante listas dispersas.
PolRepDensa: Implementación de los polinomios mediante listas densas.
PolOperaciones: Operaciones con el TAD de los polinomios.

Los ejercicios, y sus soluciones, se muestran a continuación.

-- ---------------------------------------------------------------------
-- Importación de librerías                                           --
-- ---------------------------------------------------------------------

import PolOperaciones
import Test.QuickCheck
import Data.Ratio

-- ---------------------------------------------------------------------
-- Ejercicio 1. Definir la función
--    creaPolDispersa :: Num a => [a] -> Polinomio a
-- tal que (creaPolDispersa xs) es el polinomio cuya representación
-- dispersa es xs. Por ejemplo,
--    creaPolDispersa [7,0,0,4,0,3]  ==  7*x^5 + 4*x^2 + 3
-- ---------------------------------------------------------------------

creaPolDispersa :: Num a => [a] -> Polinomio a
creaPolDispersa []     = polCero
creaPolDispersa (x:xs) = consPol (length xs) x (creaPolDispersa xs)

-- ---------------------------------------------------------------------
-- Ejercicio 2. Definir la función
--    creaPolDensa :: Num a => [(Int,a)] -> Polinomio a
-- tal que (creaPolDensa xs) es el polinomio cuya representación
-- densa es xs. Por ejemplo,
--    creaPolDensa [(5,7),(4,2),(3,0)]  ==  7*x^5 + 2*x^4
-- ---------------------------------------------------------------------

creaPolDensa :: Num a => [(Int,a)] -> Polinomio a
creaPolDensa [] = polCero
creaPolDensa ((n,a):ps) = consPol n a (creaPolDensa ps)

-- ---------------------------------------------------------------------
-- Nota. En el resto de la sucesión se usará en los ejemplos los
-- los polinomios que se definen a continuación.
-- ---------------------------------------------------------------------

pol1, pol2, pol3 :: Num a => Polinomio a
pol1 = creaPolDensa [(5,1),(2,5),(1,4)]
pol2 = creaPolDispersa [2,3]
pol3 = creaPolDensa [(7,2),(4,5),(2,5)]

pol4, pol5, pol6 :: Polinomio Rational 
pol4 = creaPolDensa [(4,3),(2,5),(0,3)]
pol5 = creaPolDensa [(2,6),(1,2)]
pol6 = creaPolDensa [(2,8),(1,14),(0,3)]

-- ---------------------------------------------------------------------
-- Ejercicio 3. Definir la función
--    densa :: Num a => Polinomio a -> [(Int,a)]
-- tal que (densa p) es la representación densa del polinomio p. Por
-- ejemplo, 
--    pol1        ==  x^5 + 5*x^2 + 4*x
--    densa pol1  ==  [(5,1),(2,5),(1,4)]
-- ---------------------------------------------------------------------

densa :: Num a => Polinomio a -> [(Int,a)]
densa p | esPolCero p = []
        | otherwise   = (grado p, coefLider p) : densa (restoPol p)

-- ---------------------------------------------------------------------
-- Ejercicio 4. Definir la función
--    densaAdispersa :: Num a => [(Int,a)] -> [a]
-- tal que (densaAdispersa ps) es la representación dispersa del
-- polinomio cuya representación densa es ps. Por ejemplo,
--    densaAdispersa [(5,1),(2,5),(1,4)]  ==  [1,0,0,5,4,0]
-- ---------------------------------------------------------------------

densaAdispersa :: Num a => [(Int,a)] -> [a]
densaAdispersa [] = []
densaAdispersa [(n,a)] = a : replicate n 0
densaAdispersa ((n,a):(m,b):ps) = 
    a : (replicate (n-m-1) 0) ++ densaAdispersa ((m,b):ps)

-- ---------------------------------------------------------------------
-- Ejercicio 5. Definir la función
--    dispersa :: Num a => Polinomio a -> [a]
-- tal que (dispersa p) es la representación dispersa del polinomio
-- p. Por ejemplo,
--    pol1           ==  x^5 + 5*x^2 + 4*x
--    dispersa pol1  ==  [1,0,0,5,4,0]
-- ---------------------------------------------------------------------

dispersa :: Num a => Polinomio a -> [a]
dispersa = densaAdispersa . densa

-- ---------------------------------------------------------------------
-- Ejercicio 6. Definir la función
--    coeficiente :: Num a => Int -> Polinomio a -> a
-- tal que (coeficiente k p) es el coeficiente del término de grado k
-- del polinomio p. Por ejemplo,
--    pol1                ==  x^5 + 5*x^2 + 4*x
--    coeficiente 2 pol1  ==  5
--    coeficiente 3 pol1  ==  0
-- ---------------------------------------------------------------------

coeficiente :: Num a => Int -> Polinomio a -> a
coeficiente k p | k == n                 = coefLider p
                | k > grado (restoPol p) = 0
                | otherwise              = coeficiente k (restoPol p)
                where n = grado p

-- Otra definición equivalente es
coeficiente' :: Num a => Int -> Polinomio a -> a
coeficiente' k p = busca k (densa p)
    where busca k ps = head ([a | (n,a) <- ps, n == k] ++ [0])

-- ---------------------------------------------------------------------
-- Ejercicio 7. Definir la función
--    coeficientes :: Num a => Polinomio a -> [a]
-- tal que (coeficientes p) es la lista de los coeficientes del
-- polinomio p. Por ejemplo,
--    pol1               ==  x^5 + 5*x^2 + 4*x
--    coeficientes pol1  ==  [1,0,0,5,4,0]
-- ---------------------------------------------------------------------

coeficientes :: Num a => Polinomio a -> [a]
coeficientes p = [coeficiente k p | k <-[n,n-1..0]]
    where n = grado p

-- Una definición equivalente es
coeficientes' :: Num a => Polinomio a -> [a]
coeficientes' = dispersa

-- ---------------------------------------------------------------------
-- Ejercicio 8. Definir la función
--    potencia :: Num a => Polinomio a -> Int -> Polinomio a
-- tal que (potencia p n) es la potencia n-ésima del polinomio p. Por
-- ejemplo, 
--    pol2             ==  2*x + 3
--    potencia pol2 2  ==  4*x^2 + 12*x + 9
--    potencia pol2 3  ==  8*x^3 + 36*x^2 + 54*x + 27
-- ---------------------------------------------------------------------

potencia :: Num a => Polinomio a -> Int -> Polinomio a
potencia p 0 = polUnidad
potencia p n = multPol p (potencia p (n-1))

-- ---------------------------------------------------------------------
-- Ejercicio 9. Mejorar la definición de potencia definiendo la función
--    potenciaM :: Num a => Polinomio a -> Int -> Polinomio a
-- tal que (potenciaM p n) es la potencia n-ésima del polinomio p,
-- utilizando las siguientes propiedades:
--    * Si n es par,   entonces x^n = (x^2)^(n/2)
--    * Si n es impar, entonces x^n = x * (x^2)^((n-1)/2)
-- Por ejemplo, 
--    pol2              ==  2*x + 3
--    potenciaM pol2 2  ==  4*x^2 + 12*x + 9
--    potenciaM pol2 3  ==  8*x^3 + 36*x^2 + 54*x + 27
-- ---------------------------------------------------------------------

potenciaM :: Num a => Polinomio a -> Int -> Polinomio a
potenciaM p 0 = polUnidad
potenciaM p n
    | even n    = potenciaM (multPol p p) (n `div` 2)
    | otherwise = multPol p (potenciaM (multPol p p) ((n-1) `div` 2))

-- ---------------------------------------------------------------------
-- Ejercicio 10. Definir la función
--    integral :: Fractional a => Polinomio a -> Polinomio a
-- tal que (integral p) es la integral del polinomio p cuyos coefientes
-- son números racionales. Por ejemplo,
--    ghci> pol3
--    2*x^7 + 5*x^4 + 5*x^2
--    ghci> integral pol3
--    0.25*x^8 + x^5 + 1.6666666666666667*x^3
--    ghci> integral pol3 :: Polinomio Rational
--    1 % 4*x^8 + x^5 + 5 % 3*x^3
-- ---------------------------------------------------------------------

integral :: Fractional a => Polinomio a -> Polinomio a
integral p 
    | esPolCero p = polCero
    | otherwise   = consPol (n+1) (b / (fromIntegral (n+1))) (integral r)
    where n = grado p
          b = coefLider p
          r = restoPol p

-- ---------------------------------------------------------------------
-- Ejercicio 11. Definir la función
--    integralDef :: Fractional t => Polinomio t -> t -> t -> t          
-- tal que (integralDef p a b) es la integral definida del polinomio p
-- cuyos coefientes son números racionales. Por ejemplo,
--    ghci> integralDef pol3 0 1
--    2.916666666666667
--    ghci> integralDef pol3 0 1 :: Rational
--    35 % 12
-- ---------------------------------------------------------------------

integralDef :: Fractional t => Polinomio t -> t -> t -> t          
integralDef p a b = (valor q b) - (valor q a)
    where q = integral p

-- ---------------------------------------------------------------------
-- Ejercicio 12. Definir la función
--    multEscalar :: Num a => a -> Polinomio a -> Polinomio a
-- tal que (multEscalar c p) es el polinomio obtenido multiplicando el
-- número c por el polinomio p. Por ejemplo, 
--    pol2                    ==  2*x + 3
--    multEscalar 4 pol2      ==  8*x + 12
--    multEscalar (1%4) pol2  ==  1 % 2*x + 3 % 4
-- ---------------------------------------------------------------------

multEscalar :: Num a => a -> Polinomio a -> Polinomio a
multEscalar c p 
  | esPolCero p = polCero
  | otherwise   = consPol n (c*b) (multEscalar c r)
  where n = grado p
        b = coefLider p
        r = restoPol p

-- ---------------------------------------------------------------------
-- Ejercicio 13. Definir la función
--    cociente:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a
-- tal que (cociente p q) es el cociente de la división de p entre
-- q. Por ejemplo, 
--    pol4  ==  3 % 1*x^4 + 5 % 1*x^2 + 3 % 1
--    pol5  ==  6 % 1*x^2 + 2 % 1*x
--    cociente pol4 pol5  ==  1 % 2*x^2 + (-1) % 6*x + 8 % 9
-- ---------------------------------------------------------------------

cociente:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a
cociente p q
    | n2 == 0   = multEscalar (1/a2) p
    | n1 < n2   = polCero
    | otherwise =  consPol n' a' (cociente p' q)
    where n1 = grado p
          a1 = coefLider p
          n2 = grado q
          a2 = coefLider q
          n' = n1-n2
          a' = a1/a2
          p' = restaPol p (multPorTerm (creaTermino n' a') q)

-- ---------------------------------------------------------------------
-- Ejercicio 14. Definir la función
--    resto:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a
-- tal que (resto p q) es el resto de la división de p entre q. Por
-- ejemplo,  
--    pol4  ==  3 % 1*x^4 + 5 % 1*x^2 + 3 % 1
--    pol5  ==  6 % 1*x^2 + 2 % 1*x
--    resto pol4 pol5  ==  (-16) % 9*x + 3 % 1
-- ---------------------------------------------------------------------

resto :: Fractional a => Polinomio a -> Polinomio a -> Polinomio a
resto p q = restaPol p (multPol (cociente p q) q)

-- ---------------------------------------------------------------------
-- Ejercicio 15. Definir la función
--    divisiblePol :: Fractional a => Polinomio a -> Polinomio a -> Bool
-- tal que (divisiblePol p q) se verifica si el polinomio p es divisible
-- por el polinomio q. Por ejemplo,
--    pol6  ==  8 % 1*x^2 + 14 % 1*x + 3 % 1
--    pol2  ==  2*x + 3
--    pol5  ==  6 % 1*x^2 + 2 % 1*x
--    divisiblePol pol6 pol2  ==  True
--    divisiblePol pol6 pol5  ==  False
-- ---------------------------------------------------------------------

divisiblePol :: Fractional a => Polinomio a -> Polinomio a -> Bool
divisiblePol p q = esPolCero (resto p q)

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

219

220

221

222

223

224

225

226

227

228

229

230

231

232

233

234

235

236

237

238

239

240

241

242

243

244

245

246

247

248

249

250

251

252

253

254

255

256

257

258

259

260

261

-- ---------------------------------------------------------------------

-- Importación de librerías --

-- ---------------------------------------------------------------------

import PolOperaciones

import Test.QuickCheck

import Data.Ratio

-- ---------------------------------------------------------------------

-- Ejercicio 1. Definir la función

-- creaPolDispersa :: Num a => [a] -> Polinomio a

-- tal que (creaPolDispersa xs) es el polinomio cuya representación

-- dispersa es xs. Por ejemplo,

-- creaPolDispersa [7,0,0,4,0,3] == 7*x^5 + 4*x^2 + 3

-- ---------------------------------------------------------------------

creaPolDispersa :: Num a => [a] -> Polinomio a

creaPolDispersa [] = polCero

creaPolDispersa (x:xs) = consPol (length xs) x (creaPolDispersa xs)

-- ---------------------------------------------------------------------

-- Ejercicio 2. Definir la función

-- creaPolDensa :: Num a => [(Int,a)] -> Polinomio a

-- tal que (creaPolDensa xs) es el polinomio cuya representación

-- densa es xs. Por ejemplo,

-- creaPolDensa [(5,7),(4,2),(3,0)] == 7*x^5 + 2*x^4

-- ---------------------------------------------------------------------

creaPolDensa :: Num a => [(Int,a)] -> Polinomio a

creaPolDensa [] = polCero

creaPolDensa ((n,a):ps) = consPol n a (creaPolDensa ps)

-- ---------------------------------------------------------------------

-- Nota. En el resto de la sucesión se usará en los ejemplos los

-- los polinomios que se definen a continuación.

-- ---------------------------------------------------------------------

pol1, pol2, pol3 :: Num a => Polinomio a

pol1 = creaPolDensa [(5,1),(2,5),(1,4)]

pol2 = creaPolDispersa [2,3]

pol3 = creaPolDensa [(7,2),(4,5),(2,5)]

pol4, pol5, pol6 :: Polinomio Rational

pol4 = creaPolDensa [(4,3),(2,5),(0,3)]

pol5 = creaPolDensa [(2,6),(1,2)]

pol6 = creaPolDensa [(2,8),(1,14),(0,3)]

-- ---------------------------------------------------------------------

-- Ejercicio 3. Definir la función

-- densa :: Num a => Polinomio a -> [(Int,a)]

-- tal que (densa p) es la representación densa del polinomio p. Por

-- ejemplo,

-- pol1 == x^5 + 5*x^2 + 4*x

-- densa pol1 == [(5,1),(2,5),(1,4)]

-- ---------------------------------------------------------------------

densa :: Num a => Polinomio a -> [(Int,a)]

densa p | esPolCero p = []

| otherwise = (grado p, coefLider p) : densa (restoPol p)

-- ---------------------------------------------------------------------

-- Ejercicio 4. Definir la función

-- densaAdispersa :: Num a => [(Int,a)] -> [a]

-- tal que (densaAdispersa ps) es la representación dispersa del

-- polinomio cuya representación densa es ps. Por ejemplo,

-- densaAdispersa [(5,1),(2,5),(1,4)] == [1,0,0,5,4,0]

-- ---------------------------------------------------------------------

densaAdispersa :: Num a => [(Int,a)] -> [a]

densaAdispersa [] = []

densaAdispersa [(n,a)] = a : replicate n 0

densaAdispersa ((n,a):(m,b):ps) =

a : (replicate (n-m-1) 0) ++ densaAdispersa ((m,b):ps)

-- ---------------------------------------------------------------------

-- Ejercicio 5. Definir la función

-- dispersa :: Num a => Polinomio a -> [a]

-- tal que (dispersa p) es la representación dispersa del polinomio

-- p. Por ejemplo,

-- pol1 == x^5 + 5*x^2 + 4*x

-- dispersa pol1 == [1,0,0,5,4,0]

-- ---------------------------------------------------------------------

dispersa :: Num a => Polinomio a -> [a]

dispersa = densaAdispersa . densa

-- ---------------------------------------------------------------------

-- Ejercicio 6. Definir la función

-- coeficiente :: Num a => Int -> Polinomio a -> a

-- tal que (coeficiente k p) es el coeficiente del término de grado k

-- del polinomio p. Por ejemplo,

-- pol1 == x^5 + 5*x^2 + 4*x

-- coeficiente 2 pol1 == 5

-- coeficiente 3 pol1 == 0

-- ---------------------------------------------------------------------

coeficiente :: Num a => Int -> Polinomio a -> a

coeficiente k p | k == n = coefLider p

| k > grado (restoPol p) = 0

| otherwise = coeficiente k (restoPol p)

where n = grado p

-- Otra definición equivalente es

coeficiente' :: Num a => Int -> Polinomio a -> a

coeficiente' k p = busca k (densa p)

where busca k ps = head ([a | (n,a) <- ps, n == k] ++ [0])

-- ---------------------------------------------------------------------

-- Ejercicio 7. Definir la función

-- coeficientes :: Num a => Polinomio a -> [a]

-- tal que (coeficientes p) es la lista de los coeficientes del

-- polinomio p. Por ejemplo,

-- pol1 == x^5 + 5*x^2 + 4*x

-- coeficientes pol1 == [1,0,0,5,4,0]

-- ---------------------------------------------------------------------

coeficientes :: Num a => Polinomio a -> [a]

coeficientes p = [coeficiente k p | k <-[n,n-1..0]]

where n = grado p

-- Una definición equivalente es

coeficientes' :: Num a => Polinomio a -> [a]

coeficientes' = dispersa

-- ---------------------------------------------------------------------

-- Ejercicio 8. Definir la función

-- potencia :: Num a => Polinomio a -> Int -> Polinomio a

-- tal que (potencia p n) es la potencia n-ésima del polinomio p. Por

-- ejemplo,

-- pol2 == 2*x + 3

-- potencia pol2 2 == 4*x^2 + 12*x + 9

-- potencia pol2 3 == 8*x^3 + 36*x^2 + 54*x + 27

-- ---------------------------------------------------------------------

potencia :: Num a => Polinomio a -> Int -> Polinomio a

potencia p 0 = polUnidad

potencia p n = multPol p (potencia p (n-1))

-- ---------------------------------------------------------------------

-- Ejercicio 9. Mejorar la definición de potencia definiendo la función

-- potenciaM :: Num a => Polinomio a -> Int -> Polinomio a

-- tal que (potenciaM p n) es la potencia n-ésima del polinomio p,

-- utilizando las siguientes propiedades:

-- * Si n es par, entonces x^n = (x^2)^(n/2)

-- * Si n es impar, entonces x^n = x * (x^2)^((n-1)/2)

-- Por ejemplo,

-- pol2 == 2*x + 3

-- potenciaM pol2 2 == 4*x^2 + 12*x + 9

-- potenciaM pol2 3 == 8*x^3 + 36*x^2 + 54*x + 27

-- ---------------------------------------------------------------------

potenciaM :: Num a => Polinomio a -> Int -> Polinomio a

potenciaM p 0 = polUnidad

potenciaM p n

| even n = potenciaM (multPol p p) (n `div` 2)

| otherwise = multPol p (potenciaM (multPol p p) ((n-1) `div` 2))

-- ---------------------------------------------------------------------

-- Ejercicio 10. Definir la función

-- integral :: Fractional a => Polinomio a -> Polinomio a

-- tal que (integral p) es la integral del polinomio p cuyos coefientes

-- son números racionales. Por ejemplo,

-- ghci> pol3

-- 2*x^7 + 5*x^4 + 5*x^2

-- ghci> integral pol3

-- 0.25*x^8 + x^5 + 1.6666666666666667*x^3

-- ghci> integral pol3 :: Polinomio Rational

-- 1 % 4*x^8 + x^5 + 5 % 3*x^3

-- ---------------------------------------------------------------------

integral :: Fractional a => Polinomio a -> Polinomio a

integral p

| esPolCero p = polCero

| otherwise = consPol (n+1) (b / (fromIntegral (n+1))) (integral r)

where n = grado p

b = coefLider p

r = restoPol p

-- ---------------------------------------------------------------------

-- Ejercicio 11. Definir la función

-- integralDef :: Fractional t => Polinomio t -> t -> t -> t

-- tal que (integralDef p a b) es la integral definida del polinomio p

-- cuyos coefientes son números racionales. Por ejemplo,

-- ghci> integralDef pol3 0 1

-- 2.916666666666667

-- ghci> integralDef pol3 0 1 :: Rational

-- 35 % 12

-- ---------------------------------------------------------------------

integralDef :: Fractional t => Polinomio t -> t -> t -> t

integralDef p a b = (valor q b) - (valor q a)

where q = integral p

-- ---------------------------------------------------------------------

-- Ejercicio 12. Definir la función

-- multEscalar :: Num a => a -> Polinomio a -> Polinomio a

-- tal que (multEscalar c p) es el polinomio obtenido multiplicando el

-- número c por el polinomio p. Por ejemplo,

-- pol2 == 2*x + 3

-- multEscalar 4 pol2 == 8*x + 12

-- multEscalar (1%4) pol2 == 1 % 2*x + 3 % 4

-- ---------------------------------------------------------------------

multEscalar :: Num a => a -> Polinomio a -> Polinomio a

multEscalar c p

| esPolCero p = polCero

| otherwise = consPol n (c*b) (multEscalar c r)

where n = grado p

b = coefLider p

r = restoPol p

-- ---------------------------------------------------------------------

-- Ejercicio 13. Definir la función

-- cociente:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a

-- tal que (cociente p q) es el cociente de la división de p entre

-- q. Por ejemplo,

-- pol4 == 3 % 1*x^4 + 5 % 1*x^2 + 3 % 1

-- pol5 == 6 % 1*x^2 + 2 % 1*x

-- cociente pol4 pol5 == 1 % 2*x^2 + (-1) % 6*x + 8 % 9

-- ---------------------------------------------------------------------

cociente:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a

cociente p q

| n2 == 0 = multEscalar (1/a2) p

| n1 < n2 = polCero

| otherwise = consPol n' a' (cociente p' q)

where n1 = grado p

a1 = coefLider p

n2 = grado q

a2 = coefLider q

n' = n1-n2

a' = a1/a2

p' = restaPol p (multPorTerm (creaTermino n' a') q)

-- ---------------------------------------------------------------------

-- Ejercicio 14. Definir la función

-- resto:: Fractional a => Polinomio a -> Polinomio a -> Polinomio a

-- tal que (resto p q) es el resto de la división de p entre q. Por

-- ejemplo,

-- pol4 == 3 % 1*x^4 + 5 % 1*x^2 + 3 % 1

-- pol5 == 6 % 1*x^2 + 2 % 1*x

-- resto pol4 pol5 == (-16) % 9*x + 3 % 1

-- ---------------------------------------------------------------------

resto :: Fractional a => Polinomio a -> Polinomio a -> Polinomio a

resto p q = restaPol p (multPol (cociente p q) q)

-- ---------------------------------------------------------------------

-- Ejercicio 15. Definir la función

-- divisiblePol :: Fractional a => Polinomio a -> Polinomio a -> Bool

-- tal que (divisiblePol p q) se verifica si el polinomio p es divisible

-- por el polinomio q. Por ejemplo,

-- pol6 == 8 % 1*x^2 + 14 % 1*x + 3 % 1

-- pol2 == 2*x + 3

-- pol5 == 6 % 1*x^2 + 2 % 1*x

-- divisiblePol pol6 pol2 == True

-- divisiblePol pol6 pol5 == False

-- ---------------------------------------------------------------------

divisiblePol :: Fractional a => Polinomio a -> Polinomio a -> Bool

divisiblePol p q = esPolCero (resto p q)

Se puede imprimir o compartir con