Diferencia entre revisiones de «Relación 3»

Revisión del 22:17 22 nov 2013

header {* R3: Razonamiento sobre programas en Isabelle/HOL *}

theory R3
imports Main 
begin

text {* --------------------------------------------------------------- 
  Ejercicio 1. Definir la función
     sumaImpares :: nat \<Rightarrow> nat
  tal que (sumaImpares n) es la suma de los n primeros números
  impares. Por ejemplo,
     sumaImpares 5  =  25
  ------------------------------------------------------------------ *}

-- "maresccas4"

fun sumaImpares :: "nat \<Rightarrow> nat" where
  "sumaImpares 0 = 0"
| "sumaImpares (Suc n) = (2 * n + 1) + sumaImpares n"

value "sumaImpares 5" -- "= 25"

text {* --------------------------------------------------------------- 
  Ejercicio 2. Demostrar que 
     sumaImpares n = n*n
  ------------------------------------------------------------------- *}

-- "maresccas4"

lemma "sumaImpares n = n*n"
proof (induct n)
  show "sumaImpares 0 = 0*0" by simp
next
  fix n
  assume HI: "sumaImpares n = n*n"
  have "sumaImpares (Suc n) = (2 * n + 1) + sumaImpares n" by (simp only: sumaImpares.simps(2))
  also have "... = 2 * n + 1 + n * n" using HI by simp
  finally show "sumaImpares (Suc n) = (Suc n) * (Suc n)" by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 3. Definir la función
     sumaPotenciasDeDosMasUno :: nat \<Rightarrow> nat
  tal que 
     (sumaPotenciasDeDosMasUno n) = 1 + 2^0 + 2^1 + 2^2 + ... + 2^n. 
  Por ejemplo, 
     sumaPotenciasDeDosMasUno 3  =  16
  ------------------------------------------------------------------ *}

-- "maresccas4"

fun sumaPotenciasDeDosMasUno :: "nat \<Rightarrow> nat" where
  "sumaPotenciasDeDosMasUno 0 = 2"
| "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n) + sumaPotenciasDeDosMasUno n"

value "sumaPotenciasDeDosMasUno 3" -- "= 16"

text {* --------------------------------------------------------------- 
  Ejercicio 4. Demostrar que 
     sumaPotenciasDeDosMasUno n = 2^(n+1)
  ------------------------------------------------------------------- *}

-- "maresccas4"

lemma "sumaPotenciasDeDosMasUno n = 2^(n+1)"
proof (induct n)
  show "sumaPotenciasDeDosMasUno 0 = 2^(0+1)" by simp
next
  fix n
  assume HI: "sumaPotenciasDeDosMasUno n = 2^(n+1)"
  have "sumaPotenciasDeDosMasUno (Suc n) = 2^(Suc n) + sumaPotenciasDeDosMasUno n" by (simp only: sumaPotenciasDeDosMasUno.simps(2))
  also have "... = 2^(Suc n) + 2^(n+1)" using HI by simp
  also have "... = 2^(n+1) + 2^(n+1)" by simp
  also have "... = 2 * (2^n + 2^n)" by simp
  also have "... = 2 * (2 * 2^n)" by simp
  also have "... = 2 * 2^(Suc n)" by simp
  finally show "sumaPotenciasDeDosMasUno (Suc n) = 2^((Suc n)+1)" by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 5. Definir la función
     copia :: nat \<Rightarrow> 'a \<Rightarrow> 'a list
  tal que (copia n x) es la lista formado por n copias del elemento
  x. Por ejemplo, 
     copia 3 x = [x,x,x]
  ------------------------------------------------------------------ *}

-- "maresccas4"

fun copia :: "nat \<Rightarrow> 'a \<Rightarrow> 'a list" where
  "copia 0 x = []"
| "copia (Suc n) x = x # copia n x"

value "copia 3 x" -- "= [x,x,x]"

text {* --------------------------------------------------------------- 
  Ejercicio 6. Definir la función
     todos :: ('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool
  tal que (todos p xs) se verifica si todos los elementos de xs cumplen
  la propiedad p. Por ejemplo,
     todos (\<lambda>x. x>(1::nat)) [2,6,4] = True
     todos (\<lambda>x. x>(2::nat)) [2,6,4] = False
  Nota: La conjunción se representa por \<and>
  ----------------------------------------------------------------- *}

-- "maresccas4"

fun todos :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  "todos p [] = True"
| "todos p (x#xs) = (p x \<and> todos p xs)"

value "todos (\<lambda>x. x>(1::nat)) [2,6,4]" -- "= True"
value "todos (\<lambda>x. x>(2::nat)) [2,6,4]" -- "= False"

text {* --------------------------------------------------------------- 
  Ejercicio 7. Demostrar que todos los elementos de (copia n x) son
  iguales a x. 
  ------------------------------------------------------------------- *}

-- "maresccas4"

lemma "todos (\<lambda>y. y=x) (copia n x)"
proof (induct n)
  show "todos (\<lambda>y. y=x) (copia 0 x)" by simp
next 
  fix n
  assume HI: "todos (\<lambda>y. y=x) (copia n x)"
  have "todos (\<lambda>y. y=x) (copia (Suc n) x) = todos (\<lambda>y. y=x) (x # copia n x)" by (simp only: copia.simps(2))
  also have "... = todos (\<lambda>y. y=x) (copia n x)" by simp
  finally show "todos (\<lambda>y. y=x) (copia (Suc n) x)" using HI by simp
qed

text {* --------------------------------------------------------------- 
  Ejercicio 8. Definir la función
    factR :: nat \<Rightarrow> nat
  tal que (factR n) es el factorial de n. Por ejemplo,
    factR 4 = 24
  ------------------------------------------------------------------ *}

-- "maresccas4"

fun factR :: "nat \<Rightarrow> nat" where
  "factR 0 = 1"
| "factR (Suc n) = Suc n * factR n"

value "factR 4" -- "= 24"

text {* --------------------------------------------------------------- 
  Ejercicio 9. Se considera la siguiente definición iterativa de la
  función factorial 
     factI :: "nat \<Rightarrow> nat" where
     factI n = factI' n 1
     
     factI' :: nat \<Rightarrow> nat \<Rightarrow> nat" where
     factI' 0       x = x
     factI' (Suc n) x = factI' n (Suc n)*x
  Demostrar que, para todo n y todo x, se tiene 
     factI' n x = x * factR n
  ------------------------------------------------------------------- *}

fun factI' :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
  "factI' 0       x = x"
| "factI' (Suc n) x = factI' n (Suc n)*x"

fun factI :: "nat \<Rightarrow> nat" where
  "factI n = factI' n 1"

value "factI 4" -- "= 24"

-- "maresccas4"
     
lemma fact: "factI' n x = x * factR n"
proof (induct n arbitrary: x)
  show "\<And>x. factI' 0 x = x * factR 0" by simp
next
  fix n
  assume HI: "\<And>x. factI' n x = x * factR n"
  show "\<And>x. factI' (Suc n) x = x * factR (Suc n)"
  proof -
    fix x
    have "factI' (Suc n) x = factI' n (Suc n)*x" by (simp only: factI'.simps(2))
    also have "... = x * factI' n (Suc n)" by simp
    also have "... = x * ((Suc n) * factR n)" using HI by simp
    finally show "factI' (Suc n) x = x * factR (Suc n)" by simp
  qed
qed

text {* --------------------------------------------------------------- 
  Ejercicio 10. Demostrar que
     factI n = factR n
  ------------------------------------------------------------------- *}

-- "maresccas4"

corollary "factI n = factR n"
proof - 
  show "factI n = factR n" by (simp add:fact)
qed

text {* --------------------------------------------------------------- 
  Ejercicio 11. Definir, recursivamente y sin usar (@), la función
     amplia :: 'a list \<Rightarrow> 'a \<Rightarrow> 'a list
  tal que (amplia xs y) es la lista obtenida añadiendo el elemento y al
  final de la lista xs. Por ejemplo,
     amplia [d,a] t = [d,a,t]
  ------------------------------------------------------------------ *}

-- "maresccas4"

fun amplia :: "'a list \<Rightarrow> 'a \<Rightarrow> 'a list" where
  "amplia [] y = [y]"
| "amplia (x#xs) y = x # (amplia xs y)"

value "amplia [d,a] t" -- "= [d,a,t]"

text {* --------------------------------------------------------------- 
  Ejercicio 12. Demostrar que 
     amplia xs y = xs @ [y]
  ------------------------------------------------------------------- *}

-- "maresccas4"

lemma "amplia xs y = xs @ [y]"
proof (induct xs)
 show "amplia [] y = [] @ [y]" by simp
next
  fix x xs
  assume HI: "amplia xs y = xs @ [y]"
  have "amplia (x#xs) y = x # (amplia xs y)" by (simp only: amplia.simps(2))
  also have "... = x # xs @ [y]" using HI by simp
  finally show "amplia (x#xs) y = (x#xs) @ [y]" by simp
qed

end
De Razonamiento automático (2013-14)

Revisión del 22:17 22 nov 2013
