Razonamiento automático (2014-15) - Contribuciones del usuario [es]

Relación 3

2014-11-13T14:49:48Z

Danrodcha:

<source lang="isar">
header {* R3: Razonamiento sobre programas en Isabelle/HOL *}

theory R3
imports Main
begin

text {* ---------------------------------------------------------------
Ejercicio 1. Definir la función
sumaImpares :: nat ⇒ nat
tal que (sumaImpares n) es la suma de los n primeros números
impares. Por ejemplo,
sumaImpares 5 = 25
------------------------------------------------------------------ *}

-- "davoremar juacorvic jeshorcob domcadgom danrodcha"
fun sumaImpares :: "nat ⇒ nat" where
"sumaImpares 0 = 0"
| "sumaImpares (Suc n) = (2*n+1) + sumaImpares n"

-- "marnajgom"
fun sumaImpares2 :: "nat ⇒ nat" where
"sumaImpares2 0 = 0"
| "sumaImpares2 (Suc n) = (Suc n) + n + sumaImpares2 n"

-- "jeshorcob"
fun sumaImpares3 :: "nat ⇒ nat" where
"sumaImpares3 n = foldr (λ x y. y + (2 * x) + 1) (upt 0 n) 0"

(* Esta definición en principio es más eficiente pero a la hora de
demostrar se complica todo. Estaría bien si en clase pudieramos
explicar si se puede demostrar el lema usando esta definición de
manera sencilla o explicar un poco cómo iría la prueba *)

value "sumaImpares 5" -- "= 25"

text {* ---------------------------------------------------------------
Ejercicio 2. Demostrar que
sumaImpares n = n*n
------------------------------------------------------------------- *}

(* Pedrosrei: lo dejo de menos a más estructurado *)

lemma "sumaImpares n = n*n"
apply (induct n)
apply auto
done

-- "davoremar juacorvic jeshorcob danrodcha"

lemma "sumaImpares n = n*n"
by (induct n) auto

lemma "sumaImpares n = n*n"
proof (induct n)
show "sumaImpares 0 = 0 * 0" by simp
next
fix n
assume HI: "sumaImpares n = n * n"
thus "sumaImpares (Suc n) = Suc n * Suc n" by simp
qed

-- "davoremar juacorvic marnajgom jeshorcob domcadgom danrodcha"

lemma "sumaImpares n = n*n"
proof (induct n)
show "sumaImpares 0 = 0 * 0" by simp
next
fix n
assume HI: "sumaImpares n = n*n"
have "sumaImpares (Suc n) = sumaImpares n + (2*n + 1)" by simp
also have "... = n*n + 2*n + 1" using HI by simp
also have "... = (n + 1) * (n + 1)" by simp
finally show "sumaImpares (Suc n) = Suc n * Suc n" by simp
qed

text {* ---------------------------------------------------------------
Ejercicio 3. Definir la función
sumaPotenciasDeDosMasUno :: nat ⇒ nat
tal que
(sumaPotenciasDeDosMasUno n) = 1 + 2^0 + 2^1 + 2^2 + ... + 2^n.
Por ejemplo,
sumaPotenciasDeDosMasUno 3 = 16
------------------------------------------------------------------ *}

-- "davoremar juacorvic marnajgom jeshorcob domcadgom danrodcha"

fun sumaPotenciasDeDosMasUno :: "nat ⇒ nat" where
"sumaPotenciasDeDosMasUno 0 = 2"
| "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n) + sumaPotenciasDeDosMasUno n"

value "sumaPotenciasDeDosMasUno 3" -- "= 16"

text {* ---------------------------------------------------------------
Ejercicio 4. Demostrar que
sumaPotenciasDeDosMasUno n = 2^(n+1)
------------------------------------------------------------------- *}

-- "davoremar juacorvic jeshorcob danrodcha"
lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
by (induct n) auto

-- "jeshorcob"
lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
proof (induct n)
show "sumaPotenciasDeDosMasUno 0 = 2^(0+1)" by simp
next
fix n
assume HI: "sumaPotenciasDeDosMasUno n = 2^(n+1)"
thus "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n + 1)" by simp
qed

-- "davoremar juacorvic marnajgom jeshorcob domcadgom danrodcha"
lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
proof (induct n)
show "sumaPotenciasDeDosMasUno 0 = 2^(0+1)" by simp
next
fix n
assume HI: "sumaPotenciasDeDosMasUno n = 2^(n+1)"
have "sumaPotenciasDeDosMasUno (Suc n) =
sumaPotenciasDeDosMasUno n + 2^(Suc n)" by simp
also have "... = 2^(n+1) + 2^(Suc n)" using HI by simp
also have "... = 2^(Suc n + 1)" by simp
finally show "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n + 1)"
by simp
qed

text {* ---------------------------------------------------------------
Ejercicio 5. Definir la función
copia :: nat ⇒ 'a ⇒ 'a list
tal que (copia n x) es la lista formado por n copias del elemento
x. Por ejemplo,
copia 3 x = [x,x,x]
------------------------------------------------------------------ *}

-- "davoremar juacorvic marnajgom jeshorcob domcadgom danrodcha"
fun copia :: "nat ⇒ 'a ⇒ 'a list" where
"copia 0 x = []"
| "copia (Suc n) x = x # copia n x"

value "copia 3 x" -- "= [x,x,x]"

text {* ---------------------------------------------------------------
Ejercicio 6. Definir la función
todos :: ('a ⇒ bool) ⇒ 'a list ⇒ bool
tal que (todos p xs) se verifica si todos los elementos de xs cumplen
la propiedad p. Por ejemplo,
todos (λx. x>(1::nat)) [2,6,4] = True
todos (λx. x>(2::nat)) [2,6,4] = False
Nota: La conjunción se representa por ∧
----------------------------------------------------------------- *}

-- "davoremar juacorvic marnajgom jeshorcob domcadgom danrodcha"
fun todos :: "('a ⇒ bool) ⇒ 'a list ⇒ bool" where
"todos p [] = True"
| "todos p (x#xs) = ((p x) ∧ (todos p xs))"

(* jeshorcob: me gustaría saber por qué es necesario poner el paréntesis
en la definición(2) *)

(* Pedrosrei: porque aunque están predefinidas las prioridades entre la
suma y el producto en los cuerpos y anillos más comunes, la conjunción
y la igualdad no tienen definida esa prioridad*)

value "todos (λx. x>(1::nat)) [2,6,4]" -- "= True"
value "todos (λx. x>(2::nat)) [2,6,4]" -- "= False"

text {* ---------------------------------------------------------------
Ejercicio 7. Demostrar que todos los elementos de (copia n x) son
iguales a x.
------------------------------------------------------------------- *}

-- "davoremar juacorvic jeshorcob danrodcha"
lemma "todos (λy. y=x) (copia n x)"
by (induct n) auto

-- "davoremar marnajgom jeshorcob domcadgom"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
show "todos (λy. y=x) (copia 0 x)" by simp
next
fix n
assume HI: "todos (λy. y=x) (copia n x)"
have "todos (λy. y=x) (copia (Suc n) x) =
todos (λy. y=x) (x#(copia n x))" by simp
also have "... = todos (λy. y=x) (copia n x)" by simp
finally show "todos (λy. y=x) (copia (Suc n) x)" using HI by simp
qed

-- "juacorvic jeshorcob"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
show "todos (λy. y=x) (copia 0 x)" by simp
fix n
assume HI: "todos (λy. y=x) (copia n x)"
thus "todos (λy. y=x) (copia (Suc n) x)" by simp
qed

-- "juacorvic"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
show "todos (λy. y=x) (copia 0 x)" by simp
next
fix n
assume HI: "todos (λy. y=x) (copia n x)"
have "todos (λy. y=x) (copia (Suc n) x) =
todos (λy. y=x) (x # (copia n x))" by simp
also have "...= todos (λy. y=x)[x]" using HI by simp
finally show "todos (λy. y=x) (copia (Suc n) x)" using HI by simp
qed

-- "danrodcha"
lemma "todos (λy. y=x) (copia n x)"
proof (induct n)
show "todos (λy. y=x) (copia 0 x)" by simp
next
fix n
assume HI: "todos (λy. y=x) (copia n x)"
have "todos (λy. y=x) (copia (Suc n) x) = todos (λy. y=x) (x#(copia n x))" by (simp only: copia.simps)
also have "... = (((λy. y=x) x) ∧ (todos (λy. y=x) (x#(copia n x))))" by simp
also have "... = (todos (λy. y=x) (copia n x))" using HI by simp
also have "... = True" using HI by simp
finally show "todos (λy. y=x) (copia (Suc n) x) " by simp
qed

text {* ---------------------------------------------------------------
Ejercicio 8. Definir la función
factR :: nat ⇒ nat
tal que (factR n) es el factorial de n. Por ejemplo,
factR 4 = 24
------------------------------------------------------------------ *}

-- "davoremar juacorvic marnajgom jeshorcob domcadgom"
fun factR :: "nat ⇒ nat" where
"factR 0 = 1"
| "factR (Suc n) = (Suc n) * factR n"

value "factR 4" -- "= 24"

text {* ---------------------------------------------------------------
Ejercicio 9. Se considera la siguiente definición iterativa de la
función factorial
factI :: "nat ⇒ nat" where
factI n = factI' n 1

factI' :: nat ⇒ nat ⇒ nat" where
factI' 0 x = x
factI' (Suc n) x = factI' n (Suc n)*x
Demostrar que, para todo n y todo x, se tiene
factI' n x = x * factR n
------------------------------------------------------------------- *}

fun factI' :: "nat ⇒ nat ⇒ nat" where
"factI' 0 x = x"
| "factI' (Suc n) x = factI' n (Suc n)*x"

fun factI :: "nat ⇒ nat" where
"factI n = factI' n 1"

value "factI 4" -- "= 24"

-- "davoremar jeshorcob domcadgom"
lemma fact1: "factI' n x = x* factR n"
by (induct n arbitrary: x) auto

(* juacorvic: ¿Por que tenemos que indicar arbitrary:x? *)

(* Pedrosrei: no tienes que hacerlo como resulta de mi ejemplo o las
correcciones que he indicado en el tuyo. En este caso concreto
totalmente automatizado es porque posees dos variables y tienes que
decirle qué hacer con cada una. En una haces la inducción pero la otra
la dejas sin tocar, o como solemos decir: "sea un x cualquiera..." *)

-- "davoremar jeshorcob domcadgom"
lemma fact: "factI' n x = x * factR n"
proof (induct n arbitrary: x)
show "⋀x. factI' 0 x = x * factR 0" by simp
next
fix n x
assume HI: "⋀x. factI' n x = x * factR n"
have "factI' (Suc n) x = factI' n (Suc n)*x" by simp
also have "... = x * factI' n (Suc n)" by simp
also have "... = x * ((Suc n) * factR n)" using HI by simp
also have "... = x * factR (Suc n)" by simp
finally show "factI' (Suc n) x = x * factR (Suc n)" by simp
qed

(* marnajgom: no entiendo el paso
"also have "... = x * factI' n (Suc n)" by simp"
¿Por qué no sacas fuera (Suc n)*x, sólo sacas x? *)

(* Pedrosrei: También podemos prescindir de arbitrary x *)

lemma fact2: "factI' n x = x * factR n"
proof (induct n)
show "factI' 0 x = x * factR 0" by simp
next
fix n
assume HI: "factI' n x = x * factR n"
show "factI' (Suc n) x = x * factR (Suc n)"
proof -
have "factI' (Suc n) x = (factI' n (Suc n))*x" by simp
also have " ... = ((Suc n) * factR n) * x" using HI fact by simp
-- "Si usamos auto: finally show ?thesis by auto "
also have " ... = x * factR (Suc n)" by simp
finally show ?thesis .
qed
qed

(* Pedrosrei: no resuelve finally debido a la conjunción grande que
emplea isabelle para indicarte un "para todo de cualquier conjunto"
(en realidad es la conjunción de conjuntos, creo recordar). Si quieres
poner un para todo recurre a ! ó \forall. Si sólo has puesto lo que te
ha indicado la máquina, quería indicarte un valor cualquiera, vamos,
lo que fijas con "arbitrary".

Sólo tienes que eliminar los ⋀ de la prueba y añadirle un paso
intermedio con la regla adecuada (usa find_theorem y el nombre que
crees que tendrá) entre el also have último y el finally para que vea
la igualdad de derecha a izquierda y listo. También puedes emplear "by
arith" para estas cosas tan sencillas y no tener que irte a la regla
exacta de la aritmética (que no siempre es fácil).

*)
-- "juacorvic"
(* Se intenta demostración en sentido inverso:
x * factR n = factI' n x
No resuelve finally *)

lemma "x * factR n = factI' n x "
proof (induct n)
show "⋀x. x * factR 0 = factI' 0 x" by simp
next
fix n
assume HI: "⋀x. x * factR n = factI' n x "
have "x * factR (Suc n) = x * (factR n * (Suc n))" by simp
also have "... = x * ((Suc n) * factR n)" by simp
also have "... = x * (factI' n (Suc n))" using HI by simp
also have "... = factI' (Suc n) x" by simp
finally show "x * factR (Suc n) = factI' (Suc n) x" by simp
qed
oops

text {* ---------------------------------------------------------------
Ejercicio 10. Demostrar que
factI n = factR n
------------------------------------------------------------------- *}

-- "davoremar juacorvic jeshorcob domcadgom"
corollary "factI n = factR n"
by (simp add: fact)

-- "juacorvic"
corollary "factI n = factR n"
proof -
show "factI n = factR n" by (simp add:fact)
qed

-- "davoremar juacorvic jeshorcob"
corollary "factI n = factR n"
proof -
have "factI n = factI' n 1" by simp
also have "... = 1 * factR n" by (simp add: fact)
finally show "factI n = factR n" by simp
qed

-- "marnajgom"
corollary "factI n = factR n"
proof (induct n)
show "factI 0 = factR 0" by simp
next
fix n
assume HI:"factI n = factR n"
have "factI (Suc n) = factI' (Suc n) 1" by simp
also have "... = factI' n (Suc n)*1" by simp
also have "... = (Suc n)*1 * factR n" using fact by simp
also have "... = (Suc n) * factR n" by simp
finally show "factI (Suc n) = factR (Suc n)" by simp
qed

text {* ---------------------------------------------------------------
Ejercicio 11. Definir, recursivamente y sin usar (@), la función
amplia :: 'a list ⇒ 'a ⇒ 'a list
tal que (amplia xs y) es la lista obtenida añadiendo el elemento y al
final de la lista xs. Por ejemplo,
amplia [d,a] t = [d,a,t]
------------------------------------------------------------------ *}

-- "davoremar marnajgom jeshorcob domcadgom"
fun amplia :: "'a list ⇒ 'a ⇒ 'a list" where
"amplia [] y = [y]"
| "amplia (x#xs) y = x # (amplia xs y)"

value "amplia [d,a] t" -- "= [d,a,t]"

text {* ---------------------------------------------------------------
Ejercicio 12. Demostrar que
amplia xs y = xs @ [y]
------------------------------------------------------------------- *}

-- "davoremar"
lemma "amplia xs y = xs @ [y]"
by (induct xs) auto

-- "juacorvic" (* Añado esquema intermedio *)
lemma "amplia xs y = xs @ [y]"
proof (induct xs)
show "amplia [] y = [] @ [y]" by simp
next
fix a xs
assume HI: "amplia xs y = xs @ [y]"
thus "amplia (a # xs) y = (a # xs) @ [y]" by simp
qed

-- "davoremar marnajgom jeshorcob domcadgom"
lemma "amplia xs y = xs @ [y]"
proof (induct xs)
show "amplia [] y = [] @ [y]" by simp
next
fix x xs
assume HI: "amplia xs y = xs @ [y]"
have "amplia (x#xs) y = x # amplia xs y" by simp
also have "... = x # (xs @ [y])" using HI by simp
also have "... = (x#xs) @ [y]" by simp (* Pedrosrei: prescindible *)
finally show "amplia (x#xs) y = (x#xs) @ [y]" by simp
qed

(* Pedrosrei: las variables son mudas. Da igual 'a' que 'x', del mismo
modo que da igual en papel el nombre de la incógnita. Puedes usar
'incognitabonita' y sigue siendo lo mismo *)

-- "juacorvic"
(* Demostración idéntica a 'davoremar' pero el sistema me sugirió usar
'a' en vez de 'x' *)
lemma "amplia xs y = xs @ [y]"
proof (induct xs)
show "amplia [] y = [] @ [y]" by simp
next
fix a xs
assume HI: "amplia xs y = xs @ [y]"
have "amplia (a # xs) y = a # (amplia xs y) " by simp
also have "... = a # (xs @ [y])" using HI by simp
also have "... = (a # xs) @ [y]" by simp
finally show "amplia (a # xs) y = (a # xs) @ [y]" by simp
qed

end
</source>

Relación 1

2014-11-02T20:11:53Z

Danrodcha:

<source lang="isar">
header {* R1: Programación funcional en Isabelle *}

theory R1
imports Main
begin

text {* ----------------------------------------------------------------
Ejercicio 0. Definir, por recursión, la función
factorial :: nat ⇒ nat
tal que (factorial n) es el factorial de n. Por ejemplo,
factorial 4 = 24
------------------------------------------------------------------- *}

-- "jeshorcob","javrodviv1", "danrodcha"
fun factorial :: "nat ⇒ nat" where
"factorial 0 = 1 "
|"factorial (Suc m) = (Suc m) * factorial m"

value "factorial 4" -- "24"

text {* ----------------------------------------------------------------
Ejercicio 1. Definir, por recursión, la función
longitud :: 'a list ⇒ nat
tal que (longitud xs) es la longitud de la listas xs. Por ejemplo,
longitud [4,2,5] = 3
------------------------------------------------------------------- *}

-- "jeshorcob","javrodviv1","danrodcha"
fun longitud :: "'a list ⇒ nat" where
"longitud [] = 0"
|"longitud (x#xs) = 1 + longitud xs"

value "longitud [4,2,5]" -- "= 3"

text {* ---------------------------------------------------------------
Ejercicio 2. Definir la función
fun intercambia :: 'a × 'b ⇒ 'b × 'a
tal que (intercambia p) es el par obtenido intercambiando las
componentes del par p. Por ejemplo,
intercambia (u,v) = (v,u)
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun intercambia :: "'a × 'b ⇒ 'b × 'a" where
"intercambia (x,y) = (y,x)"

value "intercambia (u,v)" -- "= (v,u)"

text {* ---------------------------------------------------------------
Ejercicio 3. Definir, por recursión, la función
inversa :: 'a list ⇒ 'a list
tal que (inversa xs) es la lista obtenida invirtiendo el orden de los
elementos de xs. Por ejemplo,
inversa [a,d,c] = [c,d,a]
------------------------------------------------------------------ *}

-- "jeshorcob","danrodcha"
fun inversa :: "'a list ⇒ 'a list" where
"inversa [] = []"
|"inversa (x#xs) = (inversa xs) @ [x]"

--"javrodviv1"
fun inversa2 :: "'a list ⇒ 'a list" where
"inversa2 [] = []"
| "inversa2 xs = (last xs)#(inversa2 (butlast xs))"

value "inversa [a,d,c]" -- "= [c,d,a]"

text {* ---------------------------------------------------------------
Ejercicio 4. Definir la función
repite :: nat ⇒ 'a ⇒ 'a list
tal que (repite n x) es la lista formada por n copias del elemento
x. Por ejemplo,
repite 3 a = [a,a,a]
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun repite :: "nat ⇒ 'a ⇒ 'a list" where
"repite 0 x = []"
|"repite (Suc m) x = x # (repite m x)"

value "repite 3 a" -- "= [a,a,a]"

text {* ---------------------------------------------------------------
Ejercicio 5. Definir la función
conc :: 'a list ⇒ 'a list ⇒ 'a list
tal que (conc xs ys) es la concatención de las listas xs e ys. Por
ejemplo,
conc [a,d] [b,d,a,c] = [a,d,b,d,a,c]
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun conc :: "'a list ⇒ 'a list ⇒ 'a list" where
"conc [] ys = ys"
|"conc (x#xs) ys = x#(conc xs ys)"

value "conc [a,d] [b,d,a,c]" -- "= [a,d,b,d,a,c]"

text {* ---------------------------------------------------------------
Ejercicio 6. Definir la función
coge :: nat ⇒ 'a list ⇒ 'a list
tal que (coge n xs) es la lista de los n primeros elementos de xs. Por
ejemplo,
coge 2 [a,c,d,b,e] = [a,c]
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun coge :: "nat ⇒ 'a list ⇒ 'a list" where
"coge _ [] = []"
|"coge 0 xs = []"
|"coge (Suc m) (x#xs) = x#(coge m xs)"

value "coge 2 [a,c,d,b,e]" -- "= [a,c]"

text {* ---------------------------------------------------------------
Ejercicio 7. Definir la función
elimina :: nat ⇒ 'a list ⇒ 'a list
tal que (elimina n xs) es la lista obtenida eliminando los n primeros
elementos de xs. Por ejemplo,
elimina 2 [a,c,d,b,e] = [d,b,e]
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun elimina :: "nat ⇒ 'a list ⇒ 'a list" where
"elimina _ [] = []"
|"elimina 0 xs = xs"
|"elimina (Suc m) (x#xs) = elimina m xs"

value "elimina 2 [a,c,d,b,e]" -- "= [d,b,e]"

text {* ---------------------------------------------------------------
Ejercicio 8. Definir la función
esVacia :: 'a list ⇒ bool
tal que (esVacia xs) se verifica si xs es la lista vacía. Por ejemplo,
esVacia [] = True
esVacia [1] = False
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1"
fun esVacia :: "'a list ⇒ bool" where
"esVacia [] = True"
|"esVacia _ = False"

value "esVacia []" -- "= True"
value "esVacia [1]" -- "= False"

text {* ---------------------------------------------------------------
Ejercicio 9. Definir la función
inversaAc :: 'a list ⇒ 'a list
tal que (inversaAc xs) es a inversa de xs calculada usando
acumuladores. Por ejemplo,
inversaAc [a,c,b,e] = [e,b,c,a]
------------------------------------------------------------------ *}

-- "jeshorcob","danrodcha"
fun inversaAcAux :: "'a list ⇒ 'a list ⇒ 'a list" where
"inversaAcAux [] ys = ys"
|"inversaAcAux (x#xs) ys = inversaAcAux xs (x#ys)"

-- "jeshorcob","danrodcha"
fun inversaAc :: "'a list ⇒ 'a list" where
"inversaAc xs = inversaAcAux xs []"

value "inversaAc [a,c,b,e]" -- "= [e,b,c,a]"

text {* ---------------------------------------------------------------
Ejercicio 10. Definir la función
sum :: nat list ⇒ nat
tal que (sum xs) es la suma de los elementos de xs. Por ejemplo,
sum [3,2,5] = 10
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun sum :: "nat list ⇒ nat" where
"sum [] = 0"
|"sum (x#xs) = x + sum xs"

-- "jeshorcob"
fun sum2 :: "nat list ⇒ nat" where
"sum2 xs = foldr (op +) xs 0"

value "sum [3,2,5]" -- "= 10"

text {* ---------------------------------------------------------------
Ejercicio 11. Definir la función
map :: ('a ⇒ 'b) ⇒ 'a list ⇒ 'b list
tal que (map f xs) es la lista obtenida aplicando la función f a los
elementos de xs. Por ejemplo,
map (λx. 2*x) [3,2,5] = [6,4,10]
------------------------------------------------------------------ *}

-- "jeshorcob","javrodviv1","danrodcha"
fun map :: "('a ⇒ 'b) ⇒ 'a list ⇒ 'b list" where
"map f [] = []"
|"map f (x#xs) = (f x)#(map f xs)"

value "map (λx. 2*x) [3::nat,2,5]" -- "= [6,4,10]"

end
</source>