Relación 2

header {* R2: Razonamiento sobre programas en Isabelle/HOL *}

theory R2
imports Main 
begin

text {* --------------------------------------------------------------- 
  Ejercicio 1. Definir la función
     sumaImpares :: nat ⇒ nat
  tal que (sumaImpares n) es la suma de los n primeros números
  impares. Por ejemplo,
     sumaImpares 5  =  25
  ------------------------------------------------------------------ *}

-- "angfraalv jospalhid marsoldia2"
fun sumaImpares :: "nat ⇒ nat" where
  "sumaImpares 0       = 0" |
  "sumaImpares (Suc n) = ((2*(Suc n)) - 1) + sumaImpares n"
 

value "sumaImpares 5" -- "= 25"

text {* --------------------------------------------------------------- 
  Ejercicio 2. Demostrar que 
     sumaImpares n = n*n
  ------------------------------------------------------------------- *}

-- "angfraalv"
lemma "sumaImpares n = n*n"
by (induct n) simp_all

-- "jospalhid marsoldia2"
lemma "sumaImpares n = n*n"
by (induct n) auto

text {* --------------------------------------------------------------- 
  Ejercicio 3. Definir la función
     sumaPotenciasDeDosMasUno :: nat ⇒ nat
  tal que 
     (sumaPotenciasDeDosMasUno n) = 1 + 2^0 + 2^1 + 2^2 + ... + 2^n. 
  Por ejemplo, 
     sumaPotenciasDeDosMasUno 3  =  16
  ------------------------------------------------------------------ *}

-- "angfraalv jospalhid marsoldia2"
fun sumaPotenciasDeDosMasUno :: "nat ⇒ nat" where
   "sumaPotenciasDeDosMasUno 0       = 2 " |
   "sumaPotenciasDeDosMasUno (Suc n) = sumaPotenciasDeDosMasUno n + 2^(Suc n)"

value "sumaPotenciasDeDosMasUno 3" -- "= 16"

text {* --------------------------------------------------------------- 
  Ejercicio 4. Demostrar que 
     sumaPotenciasDeDosMasUno n = 2^(n+1)
  ------------------------------------------------------------------- *}

-- "angfraalv"
lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
by (induct n) simp_all

-- "jospalhid marsoldia2"
lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
by (induct n) auto

text {* --------------------------------------------------------------- 
  Ejercicio 5. Definir la función
     copia :: nat ⇒ 'a ⇒ 'a list
  tal que (copia n x) es la lista formado por n copias del elemento
  x. Por ejemplo, 
     copia 3 x = [x,x,x]
  ------------------------------------------------------------------ *}

-- "angfraalv marsoldia2"
fun copia :: "nat ⇒ 'a ⇒ 'a list" where
  "copia 0       x = []" |
  "copia (Suc n) x = (copia n x)@[x]"

value "copia 3 x" -- "= [x,x,x]"

-- "jospalhid"
fun copia2 :: "nat ⇒ 'a ⇒ 'a list" where
  "copia2 0 _       = []"|
  "copia2 (Suc n) x = x#copia2 n x"

value "copia2 3 x" -- "=[x,x,x]"

text {* --------------------------------------------------------------- 
  Ejercicio 6. Definir la función
     todos :: ('a ⇒ bool) ⇒ 'a list ⇒ bool
  tal que (todos p xs) se verifica si todos los elementos de xs cumplen
  la propiedad p. Por ejemplo,
     todos (λx. x>(1::nat)) [2,6,4] = True
     todos (λx. x>(2::nat)) [2,6,4] = False
  Nota: La conjunción se representa por ∧
  ----------------------------------------------------------------- *}

-- "angfraalv jospalhid marsoldia2"
fun todos :: "('a ⇒ bool) ⇒ 'a list ⇒ bool" where
  "todos _ []     = True " |
  "todos p (x#xs) = (p x ∧ todos p xs)"

value "todos (λx. x>(1::nat)) [2,6,4]" -- "= True"
value "todos (λx. x>(2::nat)) [2,6,4]" -- "= False"

text {* --------------------------------------------------------------- 
  Ejercicio 7. Demostrar que todos los elementos de (copia n x) son
  iguales a x. 
  ------------------------------------------------------------------- *}

-- "jospalhid marsoldia2"
lemma "todos (λy. y=x) (copia2 n x)"
by (induct n) auto

text {* --------------------------------------------------------------- 
  Ejercicio 8. Definir la función
    factR :: nat ⇒ nat
  tal que (factR n) es el factorial de n. Por ejemplo,
    factR 4 = 24
  ------------------------------------------------------------------ *}

--"angfraalv jospalhid marsoldia2"
fun factR :: "nat ⇒ nat" where
  "factR 0       = 1" |
  "factR (Suc n) = Suc n * factR n"

value "factR 4" -- "= 24"

text {* --------------------------------------------------------------- 
  Ejercicio 9. Se considera la siguiente definición iterativa de la
  función factorial 
     factI :: "nat ⇒ nat" where
     factI n = factI' n 1
     
     factI' :: nat ⇒ nat ⇒ nat" where
     factI' 0       x = x
     factI' (Suc n) x = factI' n (Suc n)*x
  Demostrar que, para todo n y todo x, se tiene 
     factI' n x = x * factR n
  ------------------------------------------------------------------- *}

fun factI' :: "nat ⇒ nat ⇒ nat" where
  "factI' 0       x = x"
| "factI' (Suc n) x = factI' n (Suc n)*x"

fun factI :: "nat ⇒ nat" where
  "factI n = factI' n 1"

value "factI 4" -- "= 24"
     
-- "jospalhid"
lemma fact: "factI' n x = x * factR n"
by (induct n arbitrary: x) auto

text {* --------------------------------------------------------------- 
  Ejercicio 10. Demostrar que
     factI n = factR n
  ------------------------------------------------------------------- *}

-- "jospalhid"
corollary "factI n = factR n"
by (simp add:fact)

text {* --------------------------------------------------------------- 
  Ejercicio 11. Definir, recursivamente y sin usar (@), la función
     amplia :: 'a list ⇒ 'a ⇒ 'a list
  tal que (amplia xs y) es la lista obtenida añadiendo el elemento y al
  final de la lista xs. Por ejemplo,
     amplia [d,a] t = [d,a,t]
  ------------------------------------------------------------------ *}

-- "angfraalv marsoldia2"
fun amplia :: "'a list ⇒ 'a ⇒ 'a list" where
  "amplia []     y = y#[]" |
  "amplia (x#xs) y = x#(amplia xs y)"

-- "jospalhid"
fun amplia2 :: "'a list ⇒ 'a ⇒ 'a list" where
  "amplia2 [] y     = [y]"|
  "amplia2 (x#xs) y = x#(amplia xs y)"

value "amplia [d,a] t" -- "= [d,a,t]"

text {* --------------------------------------------------------------- 
  Ejercicio 12. Demostrar que 
     amplia xs y = xs @ [y]
  ------------------------------------------------------------------- *}

-- "jospalhid"
lemma "amplia xs y = xs @ [y]"
by (induct xs) auto

end