Acciones

Relación 3

De Razonamiento automático (2014-15)

Revisión del 11:06 11 nov 2014 de Juacorvic (discusión | contribuciones)
header {* R3: Razonamiento sobre programas en Isabelle/HOL *}

theory R3
imports Main 
begin

text {* --------------------------------------------------------------- 
  Ejercicio 1. Definir la función
     sumaImpares :: nat ⇒ nat
  tal que (sumaImpares n) es la suma de los n primeros números
  impares. Por ejemplo,
     sumaImpares 5  =  25
  ------------------------------------------------------------------ *}
(* Pedrosrei: como no veo a nadie animarse pongo las dos primeras a ver si sirve de ayuda: *)

-- "davoremar juacorvic"

fun sumaImpares :: "nat ⇒ nat" where
  "sumaImpares 0 = 0"
| "sumaImpares (Suc n) = (2*n+1) + sumaImpares n"


value "sumaImpares 5" -- "= 25"

text {* --------------------------------------------------------------- 
  Ejercicio 2. Demostrar que 
     sumaImpares n = n*n
  ------------------------------------------------------------------- *}
(* Pedrosrei: lo dejo de menos a más estructurado *)

lemma "sumaImpares n = n*n"
apply (induct n) apply auto
done

-- "davoremar juacorvic"
 
lemma "sumaImpares n = n*n"
by (induct n) auto
 
lemma "sumaImpares n = n*n"
proof (induct n)
  show "sumaImpares 0 = 0 * 0" by simp
next
  fix n
  assume HI: "sumaImpares n = n * n"
  thus "sumaImpares (Suc n) = Suc n * Suc n" by simp
qed

-- "davoremar juacorvic"

lemma "sumaImpares n = n*n"
proof (induct n)
  show "sumaImpares 0 = 0 * 0" by simp
next
  fix n
  assume HI: "sumaImpares n = n*n"
  have "sumaImpares (Suc n) = sumaImpares n + (2*n + 1)" by simp
  also have "... = n*n + 2*n + 1" using HI by simp
  also have "... = (n + 1) * (n + 1)" by simp
  finally show "sumaImpares (Suc n) = Suc n * Suc n" by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 3. Definir la función
     sumaPotenciasDeDosMasUno :: nat ⇒ nat
  tal que 
     (sumaPotenciasDeDosMasUno n) = 1 + 2^0 + 2^1 + 2^2 + ... + 2^n. 
  Por ejemplo, 
     sumaPotenciasDeDosMasUno 3  =  16
  ------------------------------------------------------------------ *}

-- "davoremar juacorvic"

fun sumaPotenciasDeDosMasUno :: "nat ⇒ nat" where
  "sumaPotenciasDeDosMasUno 0 = 2"
| "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n) + sumaPotenciasDeDosMasUno n"

value "sumaPotenciasDeDosMasUno 3" -- "= 16"

text {* --------------------------------------------------------------- 
  Ejercicio 4. Demostrar que 
     sumaPotenciasDeDosMasUno n = 2^(n+1)
  ------------------------------------------------------------------- *}

-- "davoremar juacorvic"

lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
by (induct n) auto

-- "davoremar juacorvic"

lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
proof (induct n)
  show "sumaPotenciasDeDosMasUno 0 = 2^(0+1)" by simp
next
  fix n
  assume HI: "sumaPotenciasDeDosMasUno n = 2^(n+1)"
  have "sumaPotenciasDeDosMasUno (Suc n) = sumaPotenciasDeDosMasUno n + 2^(Suc n)" by simp
  also have "... = 2^(n+1) + 2^(Suc n)" using HI by simp
  also have "... = 2^(Suc n + 1)" by simp
  finally show "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n + 1)" by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 5. Definir la función
     copia :: nat ⇒ 'a ⇒ 'a list
  tal que (copia n x) es la lista formado por n copias del elemento
  x. Por ejemplo, 
     copia 3 x = [x,x,x]
  ------------------------------------------------------------------ *}

-- "davoremar juacorvic"

fun copia :: "nat ⇒ 'a ⇒ 'a list" where
  "copia 0 x = []"
| "copia (Suc n) x = x # copia n x"

value "copia 3 x" -- "= [x,x,x]"

text {* --------------------------------------------------------------- 
  Ejercicio 6. Definir la función
     todos :: ('a ⇒ bool) ⇒ 'a list ⇒ bool
  tal que (todos p xs) se verifica si todos los elementos de xs cumplen
  la propiedad p. Por ejemplo,
     todos (λx. x>(1::nat)) [2,6,4] = True
     todos (λx. x>(2::nat)) [2,6,4] = False
  Nota: La conjunción se representa por ∧
  ----------------------------------------------------------------- *}

-- "davoremar juacorvic"

fun todos :: "('a ⇒ bool) ⇒ 'a list ⇒ bool" where
  "todos p [] = True"
| "todos p (x#xs) = ((p x) ∧ (todos p xs))"

value "todos (λx. x>(1::nat)) [2,6,4]" -- "= True"
value "todos (λx. x>(2::nat)) [2,6,4]" -- "= False"

text {* --------------------------------------------------------------- 
  Ejercicio 7. Demostrar que todos los elementos de (copia n x) son
  iguales a x. 
  ------------------------------------------------------------------- *}

-- "davoremar juacorvic"

lemma "todos (λy. y=x) (copia n x)"
by (induct n) auto


-- "juacorvic"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
  show "todos (λy. y=x) (copia 0 x)" by simp
  fix n
    assume HI: "todos (λy. y=x) (copia n x)"
    thus  "todos (λy. y=x) (copia (Suc n) x)" by simp
qed

-- "davoremar"

lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
  show "todos (λy. y=x) (copia 0 x)" by simp
next
  fix n
  assume HI: "todos (λy. y=x) (copia n x)"
  have "todos (λy. y=x) (copia (Suc n) x) = todos (λy. y=x) (x#(copia n x))" by simp
  also have "... = todos (λy. y=x) (copia n x)" by simp
  finally show "todos (λy. y=x) (copia (Suc n) x)" using HI by simp
qed

-- "juacorvic"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
  show "todos (λy. y=x) (copia 0 x)" by simp
  next
  fix n
  assume HI: "todos (λy. y=x) (copia n x)"
  have "todos (λy. y=x) (copia (Suc n) x) = todos (λy. y=x)  (x # (copia n x))" by simp
  also have "...=todos (λy. y=x)[x]" using HI by simp
  finally show "todos (λy. y=x) (copia (Suc n) x)" using HI by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 8. Definir la función
    factR :: nat ⇒ nat
  tal que (factR n) es el factorial de n. Por ejemplo,
    factR 4 = 24
  ------------------------------------------------------------------ *}

-- "davoremar"

fun factR :: "nat ⇒ nat" where
  "factR 0 = 1"
| "factR (Suc n) = (Suc n) * factR n"

value "factR 4" -- "= 24"

text {* --------------------------------------------------------------- 
  Ejercicio 9. Se considera la siguiente definición iterativa de la
  función factorial 
     factI :: "nat ⇒ nat" where
     factI n = factI' n 1
     
     factI' :: nat ⇒ nat ⇒ nat" where
     factI' 0       x = x
     factI' (Suc n) x = factI' n (Suc n)*x
  Demostrar que, para todo n y todo x, se tiene 
     factI' n x = x * factR n
  ------------------------------------------------------------------- *}

fun factI' :: "nat ⇒ nat ⇒ nat" where
  "factI' 0       x = x"
| "factI' (Suc n) x = factI' n (Suc n)*x"

fun factI :: "nat ⇒ nat" where
  "factI n = factI' n 1"

value "factI 4" -- "= 24"
     
-- "davoremar"

lemma fact1: "factI' n x = x* factR n"
by (induct n arbitrary: x) auto
 
-- "davoremar"

lemma fact: "factI' n x = x * factR n"
proof (induct n arbitrary: x)
  show "⋀x. factI' 0 x = x * factR 0" by simp
next
  fix n x
  assume HI: "⋀x. factI' n x = x * factR n"
  have "factI' (Suc n) x = factI' n (Suc n)*x" by simp
  also have "... = x * factI' n (Suc n)" by simp
  also have "... = x * ((Suc n) * factR n)" using HI by simp
  also have "... = x * factR (Suc n)" by simp
  finally show "factI' (Suc n) x = x * factR (Suc n)" by simp
qed

(* Pedrosrei: También podemos prescindir de arbitrary x *)

lemma fact2: "factI' n x = x * factR n"
proof (induct n)
  show "factI' 0 x = x * factR 0" by simp
next
  fix n
  assume HI: "factI' n x = x * factR n"
  show "factI' (Suc n) x = x * factR (Suc n)"
  proof -
    have "factI' (Suc n) x = (factI' n (Suc n))*x" by simp
    also have " ... = ((Suc n) * factR n) * x" using HI fact by simp
-- "Si usamos auto: finally show ?thesis by auto    "
    also have " ... = x * factR (Suc n)" by simp
    finally show ?thesis .
  qed
qed

text {* --------------------------------------------------------------- 
  Ejercicio 10. Demostrar que
     factI n = factR n
  ------------------------------------------------------------------- *}

-- "davoremar"

corollary "factI n = factR n"
by (simp add: fact)

-- "davoremar"

corollary "factI n = factR n"
proof -
  have "factI n = factI' n 1" by simp
  also have "... = 1 * factR n" by (simp add: fact)
  finally show "factI n = factR n" by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 11. Definir, recursivamente y sin usar (@), la función
     amplia :: 'a list ⇒ 'a ⇒ 'a list
  tal que (amplia xs y) es la lista obtenida añadiendo el elemento y al
  final de la lista xs. Por ejemplo,
     amplia [d,a] t = [d,a,t]
  ------------------------------------------------------------------ *}

-- "davoremar"

fun amplia :: "'a list ⇒ 'a ⇒ 'a list" where
  "amplia [] y = [y]"
| "amplia (x#xs) y = x # (amplia xs y)"

value "amplia [d,a] t" -- "= [d,a,t]"

text {* --------------------------------------------------------------- 
  Ejercicio 12. Demostrar que 
     amplia xs y = xs @ [y]
  ------------------------------------------------------------------- *}

-- "davoremar"

lemma "amplia xs y = xs @ [y]"
by (induct xs) auto

-- "davoremar"

lemma "amplia xs y = xs @ [y]"
proof (induct xs)
  show "amplia [] y = [] @ [y]" by simp
next
  fix x xs
  assume HI: "amplia xs y = xs @ [y]"
  have "amplia (x#xs) y = x # amplia xs y" by simp
  also have "... = x # (xs @ [y])" using HI by simp
  also have "... = (x#xs) @ [y]" by simp (*Pedrosrei: prescindible *)
  finally show "amplia (x#xs) y = (x#xs) @ [y]" by simp
qed

end
Obtenido de «https://www.glc.us.es/~jalonso/RA2014/index.php?title=Relación_3&oldid=66»