I1M2011: Ejercicios con listas infinitas (2)

En la clase de hoy de Informática de 1º del Grado en Matemáticas se han explicado las soluciones de los ejercicios de la 15ª relación sobre listas infinitas y evaluación perezosa. En concreto, se estudian funciones para calcular

la lista de las potencias de un número menores que otro dado,
la lista obtenida repitiendo un elemento infinitas veces,
la lista obtenida repitiendo un elemento un número finito de veces,
la cadena obtenida cada elemento tantas veces como indica su posición,
la aplicación iterada de una función a un elemento,
la lista de las sublistas de longitud dada y
la sucesión de Collatz.

Estos ejercicios corresponden al tema 10.

Los ejercicios, y sus soluciones, se muestran a continuación.

-- ---------------------------------------------------------------------
-- Importación de librerías auxiliares                                  
-- ---------------------------------------------------------------------

import Test.QuickCheck

-- ---------------------------------------------------------------------
-- Ejercicio 1. Definir, usando takeWhile y map, la función
--    potenciasMenores :: Int -> Int -> [Int]
-- tal que (potenciasMenores x y) es la lista de las potencias de x
-- menores que y. Por ejemplo,
--    potenciasMenores 2 1000  ==  [2,4,8,16,32,64,128,256,512]
-- ---------------------------------------------------------------------

potenciasMenores :: Int -> Int -> [Int]
potenciasMenores x y = takeWhile (<y) (map (x^) [1..])

-- ---------------------------------------------------------------------
-- Ejercicio 2. Definir, por recursión y comprensión, la función 
--    repite :: a -> [a]
-- tal que (repite x) es la lista infinita cuyos elementos son x. Por
-- ejemplo, 
--    repite 5           == [5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,...
--    take 3 (repite 5)  ==  [5,5,5]
-- Nota: La función repite es equivalente a la función repeat definida
-- en el preludio de Haskell.
-- ---------------------------------------------------------------------

-- Por recursión:
repite :: a -> [a]
repite x = x : repite x

-- Por comprensión:
repite' x = [x | _ <- [1..]]

-- ---------------------------------------------------------------------
-- Ejercicio 3. Definir, por recursión y por comprensión, la función 
--    repiteFinita :: Int-> a -> [a]
-- tal que (repite n x) es la lista con n elementos iguales a x. Por
-- ejemplo, 
--    repiteFinita 3 5  ==  [5,5,5]
-- Nota: La función repite es equivalente a la función replicate definida
-- en el preludio de Haskell.
-- ---------------------------------------------------------------------

-- Por recursión:
repiteFinita :: Int -> a -> [a]
repiteFinita 0 x = []
repiteFinita n x = x : repiteFinita (n-1) x

-- Por comprensión:
repiteFinita' :: Int -> a -> [a]
repiteFinita' n x = [x | _ <- [1..n]]

-- También se puede definir usando repite
repiteFinita2 :: Int -> a -> [a]
repiteFinita2 n x = take n (repite x)

-- ---------------------------------------------------------------------
-- Ejercicio 4. Se considera la función
--    eco :: String -> String
-- tal que (eco xs) es la cadena obtenida a partir de la cadena xs
-- repitiendo cada elemento tantas veces como indica su posición: el
-- primer elemento se repite 1 vez, el segundo 2 veces y así
-- sucesivamente. Por ejemplo, 
--    eco "abcd"  ==  "abbcccdddd"
-- 1. Escribir una definición 'no recursiva' de la función eco.
-- 2. Escribir una definición 'recursiva' de la función eco.
-- ---------------------------------------------------------------------

-- Una definición no recursiva es
ecoNR :: String -> String
ecoNR xs = concat [replicate i x | (i,x) <- zip [1..] xs]

-- Una definición recursiva es
ecoR :: String -> String
ecoR xs = aux 1 xs
    where aux n [] = []
          aux n (x:xs) = replicate n x ++ aux (n+1) xs

-- ---------------------------------------------------------------------
-- Ejercicio 5. Definir, por recursión, la función
--    itera :: (a -> a) -> a -> [a]
-- tal que (itera f x) es la lista cuyo primer elemento es x y los
-- siguientes elementos se calculan aplicando la función f al elemento
-- anterior. Por ejemplo, 
--    Main> itera (+1) 3
--    [3,4,5,6,7,8,9,10,11,12,{Interrupted!}
--    Main> itera (*2) 1
--    [1,2,4,8,16,32,64,{Interrupted!}
--    Main> itera (`div` 10) 1972
--    [1972,197,19,1,0,0,0,0,0,0,{Interrupted!}
-- Nota: La función repite es equivalente a la función iterate definida
-- en el preludio de Haskell.
-- ---------------------------------------------------------------------

itera :: (a -> a) -> a -> [a]
itera f x = x : itera f (f x)

-- ----------------------------------------------------------------------------
-- Ejercicio 6, Definir la función
--    agrupa :: Int -> [a] -> [[a]]
-- tal que (agrupa n xs) es la lista formada por listas de n elementos
-- conscutivos de la lista xs (salvo posiblemente la última que puede
-- tener menos de n elementos). Por ejemplo, 
--    Main> agrupa 2 [3,1,5,8,2,7]
--    [[3,1],[5,8],[2,7]]
--    Main> agrupa 2 [3,1,5,8,2,7,9] 
--    [[3,1],[5,8],[2,7],[9]]
--    Main> agrupa 5 "todo necio confunde valor y precio"
--    ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]
-- ---------------------------------------------------------------------------- 

-- Una definición recursiva de agrupa es
agrupa :: Int -> [a] -> [[a]]
agrupa n [] = []
agrupa n xs = take n xs : agrupa n (drop n xs)

-- Una definición no recursiva es
agrupa' :: Int -> [a] -> [[a]]
agrupa' n = takeWhile (not . null)
          . map (take n)
          . iterate (drop n)

-- Puede verse su funcionamiento en el siguiente ejemplo,
--    iterate (drop 2) [5..10]  
--    ==> [[5,6,7,8,9,10],[7,8,9,10],[9,10],[],[],...
--    map (take 2) (iterate (drop 2) [5..10])
--    ==> [[5,6],[7,8],[9,10],[],[],[],[],...
--    takeWhile (not . null) (map (take 2) (iterate (drop 2) [5..10]))
--    ==> [[5,6],[7,8],[9,10]]

-- ----------------------------------------------------------------------------
-- Ejercicio 7. Definir, y comprobar, con QuickCheck las dos propiedades
-- que caracterizan a la función agrupa:
-- * todos los grupos tienen que tener la longitud determinada (salvo el
--   último que puede tener una longitud menor) y
-- * combinando todos los grupos se obtiene la lista inicial.
-- ---------------------------------------------------------------------------- 

-- La primera propiedad es
prop_AgrupaLongitud :: Int -> [Int] -> Property
prop_AgrupaLongitud n xs =
    n > 0 && not (null gs) ==>
      and [length g == n | g <- init gs] &&
      0 < length (last gs) && length (last gs) <= n
    where gs = agrupa n xs

-- La comprobación es
--    Main> quickCheck prop_AgrupaLongitud
--    OK, passed 100 tests.

-- La segunda propiedad es
prop_AgrupaCombina :: Int -> [Int] -> Property
prop_AgrupaCombina n xs =
    n > 0 ==> concat (agrupa n xs) == xs 

-- La comprobación es
--    Main> quickCheck prop_AgrupaCombina
--    OK, passed 100 tests.

-- ---------------------------------------------------------------------
-- Sea la siguiente operación, aplicable a cualquier número entero
-- positivo:  
--    * Si el número es par, se divide entre 2.
--    * Si el número es impar, se multiplica por 3 y se suma 1.
-- Dado un número cualquiera, podemos considerar su órbita, es decir,
-- las imágenes sucesivas al iterar la función. Por ejemplo, la órbita
-- de 13 es
--    13, 40, 20, 10, 5, 16, 8, 4, 2, 1, 4, 2, 1,...
-- Si observamos este ejemplo, la órbita de 13 es periódica, es decir,
-- se repite indefinidamente a partir de un momento dado). La conjetura
-- de Collatz dice que siempre alcanzaremos el 1 para cualquier número
-- con el que comencemos. Ejemplos:  
--    * Empezando en n = 6 se obtiene 6, 3, 10, 5, 16, 8, 4, 2, 1.
--    * Empezando en n = 11 se obtiene: 11, 34, 17, 52, 26, 13, 40, 20,
--      10, 5, 16, 8, 4, 2, 1. 
--    * Empezando en n = 27, la sucesión tiene 112 pasos, llegando hasta
--      9232 antes de descender a 1:  27, 82, 41, 124, 62, 31, 94, 47,
--      142, 71, 214, 107, 322, 161, 484, 242, 121, 364, 182, 91, 274,
--      137, 412, 206, 103, 310, 155, 466, 233, 700, 350, 175, 526, 263,
--      790, 395, 1186, 593, 1780, 890, 445, 1336, 668, 334, 167, 502,
--      251, 754, 377, 1132, 566, 283, 850, 425, 1276, 638, 319, 958,
--      479, 1438, 719, 2158, 1079, 3238, 1619, 4858, 2429, 7288, 3644,
--      1822, 911, 2734, 1367, 4102, 2051, 6154, 3077, 9232, 4616, 2308,
--      1154, 577, 1732, 866, 433, 1300, 650, 325, 976, 488, 244, 122,
--      61, 184, 92, 46, 23, 70, 35, 106, 53, 160, 80, 40, 20, 10, 5,
--      16, 8, 4, 2, 1. 

-- ---------------------------------------------------------------------
-- Ejercicio 8. Definir la función
--    siguiente :: Integer -> Integer
-- tal que (siguiente n) es el siguiente de n en la sucesión de
-- Collatz. Por ejemplo,
--    siguiente 13  ==  40
--    siguiente 40  ==  20
-- ---------------------------------------------------------------------

siguiente n | even n    = n `div` 2
            | otherwise = 3*n+1

-- ---------------------------------------------------------------------
-- Ejercicio 9. Definir, por recursión, la función 
--    collatz :: Integer -> [Integer]
-- tal que (collatz n) es la órbita de Collatz d n hasta alcanzar el
-- 1. Por ejemplo,
--    collatz 13  ==  [13,40,20,10,5,16,8,4,2,1]
-- ---------------------------------------------------------------------

collatz :: Integer -> [Integer]
collatz 1 = [1]
collatz n = n : collatz (siguiente n)

-- ---------------------------------------------------------------------
-- Ejercicio 10. Definir, sin recursión, la función 
--    collatz' :: Integer -> [Integer]
-- tal que (collatz' n) es la órbita de Collatz d n hasta alcanzar el
-- 1. Por ejemplo,
--    collatz' 13  ==  [13,40,20,10,5,16,8,4,2,1]
-- Indicación: Usar takeWhile e iterate.
-- ---------------------------------------------------------------------

collatz' :: Integer -> [Integer]
collatz' n = (takeWhile (/=1) (iterate siguiente n)) ++ [1]

-- ---------------------------------------------------------------------
-- Ejercicio 11. Definir la función
--    menorCollatzMayor :: Int -> Integer
-- tal que (menorCollatzMayor x) es el menor número cuya órbita de
-- Collatz tiene más de x elementos. Por ejemplo,
--    menorCollatzMayor 100  ==  27
-- ---------------------------------------------------------------------

menorCollatzMayor :: Int -> Integer
menorCollatzMayor x = head [y | y <- [1..], length (collatz y) > x]

-- ---------------------------------------------------------------------
-- Ejercicio 12. Definir la función
--    menorCollatzSupera :: Integer -> Integer
-- tal que (menorCollatzSupera x) es el menor número cuya órbita de
-- Collatz tiene algún elemento mayor que x. Por ejemplo,
--    menorCollatzSupera 100  ==  15
-- ---------------------------------------------------------------------

menorCollatzSupera :: Integer -> Integer
menorCollatzSupera x = 
    head [y | y <- [1..], maximum (collatz y) > x]

-- Otra definición alternativa es
menorCollatzSupera' :: Integer -> Integer
menorCollatzSupera' x = head [n | n <- [1..], t <- collatz' n, t > x]

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

219

220

221

222

223

224

225

226

227

228

229

230

231

232

233

234

235

236

237

238

239

240

241

242

243

244

245

246

247

248

249

250

251

-- ---------------------------------------------------------------------

-- Importación de librerías auxiliares

-- ---------------------------------------------------------------------

import Test.QuickCheck

-- ---------------------------------------------------------------------

-- Ejercicio 1. Definir, usando takeWhile y map, la función

-- potenciasMenores :: Int -> Int -> [Int]

-- tal que (potenciasMenores x y) es la lista de las potencias de x

-- menores que y. Por ejemplo,

-- potenciasMenores 2 1000 == [2,4,8,16,32,64,128,256,512]

-- ---------------------------------------------------------------------

potenciasMenores :: Int -> Int -> [Int]

potenciasMenores x y = takeWhile (<y) (map (x^) [1..])

-- ---------------------------------------------------------------------

-- Ejercicio 2. Definir, por recursión y comprensión, la función

-- repite :: a -> [a]

-- tal que (repite x) es la lista infinita cuyos elementos son x. Por

-- ejemplo,

-- repite 5 == [5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,...

-- take 3 (repite 5) == [5,5,5]

-- Nota: La función repite es equivalente a la función repeat definida

-- en el preludio de Haskell.

-- ---------------------------------------------------------------------

-- Por recursión:

repite :: a -> [a]

repite x = x : repite x

-- Por comprensión:

repite' x = [x | _ <- [1..]]

-- ---------------------------------------------------------------------

-- Ejercicio 3. Definir, por recursión y por comprensión, la función

-- repiteFinita :: Int-> a -> [a]

-- tal que (repite n x) es la lista con n elementos iguales a x. Por

-- ejemplo,

-- repiteFinita 3 5 == [5,5,5]

-- Nota: La función repite es equivalente a la función replicate definida

-- en el preludio de Haskell.

-- ---------------------------------------------------------------------

-- Por recursión:

repiteFinita :: Int -> a -> [a]

repiteFinita 0 x = []

repiteFinita n x = x : repiteFinita (n-1) x

-- Por comprensión:

repiteFinita' :: Int -> a -> [a]

repiteFinita' n x = [x | _ <- [1..n]]

-- También se puede definir usando repite

repiteFinita2 :: Int -> a -> [a]

repiteFinita2 n x = take n (repite x)

-- ---------------------------------------------------------------------

-- Ejercicio 4. Se considera la función

-- eco :: String -> String

-- tal que (eco xs) es la cadena obtenida a partir de la cadena xs

-- repitiendo cada elemento tantas veces como indica su posición: el

-- primer elemento se repite 1 vez, el segundo 2 veces y así

-- sucesivamente. Por ejemplo,

-- eco "abcd" == "abbcccdddd"

-- 1. Escribir una definición 'no recursiva' de la función eco.

-- 2. Escribir una definición 'recursiva' de la función eco.

-- ---------------------------------------------------------------------

-- Una definición no recursiva es

ecoNR :: String -> String

ecoNR xs = concat [replicate i x | (i,x) <- zip [1..] xs]

-- Una definición recursiva es

ecoR :: String -> String

ecoR xs = aux 1 xs

where aux n [] = []

aux n (x:xs) = replicate n x ++ aux (n+1) xs

-- ---------------------------------------------------------------------

-- Ejercicio 5. Definir, por recursión, la función

-- itera :: (a -> a) -> a -> [a]

-- tal que (itera f x) es la lista cuyo primer elemento es x y los

-- siguientes elementos se calculan aplicando la función f al elemento

-- anterior. Por ejemplo,

-- Main> itera (+1) 3

-- [3,4,5,6,7,8,9,10,11,12,{Interrupted!}

-- Main> itera (*2) 1

-- [1,2,4,8,16,32,64,{Interrupted!}

-- Main> itera (`div` 10) 1972

-- [1972,197,19,1,0,0,0,0,0,0,{Interrupted!}

-- Nota: La función repite es equivalente a la función iterate definida

-- en el preludio de Haskell.

-- ---------------------------------------------------------------------

itera :: (a -> a) -> a -> [a]

itera f x = x : itera f (f x)

-- ----------------------------------------------------------------------------

-- Ejercicio 6, Definir la función

-- agrupa :: Int -> [a] -> [[a]]

-- tal que (agrupa n xs) es la lista formada por listas de n elementos

-- conscutivos de la lista xs (salvo posiblemente la última que puede

-- tener menos de n elementos). Por ejemplo,

-- Main> agrupa 2 [3,1,5,8,2,7]

-- [[3,1],[5,8],[2,7]]

-- Main> agrupa 2 [3,1,5,8,2,7,9]

-- [[3,1],[5,8],[2,7],[9]]

-- Main> agrupa 5 "todo necio confunde valor y precio"

-- ["todo ","necio"," conf","unde ","valor"," y pr","ecio"]

-- ----------------------------------------------------------------------------

-- Una definición recursiva de agrupa es

agrupa :: Int -> [a] -> [[a]]

agrupa n [] = []

agrupa n xs = take n xs : agrupa n (drop n xs)

-- Una definición no recursiva es

agrupa' :: Int -> [a] -> [[a]]

agrupa' n = takeWhile (not . null)

. map (take n)

. iterate (drop n)

-- Puede verse su funcionamiento en el siguiente ejemplo,

-- iterate (drop 2) [5..10]

-- ==> [[5,6,7,8,9,10],[7,8,9,10],[9,10],[],[],...

-- map (take 2) (iterate (drop 2) [5..10])

-- ==> [[5,6],[7,8],[9,10],[],[],[],[],...

-- takeWhile (not . null) (map (take 2) (iterate (drop 2) [5..10]))

-- ==> [[5,6],[7,8],[9,10]]

-- ----------------------------------------------------------------------------

-- Ejercicio 7. Definir, y comprobar, con QuickCheck las dos propiedades

-- que caracterizan a la función agrupa:

-- * todos los grupos tienen que tener la longitud determinada (salvo el

-- último que puede tener una longitud menor) y

-- * combinando todos los grupos se obtiene la lista inicial.

-- ----------------------------------------------------------------------------

-- La primera propiedad es

prop_AgrupaLongitud :: Int -> [Int] -> Property

prop_AgrupaLongitud n xs =

n > 0 && not (null gs) ==>

and [length g == n | g <- init gs] &&

0 < length (last gs) && length (last gs) <= n

where gs = agrupa n xs

-- La comprobación es

-- Main> quickCheck prop_AgrupaLongitud

-- OK, passed 100 tests.

-- La segunda propiedad es

prop_AgrupaCombina :: Int -> [Int] -> Property

prop_AgrupaCombina n xs =

n > 0 ==> concat (agrupa n xs) == xs

-- La comprobación es

-- Main> quickCheck prop_AgrupaCombina

-- OK, passed 100 tests.

-- ---------------------------------------------------------------------

-- Sea la siguiente operación, aplicable a cualquier número entero

-- positivo:

-- * Si el número es par, se divide entre 2.

-- * Si el número es impar, se multiplica por 3 y se suma 1.

-- Dado un número cualquiera, podemos considerar su órbita, es decir,

-- las imágenes sucesivas al iterar la función. Por ejemplo, la órbita

-- de 13 es

-- 13, 40, 20, 10, 5, 16, 8, 4, 2, 1, 4, 2, 1,...

-- Si observamos este ejemplo, la órbita de 13 es periódica, es decir,

-- se repite indefinidamente a partir de un momento dado). La conjetura

-- de Collatz dice que siempre alcanzaremos el 1 para cualquier número

-- con el que comencemos. Ejemplos:

-- * Empezando en n = 6 se obtiene 6, 3, 10, 5, 16, 8, 4, 2, 1.

-- * Empezando en n = 11 se obtiene: 11, 34, 17, 52, 26, 13, 40, 20,

-- 10, 5, 16, 8, 4, 2, 1.

-- * Empezando en n = 27, la sucesión tiene 112 pasos, llegando hasta

-- 9232 antes de descender a 1: 27, 82, 41, 124, 62, 31, 94, 47,

-- 142, 71, 214, 107, 322, 161, 484, 242, 121, 364, 182, 91, 274,

-- 137, 412, 206, 103, 310, 155, 466, 233, 700, 350, 175, 526, 263,

-- 790, 395, 1186, 593, 1780, 890, 445, 1336, 668, 334, 167, 502,

-- 251, 754, 377, 1132, 566, 283, 850, 425, 1276, 638, 319, 958,

-- 479, 1438, 719, 2158, 1079, 3238, 1619, 4858, 2429, 7288, 3644,

-- 1822, 911, 2734, 1367, 4102, 2051, 6154, 3077, 9232, 4616, 2308,

-- 1154, 577, 1732, 866, 433, 1300, 650, 325, 976, 488, 244, 122,

-- 61, 184, 92, 46, 23, 70, 35, 106, 53, 160, 80, 40, 20, 10, 5,

-- 16, 8, 4, 2, 1.

-- ---------------------------------------------------------------------

-- Ejercicio 8. Definir la función

-- siguiente :: Integer -> Integer

-- tal que (siguiente n) es el siguiente de n en la sucesión de

-- Collatz. Por ejemplo,

-- siguiente 13 == 40

-- siguiente 40 == 20

-- ---------------------------------------------------------------------

siguiente n | even n = n `div` 2

| otherwise = 3*n+1

-- ---------------------------------------------------------------------

-- Ejercicio 9. Definir, por recursión, la función

-- collatz :: Integer -> [Integer]

-- tal que (collatz n) es la órbita de Collatz d n hasta alcanzar el

-- 1. Por ejemplo,

-- collatz 13 == [13,40,20,10,5,16,8,4,2,1]

-- ---------------------------------------------------------------------

collatz :: Integer -> [Integer]

collatz 1 = [1]

collatz n = n : collatz (siguiente n)

-- ---------------------------------------------------------------------

-- Ejercicio 10. Definir, sin recursión, la función

-- collatz' :: Integer -> [Integer]

-- tal que (collatz' n) es la órbita de Collatz d n hasta alcanzar el

-- 1. Por ejemplo,

-- collatz' 13 == [13,40,20,10,5,16,8,4,2,1]

-- Indicación: Usar takeWhile e iterate.

-- ---------------------------------------------------------------------

collatz' :: Integer -> [Integer]

collatz' n = (takeWhile (/=1) (iterate siguiente n)) ++ [1]

-- ---------------------------------------------------------------------

-- Ejercicio 11. Definir la función

-- menorCollatzMayor :: Int -> Integer

-- tal que (menorCollatzMayor x) es el menor número cuya órbita de

-- Collatz tiene más de x elementos. Por ejemplo,

-- menorCollatzMayor 100 == 27

-- ---------------------------------------------------------------------

menorCollatzMayor :: Int -> Integer

menorCollatzMayor x = head [y | y <- [1..], length (collatz y) > x]

-- ---------------------------------------------------------------------

-- Ejercicio 12. Definir la función

-- menorCollatzSupera :: Integer -> Integer

-- tal que (menorCollatzSupera x) es el menor número cuya órbita de

-- Collatz tiene algún elemento mayor que x. Por ejemplo,

-- menorCollatzSupera 100 == 15

-- ---------------------------------------------------------------------

menorCollatzSupera :: Integer -> Integer

menorCollatzSupera x =

head [y | y <- [1..], maximum (collatz y) > x]

-- Otra definición alternativa es

menorCollatzSupera' :: Integer -> Integer

menorCollatzSupera' x = head [n | n <- [1..], t <- collatz' n, t > x]

Se puede imprimir o compartir con