Lógica computacional y teoría de modelos (2019-20) - Contribuciones del usuario [es]

Completación de redes metabólicas (código e instancia)

2020-02-12T12:14:23Z

Mjoseh: Página creada con «<source lang = "prolog"> %% LÓGICA COMPUTACIONAL Y TEORÍA DE MODELOS %% TRABAJO REDES METABÓLICAS %% Jesús Camacho Moro %% Mª Estefanía Espinar García %% Problem…»

<source lang = "prolog">
%% LÓGICA COMPUTACIONAL Y TEORÍA DE MODELOS

%% TRABAJO REDES METABÓLICAS

%% Jesús Camacho Moro
%% Mª Estefanía Espinar García

%% Problema %%
%%%%%%%%%%

%% Sea un grafo bipartito dirigido, G = (R u M, E), donde R, es el conjunto
%% de reacciones, M, el conjunto de metabolitos, y E, representa los
%% metabolitos reactantes y productos de cada reacción R. El problema
%% planteado es: dado un conjunto de semillas, S, y otro de resultantes, T,
%% hallar qué reacciones debemos obtener para poder producir los
%% resultantes a partir de las semillas.

%% Definiciones %%
%%%%%%%%%%%%

%% draft(d). :Identificación del grafo G como Net.

%% reaccion(N, G). : es la reacción que tiene un nodo N en el grafo G

%% reactivo(M, r). : es la arista que va de un metabolito a una reacción.

%% producto(M, r). : es la arista que va de una reacción a un metabolito.

%% semilla(M) : es una semilla.

%% objetivo(M). : es el objetivo.

%% Instancias %%
%%%%%%%%%%%%

draft(d).

reaccion(r1, x).
reaccion(r4, d).

reactivo(m1, r1).
reactivo(m3, r4).
reactivo(m4, r5).

producto(m3, r1).
producto(m5, r4).

semilla(m1). semilla(m2).

reaccion(r2, x).
reaccion(r3, d).
reaccion(r5, x).
reaccion(r6, d).

reactivo(m2, r2).
reactivo(m2, r3).
reactivo(m4, r4).
reactivo(m1, r5).
reactivo(m4, r6).

producto(m3, r2).
producto(m4, r3).
producto(m6, r5).
producto(m7, r6).

objetivo(m5).
objetivo(m7).

%% Código %%
%%%%%%%%

%%% Tipo de reacción a: grafo G. Tipo de reacción x: reacciones añadidas

type(Net) :- draft(Net).
type(a).
type(x).

%%% Grafo extendido.

reaccion(R,x) :- reaccion(R,Net), draft(Net).
{ reaccion(R,x) } :- reaccion(R,a).

%%% Predicado alcanzable

scope(M, T) :- semilla(M), type(T).
scope(M, T) :- type(T), producto(M,R), reaccion(R,T), scope(M2,T), reactivo(M2,R).

:- objetivo(M), not scope(M,x).

%%% Nuevas reacciones y su minimización

nuevo(R) :- reaccion(R,x), draft(Net), not reaccion(R,Net).

reacciones(S) :- S = #count{1: nuevo(R) }.

#minimize{1,R:nuevo(R)}.

#show reacciones/1.
#show nuevo/1.

</source>

Aplicaciones y casos de estudio (19-20)

2020-02-12T12:14:03Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos (Ana Bermudo y Gema Terrón)([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* Grid puzzles:
** [[Masyu (Jan Wasilewski)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf pdf]).
** [[Heyawake (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).
** [[Nuricabe (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).
* Aplicaciones biológicas (Jesús Camacho y Estefanía Espinar):
** [[Reparación de redes metabólicas (código)]] e [[instancia]].
** [[Completación de redes metabólicas (código e instancia)]]

Aplicaciones y casos de estudio (19-20)

2020-02-12T12:13:04Z

Mjoseh:

Instancia

2020-02-12T12:12:25Z

Mjoseh: Página creada con «<source lang = "prolog"> % Ejemplo del texto vertice(1..8). arco(1,2). arco(2,3). arco(3,8). arco(4,1). arco(4,2). arco(5,2). arco(5,3). arco(5,7). arco(6,4). arco(6,5).…»

<source lang = "prolog">
% Ejemplo del texto

vertice(1..8).

arco(1,2).
arco(2,3).
arco(3,8).
arco(4,1). arco(4,2).
arco(5,2). arco(5,3). arco(5,7).
arco(6,4). arco(6,5).
arco(7,6).
arco(8,4). arco(8,5).

observadoA(1,2,mas).
observadoA(2,3,mas).
observadoA(3,8,menos).
observadoA(4,1,menos).
observadoA(5,2,menos).
observadoA(5,7,mas).
observadoA(6,4,menos).
observadoA(6,5,menos).
observadoA(7,6,menos).
observadoA(8,4,mas).
observadoA(8,5,mas).
observadoV(1,menos).
entrada(1).

observadoA(4,2,mas).
</source>

Reparación de redes metabólicas (código)

2020-02-12T12:11:47Z

Mjoseh: Página creada con «<source lang = "prolog"> % Red Regulatoria Genética % Tenemos una serie de genes y sus interacciones representado por un grafo de influencia G=(N,E,s) dónde los vértices…»

<source lang = "prolog">
% Red Regulatoria Genética
% Tenemos una serie de genes y sus interacciones representado por un grafo de influencia G=(N,E,s) dónde los vértices N son los genes, las aristas E son las interacciones y s:E-->{-,+} una función parcial.
% Tenemos una serie de datos experimentales que sabemos ciertos y queremos imponer que nuestro modelo los cumpla. No solo esto, sino que a ser posible buscamos encontrar el menor número de pasos necesario para modificar nuestro modelo y convertirlo en uno consistente.

% Importante!!!
% El grafo G es dirigido y debe cumplir que si (u,v) es una arista, entonces el producto signo(u)*signo(u,v)=signo(v).

%%%%%%%%%%%%%%%%
%% Predicados %%
%%%%%%%%%%%%%%%%

% vertice(X): X es un vértice.
% arco(X,Y): G tiene un arco de X en Y.
% entrada(X): X es un vértice de entrada.
% signoV(X,S): El modelo tiene signo S en el vértice X.
% signoA(X,Y,S): El modelo tiene signo S en el arco de X a Y.
% observadoV(X,S): Se ha observado que el vértice X tiene signo S.
% observadoA(X,Y,S): Se ha observado que el arco de X a Y tiene signo S.

% Definimos los signos
signo(mas;menos).

% Añadimos que son opuestos para hacer el "producto" de signos
opuesto(mas,menos).
opuesto(menos,mas).

%%%%%%%%%%%%%%%%
%% Generación %%
%%%%%%%%%%%%%%%%

% Asignar signos a arcos y vértices para nuestros múltiples modelos:
1 {signoV(V,S): signo(S)} 1 :- vertice(V).
1 {signoA(U,V,S): signo(S)} 1 :- arco(U,V).

%%%%%%%%%%%%%%%%%%%
%% Restricciones %%
%%%%%%%%%%%%%%%%%%%

% Si se observa un signo en un vértice, debe aparecer en el modelo:
signoV(V,S) :- observadoV(V,S).

% Si se observa un signo en un arco, debe aparecer en el modelo siempre que sea consistente:
signoA(U,V,S) :- observadoA(U,V,S), not error(U,V).
signoA(U,V,S) :- observadoA(U,V,T), opuesto(S,T), error(U,V).

%%%%%%%%%%%
%% Signo %%
%%%%%%%%%%%

% Si tenemos un arco (u,v), entonces signo(u)*signo(u,v)=signo(v):
resultado(V,mas) :- arco(U,V), signoA(U,V,S), signoV(U,S).
resultado(V,menos) :- arco(U,V), signoA(U,V,T), signoV(U,S), opuesto(S,T).

%%%%%%%%%%%%%%%%%%
%% Consistencia %%
%%%%%%%%%%%%%%%%%%

% No podemos tener un vértice que no sea añadido (entrada) y le asignemos un signo sin una razón (resultado):
:- signoV(U,S), not resultado(U,S), not entrada(U).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Generación de arcos erroneos %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% Hacemos partes de E para considerar todas las posibilidades:
{error(U,V)} :- arco(U,V).

%%%%%%%%%%%%%%%%%%
%% Optimización %%
%%%%%%%%%%%%%%%%%%

%errores(N) :- N = #count{1 : error(U,V)}.

%#minimize{1,U,V : error(U,V)}.

%%%%%%%%%%%%%%%%%%%
%% Visualización %%
%%%%%%%%%%%%%%%%%%%
%#show error/2.
#show signoV/2.
#show signoA/3.
%#show resultado/2.

% Paso a realizar:
% 1. Generar un modelo
% Simplemente comentamos la sección de optimización.
% 2. Añadir observaciones distintas
% En función del modelo jugamos con cambiar algún signo.
% 3. Estudiar el número de modificaciones necesarias.
% 4. Es interesante escoger un subconjunto del modelo y ver si hay varias soluciones
% Para ello debemos imponer un solo resultado por vertice.

:- signo(S), opuesto(S,T), vertice(V),
resultado(V,S), resultado(V,T).
</source>

Aplicaciones y casos de estudio (19-20)

2020-02-12T12:11:01Z

Mjoseh:

Nuricabe (Alina Kasiuk y Xinyi Wu)

2020-02-09T20:26:12Z

Mjoseh: Página creada con «<source lang = "prolog"> % according to the known conditions numbered(1,1,1). numbered(1,5,1). numbered(1,7,6). numbered(2,3,2). numbered(3,2,1). numbered(3,5,2). numbered(…»

<source lang = "prolog">
% according to the known conditions
numbered(1,1,1).
numbered(1,5,1).
numbered(1,7,6).
numbered(2,3,2).
numbered(3,2,1).
numbered(3,5,2).
numbered(5,1,2).
numbered(5,4,1).
numbered(7,2,3).
numbered(7,6,1).

#const n=7.
#const m=7.

col(1..n).
row(1..m).
color(b;w).

% Keep some cells white (and paint the rest black)
{cell(w,X,Y)}1 :- row(X), col(Y).
cell(b,X,Y) :- not cell(w,X,Y), row(X), col(Y).

% ensuring that the given constraints N1--N8 are satisfied:

% N1: Numbered cells remain white.
:- not cell(w,X,Y), numbered(X,Y,N).

% N5 : every white cell is orthogonally connected.
% N7 : All black cells should be connected orthogonally.
adj(C,R,C1,R1) :- row(C), row(C1), col(R), col(R1), |C-C1| + |R-R1| == 1.
connected(C,X,Y,X,Y) :- cell(C,X,Y), row(X), col(Y), color(C).
connected(C,X,Y,U,V) :- connected(C,X,Y,W,Z), adj(W,Z,U,V),
cell(C,U,V),row(X;U;W), col(Y;V;Z), color(C).

w_connected(X,Y) :- connected(w,X,Y,U,V),cell(w,X,Y),numbered(U,V,N),
row(X), col(Y).
:- not connected(b,X,Y,U,V), cell(b,X,Y), cell(b,U,V),
row(X;U),col(Y;V).

% N2 : every white cell belongs to an island.
:- cell(w,X,Y), not w_connected(X,Y), row(X), col(Y).

% N4: Each island should contain the same number of white cells
% as the number it contains.
island(X,Y) :- N {connected(w,X,Y,U,V):row(U),col(V)} N,
numbered(X,Y,N).
:- not island(X,Y), numbered(X,Y,N).

% N3: Each island must contain exactly exactly one number cell,
% N6: The island can not be connected.
:- numbered(X,Y,N), numbered(U,V,M), X<U, connected(w,X,Y,U,V).
:- numbered(X,Y,N), numbered(U,V,M), Y<V, connected(w,X,Y,U,V).
%:- island(X1,Y1), island(X2,Y2), X1 != X2, connected(w,X1,Y1,X2,Y2).
%:- island(X1,Y1), island(X2,Y2), Y1 != Y2, connected(w,X1,Y1,X2,Y2).

% N8: No subset of black cells forms a 2x2 square.
:- sqrBlack(X,Y), row(X), col(Y).
sqrBlack(X,Y) :- cell(b,X+1,Y), cell(b,X,Y),
cell(b,X, Y+1), cell(b,X+1, Y+1), row(X), col(Y).

black(X,Y) :- cell(b,X,Y), row(X), col(Y).
#show black/2.
% #show w_connected/2.

</source>

Heyawake (Alina Kasiuk y Xinyi Wu)

2020-02-09T20:25:24Z

Mjoseh: Página creada con «<source lang = "prolog"> #const n = 10. #const m = 10. #const r = 18. % File: heyawake.lp col(1..m). row(1..n). num(0..r-1). segment(h;v). room_size(N,X1,Y1,X2,Y2) :- room…»

<source lang = "prolog">
#const n = 10.
#const m = 10.
#const r = 18.

% File: heyawake.lp
col(1..m). row(1..n). num(0..r-1). segment(h;v).
room_size(N,X1,Y1,X2,Y2) :- room(A,X1,Y1,X2,Y2), has(A,N).

% H3: In each room containing a cell numbered N (N>0),
% paint N cells black
N {black(C,R):col(C),row(R),C1<=C,C<=C2,R1<=R,R<=R2} N :- room_size(N,C1,R1,C2,R2), N>0.

% H4: Each room without numbered cell contains any number of
% black cells.
{black(C,R):col(C),row(R),C1<=C,C<=C2,R1<=R,R<=R2} :- room_size(-1,C1,R1,C2,R2).

% H1: No two black cells are orthogonally adjacent.
:- adj(C,R,C1,R), black(C,R), black(C1,R), C!=C1.
:- adj(C,R,C,R1), black(C,R), black(C,R1), R!=R1.

adj(C,R,C1,R1) :- col(C), col(C1), row(R), row(R1), |C-C1|+|R-R1|==1.

% H2: Nonadjacent white cells should be interconnected.
:- not connected(C,R,C1,R1), white(C,R), white(C1,R1),
col(C),col(C1), row(R), row(R1), C!=C1, R!=R1.
white(C,R) :- not black(C,R), col(C), row(R).

% connectedness of two white cells (C,R) and (C1,R1)
connected(C,R,C1,R1) :- adj(C,R,C1,R1), white(C,R), white(C1,R1).
connected(C,R,X,Y) :- connected(C1,R1,X,Y), adj(C,R,C1,R1),white(C,R), col(X), row(Y).

% H5: A straight path connecting two white cells (C,R) and (X,Y)
% does not pass through three or more rooms.
:- path(S,C,R,X,Y,3), white(C,R), white(X,Y), col(C), col(X), row(R), row(Y),segment(S).

% horizontal (h) and vertical (v) straight paths of white cells
% whose lengths are at most 3

path(S,C,R,C,R,1) :- white(C,R), col(C), row(R), segment(S).

path(h,C,R,C1,R,N) :- path(h,C+1,R,C1,R,N), adj(C,R,C+1,R),white(C,R), inroom(C,R,A), inroom(C+1,R,A),col(C), col(C1), row(R), num(N), N<3.

path(h,C,R,C1,R,N+1) :- path(h,C+1,R,C1,R,N), adj(C,R,C+1,R), white(C,R), inroom(C,R,A), inroom(C+1,R,B), A!=B, col(C), col(C1), row(R), num(N), N<3.

path(v,C,R,C,R1,N) :- path(v,C,R+1,C,R1,N), adj(C,R,C,R+1),white(C,R), inroom(C,R,A), inroom(C,R+1,A),col(C), row(R), row(R1), num(N), N<3.

path(v,C,R,C,R1,N+1) :- path(v,C,R+1,C,R1,N), adj(C,R,C,R+1),white(C,R),inroom(C,R,A), inroom(C,R+1,B),A!=B, col(C), row(R), row(R1), num(N), N<3.

%path(v,C,R,C,R1,N) :- path(v,C,R1,C,R,N).
%path(h,C,R,C1,R,N) :- path(h,C1,R,C,R,N).

% inroom(X,Y,A): grid cell (X,) is contained in Room A
inroom(X,Y,A) :- room(A,C,R,C1,R1), X<=C1, C<=X, Y<=R1, R<=Y,col(C), col(C1), col(X), row(Y), row(R1), row(R).

%The input file
room(0,1,1,2,2).room(1,1,3,2,5).room(2,1,6,2,8).room(3,1,9,2,10).
room(4,3,1,5,2).room(5,3,3,5,5).room(6,3,6,3,8).room(7,4,6,5,8).room(8,3,9,5,10).
room(9,6,1,8,2).room(10,6,3,7,5).room(11,8,3,8,5).room(12,6,6,8,8).room(13,6,9,8,10).
room(14,9,1,10,2).room(15,9,3,10,5).room(16,9,6,10,8).room(17,9,9,10,10).

has(0,-1).has(1,-1).has(2,-1).has(3,0).
has(4,-1).has(5,5).has(6,-1).has(7,0).has(8,1).
has(9,1).has(10,2).has(11,-1).has(12,2).has(13,-1).
has(14,0).has(15,-1).has(16,1).has(17,-1).

%room(0,1,1,2,2).room(1,1,3,2,5).room(2,6,1,8,2).room(3,3,4,5,5).
%room(4,3,1,5,2).room(5,3,3,5,3).room(6,6,3,8,5).room(7,3,6,5,8).
%room(8,6,6,8,7).room(9,1,6,2,8).room(10,6,8,8,8).room(13,9,6,10,8).
%room(11,9,1,10,2).room(12,9,3,10,5).room(14,9,9,10,10).
%room(17,1,9,2,10).room(16,3,9,5,10).room(15,6,9,8,10).
%has(0,0).has(1,1).has(2,1).has(3,2).has(4,-1).has(5,-1).has(6,2).
%has(7,5).has(8,0).has(9,-1).has(10,-1).has(11,-1).has(12,-1).
%has(13,1).has(14,0).has(15,-1).has(16,-1).has(17,-1).

#show black/2.
</source>

Aplicaciones y casos de estudio (19-20)

2020-02-09T20:24:39Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos (Ana Bermudo y Gema Terrón)([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* Grid puzzles
** [[Masyu (Jan Wasilewski)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf pdf]).
** [[Heyawake (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).
** [[Nuricabe (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).

Masyu (Jan Wasilewski)

2020-02-09T20:24:02Z

Mjoseh: Página creada con «<source lang = "prolog"> %white(1,3). %white(2,3). %white(4,1). %white(5,3). %black(4,2). white(1,3). black(1,6). black(3,1). black(3,4). white(3,5). black(3,8). white(3,1…»

<source lang = "prolog">
%white(1,3).
%white(2,3).
%white(4,1).
%white(5,3).
%black(4,2).

white(1,3). black(1,6). black(3,1). black(3,4). white(3,5).
black(3,8). white(3,10). white(4,7). black(5,3). black(5,8).
white(5,9). white(5,10). white(6,6). white(7,2). white(7,4).
white(7,7). white(7,8). white(8,2). white(8,5). black(9,9).
black(10,1). white(10,3). white(10,6).

#const n = 10.
#const m = 10.
col(1..n). row(1..m). direction(v;h).
ball(X,Y) :- black(X,Y), col(X), row(Y).
ball(X,Y) :- white(X,Y), col(X), row(Y).

% Generate a set of unit segments passing through cells

{line(S,X,Y)} :- direction(S), col(X), row(Y).
:- line(h,n,Y), row(Y).
:- line(v,X,m), col(X).

% including balls:

:- ball(X,Y), not on(X,Y).
on(X,Y) :- line(S,X,Y), direction(S), col(X), row(Y).
on(X+1,Y) :- line(h,X,Y), col(X), row(Y), X<n.
on(X,Y+1) :- line(v,X,Y), col(X), row(Y), Y<m.

% ensuring the constraints M1--M3 are satisfied:
% M1:
% Every cell that the generated line passes through is
% connected to exactly 2 such grid cells:

:- 3 {line(h,X-1,Y); line(h,X,Y); line(v,X,Y); line(v,X,Y-1)}, on(X,Y), col(X), row(Y).
:- {line(h,X-1,Y); line(h,X,Y); line(v,X,Y); line(v,X,Y-1)} 1, on(X,Y), col(X), row(Y).

% Furthermore, every cell on the generated line is reachable
% from other grid cells on the line:

:- on(X,Y), on(Z,W), not reachable(X,Y,Z,W), col(X;Z), row(Y;W).
adj(X,Y,X,Y+1) :- line(v,X,Y), col(X), row(Y), Y<m.
adj(X,Y,X+1,Y) :- line(h,X,Y), col(X), row(Y), X<n.
adj(X,Y,Z,W) :- adj(Z,W,X,Y), col(X;Z), row(Y;W).
reachable(X,Y,X,Y) :- on(X,Y), col(X;Z), row(Y;W).
reachable(X,Y,Z,W) :- reachable(I,J,Z,W), adj(X,Y,I,J), col(X;I;Z), row(Y;J;W).

% M3:
% The loop must turn (90 degrees) at black circles

:- black(X,Y), line(h,X,Y), line(h,X-1,Y), col(X), row(Y).
:- black(X,Y), line(v,X,Y), line(v,X,Y-1), col(X), row(Y).

% but it must travel straight through the next and previous
% cells in its path.

:- 1{line(v,X+1,Y); line(v,X+1,Y-1)}, black(X,Y), line(h,X,Y), col(X), row(Y).
:- 1{line(v,X-1,Y); line(v,X-1,Y-1)}, black(X,Y), line(h,X-1,Y), col(X),row(Y).
:- 1{line(h,X,Y+1); line(h,X-1,Y+1)}, black(X,Y), line(v,X,Y), col(X), row(Y).
:- 1{line(h,X,Y-1); line(h,X-1,Y-1)}, black(X,Y), line(v,X,Y-1), col(X), row(Y).

% M2:
% White circles must be traveled straight through

:- 1{line(v,X,Y); line(v,X,Y-1)}, 1{line(h,X,Y); line(h,X-1,Y)}, white(X,Y), col(X), row(Y).

% but the loop must turn (90 degrees) in the previous
% and/or next cell in its path.

:- white(X,Y), line(h,X,Y), line(h,X+1,Y), line(h,X-1,Y), line(h,X-2,Y), col(X), row(Y).
:- white(X,Y), line(v,X,Y), line(v,X,Y+1), line(v,X,Y-1), line(v,X,Y-2), col(X), row(Y).

#show on/2.

</source>

Aplicaciones y casos de estudio (19-20)

2020-02-09T20:22:57Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* Grid puzzles
** [[Masyu (Jan Wasilewski)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf pdf]).
** [[Heyawake (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).
** [[Nuricabe (Alina Kasiuk y Xinyi Wu)]] ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf pdf]).

Aplicaciones y casos de estudio (19-20)

2020-02-09T20:20:23Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* Grid puzzles
** [[Masyu (Jan Wasilewski)]]([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf Masyu]).
** ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf Heyawake y Nuricabe]).

Aplicaciones y casos de estudio (19-20)

2020-02-09T20:18:19Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* [[Grid puzzles]]: Grid puzzles
** ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf Masyu]).
** ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf Heyawake y Nuricabe]).

Grid puzzles

2020-02-09T20:17:36Z

Mjoseh:

En estas aplicaciones se estudian tres ejemplos de cómo usar ASP para resolver rompecabezas de cuadrícula (grid puzzles)

* [[Masyu (Jan Wasilewski)]]
* [[Nuricabe (Alina Kasiuk y Xinyu Wu)]]
* [[Heyawake (Alina Kasiuk y Xinyu Wu)]]

Grid puzzles

2020-02-09T20:15:56Z

Mjoseh: Página creada con «En estas aplicaciones se estudian tres ejemplos de cómo usar ASP para resolver rompecabezas de cuadrícula (grid puzzles) * Masyu * Nuricabe * Heyawake»

En estas aplicaciones se estudian tres ejemplos de cómo usar ASP para resolver rompecabezas de cuadrícula (grid puzzles)

* [[Masyu]]
* [[Nuricabe]]
* [[Heyawake]]

Aplicaciones y casos de estudio (19-20)

2020-02-09T20:13:14Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/PresentaciónLaberintos.pdf pdf]) .
* [[Grid puzzles]]: Grid puzzles
** ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Presentacion-masayu.pdf Masyu]).
** ([http://www.cs.us.es/~mjoseh/cursos/lcytm-19/aplicaciones/Solving-Challenging-Grid-Puzzles.pdf Heyawake y Nurikabe]).

Aplicaciones y casos de estudio (19-20)

2020-02-03T08:02:22Z

Mjoseh:

Ejemplo 1

2020-02-03T07:57:48Z

Mjoseh:

<source lang = "prolog">
% Definimos las dimensiones del tablero:
#const n = 5.
dim(1..n).

% Para cada casilla distinta a (1,1) le asignamos un solo parent: izquierda,
% derecha, arriba o abajo.
1 {parent(X,Y, 0,-1); parent(X,Y, 1,0);
parent(X,Y, -1,0); parent(X,Y, 0,1)} 1 :- dim(X), dim(Y), (X,Y) != (1,1).

% Definimos la propiedad alcanzable. Esta se cumple trivialmente en la casilla
% (1,1), y cualquier casilla desde la cual se haga un movimiento a una casilla
% alcanzable también será alcanzable:
alcanzable(1,1).
alcanzable(X,Y) :- parent(X,Y,DX,DY), alcanzable(X+DX,Y+DY).

% La raíz del árbol debe ser alcanzable desde cualquier casilla.
:- dim(X), dim(Y), not alcanzable(X,Y).

% Minimizamos el número de movimientos verticales:
vertical(X,Y) :- parent(X,Y,0,1).
vertical(X,Y) :- parent(X,Y,0,-1).
#minimize {X,Y: vertical(X,Y) }.

% Presentación:
#show parent/4.

</source>

Ejemplo 2

2020-02-03T07:57:08Z

Mjoseh:

<source lang = "prolog">
% El objetivo será diseñar un nivel de juego en el que el jugador
% empieza en la casilla de arriba y a la izquierdada del tablero, encuentra
% una gema en el muro de la mazmorra, la lleva a un altar central donde
% mágicamente desbloquea la salida, y luego va hasta la salida, situada
% abajo y a la derecha.

#const n=10.
param("n",n).

dim(1..n).

% Definimos las casillas, a partir de la dimensión de nuestro tablero.
casilla((X,Y)) :- dim(X),dim(Y).

% Dos casillas son consecutivas o adyacentes si |X1-X2| + |Y1-Y2| == 1.
adyacente((X1,Y1),(X2,Y2)):- casilla((X1,Y1)), casilla((X2,Y2)),
X1-X2 == 1, Y1-Y2 == 0.
adyacente((X1,Y1),(X2,Y2)):- casilla((X1,Y1)), casilla((X2,Y2)),
X2-X1 == 1, Y1-Y2 == 0.
adyacente((X1,Y1),(X2,Y2)):- casilla((X1,Y1)), casilla((X2,Y2)),
X1-X2 == 0, Y1-Y2 == 1.
adyacente((X1,Y1),(X2,Y2)):- casilla((X1,Y1)), casilla((X2,Y2)),
X2-X1 == 0, Y2-Y1 == 1.

% La entrada al laberinto es la casilla (1,1), y la salida es la opuesta en
% el tablero.
salida((1,1)).
llegada((n,n)).

% Las casillas tienen a lo sumo una marca:
0 { marca(T,pared); marca(T,gema); marca(T,altar) } 1 :- casilla(T).

% Hay exactamente un altar y una gema en todo el laberinto:
:- not 1 {marca(T,altar)} 1.
:- not 1 {marca(T,gema)} 1.

% Para obtener una mazmorra interesante debe de haber muchas paredes.
% Por tanto, al menos la mitad de las casillas deben ser paredes:
:- not ((n*n)/2) {marca(T,pared)}.

% Un altar debe tener alrededor algunas casillas en blanco.
% Luego, un altar no puede tener paredes circundantes a menos de dos casillas.
0 {marca(T3,pared): adyacente(T1,T2), adyacente(T2,T3)} 0 :- marca(T1,altar).

% Los altares no pueden estar en el borde del mapa. Para ello imponemos que
% tenga 4 casillas adyacentes:
:- marca(T1,altar), not 4 {adyacente(T1,T2)}.

% Las gemas deben estar adheridas a las paredes circundantes.
3 {marca(T2,pared): adyacente(T1,T2)} :- marca(T1,gema).

% Una pared empieza a tener aspecto de muro cuando va seguido de otras
% paredes. Luego imponemos que toda pared tenga al menos dos paredes
% vecinos:
2 {marca(T2,pared): adyacente(T1,T2)} :- marca(T1,pared).

% Presentación:
#show marca/2.

% Vemos que efectivamente, la gema aparece rodeada de muchos bloques.
% Pero no tenemos que olvidar que el nivel debe ser jugable.

% REPRESENTACIÓN DEL ESPACIO DE SOLUCIONES VÁLIDAS:

% Para ello vamos a definir tres estados:
% Estado 1: inicial
% Estado 2: después de coger la gema
% Estado 3: después de llevar la gema al altar

% Comenzamos pues en el estado 1.
% El predicado sobre describe sobre que marca (o casilla blanca) se espera
% que el jugador esté en cada etapa para pasarse el nivel.
% En el estado 1, el jugador empieza en la casilla de inicio:
sobre(T,1) :- salida(T).

% Además, si estamos sobre una casilla, el jugador debe poder pasar a estar
% sobre otra casilla adyacente a esta sin cambiar de estado. Si el jugador
% está sobre la marca de una gema o altar, entonces puede cambiar al siguiente
% estado.
{ sobre(T2,2) : adyacente(T1,T2) } :- sobre(T1,1), marca(T1,gema).
{ sobre(T2,3) : adyacente(T1,T2) } :- sobre(T1,2), marca(T1,altar).
{ sobre(T2,S) : adyacente(T1,T2) } :- sobre(T1,S).

% El jugador no puede estar nunca sobre la marca de una pared.
:- marca(T,pared), sobre(T,S).

% La casilla final debe tocarse en la etapa 3. Luego el predicado completo
% se verifica solo si se está sobre la casilla en la que hay que acabar y
% y estamos en la etapa 3.
completo :- llegada(T), sobre(T,3).
:- not completo.

% Finalmente, vamos a imponer que si se cumplen las restricciones de las marcas,
% entonces es seguro que toda solución debe pasar por al menos n casillas,
% siendo n la anchura del tablero:
__level_design(marca(T,Nombre)) :- marca(T,Nombre).
__concept :- n { sobre(T,1) },
n { sobre(T,2) },
n { sobre(T,3) }.

</source>

Ejemplo 1

2020-02-03T07:56:11Z

Mjoseh:

Aplicaciones y casos de estudio (19-20)

2020-02-03T07:55:26Z

Mjoseh:

En esta sección se publican loas aplicaciones y casos de estudio presentadas por los alumnos en la asignatura.

* [[Laberintos]]: Laberintos.

Ejercicio P2

2020-01-20T08:59:44Z

Mjoseh: Página creada con «<source lang = "prolog"> % Ejercicio de planificación: los siguientes predicados describen un % "mundo" que representa la acciones de un camión que transporta % paquete…»

<source lang = "prolog">

% Ejercicio de planificación: los siguientes predicados describen un
% "mundo" que representa la acciones de un camión que transporta
% paquetes entre ciudades:

% paquete(X): el objeto X es un paquete.

% ciudad(X): el objeto X es una ciudad.

% autovia(C1,C2): las ciudades C1 y C2 están conectadas por autovía.

% en(X,C): el elemento x (el camión o un paquete) está en la ciudad C.

% dentroCamion(X): el paquete X está cargado en el camión.

% descargado: el camión está descargado.

% Las acciones que se pueden realizar son las siguientes:

% cargar(P,C): el camión (que debe estar descargado) carga el paquete P
% en la ciudad C. Una vez cargado, el paquete ya no se
% considera que esté en la ciudad C.

% descargar(P,C): el camión descarga el paquete P en la ciudad C.

% ir(C1,C2): el camión se desplaza por autovía desde la ciudad C1 a la
% ciudad C2.

% Supongamos que deseamos encontrar la secuencia de acciones que a
% partir de un estado inicial en el que un paquete p1 está en Barcelona,
% un paquete p2 está en Madrid, y el camión está en Sevilla, deja
% finalmente el paquete p1 en Sevilla, el paquete p2 en Barcelona y el
% camión descargado. Supondremos que existe una autovía entre Barcelona
% y Madrid y otra entre Madrid y Sevilla.

%% ----------
%% Signatura:
%% ----------

%% ----------
%% Estáticos:
%% ----------

%% ----------
%% Fluyentes:
%% ----------

%% ---------
%% Acciones:
%% ---------

%%----------------------------------------
%% Codificación del sistema de descripción:
%%----------------------------------------

%% Hipótesis del mundo cerrado para fluyentes definidos:

-cierto(F,I) :- fluyente(definido,F), paso(I),
not cierto(F,I).

%% Axioma de inercia para fluyentes inerciales:

cierto(F,I+1) :- fluyente(inercia,F),
cierto(F,I),
not -cierto(F,I+1),
I < n.

-cierto(F,I+1) :- fluyente(inercia,F),
-cierto(F,I),
not cierto(F,I+1),
I < n.

%% Hipótesis del mundo cerrado para acciones:

-ocurre(A,I) :- accion(A), paso(I),
not ocurre(A,I).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Módulo de planificación usando regla de elección:

exito :- objetivo(I),
I <= n.
:- not exito.

1{ocurre(A,I): accion(A)}1 :- paso(I),
not objetivo(I),
I < n.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Estado inicial

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Objetivo:

%% Presentación:
#show ocurre/2.
</source>

Planificación: transporte

2020-01-20T08:59:20Z

Mjoseh: Protegió «Planificación: transporte» ([Editar=Solo administradores] (indefinido) [Trasladar=Solo administradores] (indefinido))

Planificación: transporte

2020-01-20T08:59:11Z

Ejercicios (19-20)

2020-01-20T08:58:36Z

Mjoseh:

En esta sección se publicarán las relaciones de ejercicios que se escribirán de forma colaborativa por los alumnos del curso y no deben tomarse como definitivas.

* '''Relación 1''': ([[R1 |Enunciado]], [[Relación 1 |Solución colaborativa]]).
* '''Ejercicio P1''': ([[Planificación: compra |Enunciado]], [[Ejercicio P1 |Solución colaborativa]]).
* '''Ejercicio P2''': ([[Planificación: transporte |Enunciado]], [[Ejercicio P2 |Solución colaborativa]]).

Ejercicios (19-20)

2020-01-20T08:57:15Z

Mjoseh:

En esta sección se publicarán las relaciones de ejercicios que se escribirán de forma colaborativa por los alumnos del curso y no deben tomarse como definitivas.

* '''Relación 1''': ([[R1 |Enunciado]], [[Relación 1 |Solución colaborativa]]).
* '''Ejercicio P1''': ([[Planificación: compra |Enunciado]], [[Ejercicio P1 |Solución colaborativa]]).
* '''Ejercicio P2''': Planificación: transporte ([[Media: transporte.lp|Enunciado]], [[Ejercicio P2 |Solución colaborativa]]).

Ejercicio P1

2020-01-20T08:53:27Z

Mjoseh: Página creada con «<source lang = "prolog"> %% Ejercicio de planificación: los siguientes predicados describen un %% "mundo" que representa la acciones de una persona que compra %% aliment…»

<source lang = "prolog">

%% Ejercicio de planificación: los siguientes predicados describen un
%% "mundo" que representa la acciones de una persona que compra
%% alimentos en supermercados.

%% Consideremos el problema de planificación siguiente:
%% Contexto:
%% (*) Tiendas: Mercadona vende café y Carrefour vende azúcar.
%% (*) Una persona está en una ubicación, que puede ser su casa o una tienda.
%% (*) Las acciones posibles son: ir, comprar.
%% (*) Estado inicial: está en su casa, sin café ni azúcar.
%% (*) Objetivo: tener café, azúcar y estar en casa.

%% ----------
%% Signatura:
%% ----------

%% ----------
%% Estáticos:
%% ----------

%% ----------
%% Fluyentes:
%% ----------

%% ---------
%% Acciones:
%% ---------

%%----------------------------------------
%% Codificación del sistema de descripción:
%%----------------------------------------

%% Hipótesis del mundo cerrado para fluyentes definidos:

-cierto(F,I) :- fluyente(definido,F), paso(I),
not cierto(F,I).

%% Axioma de inercia para fluyentes inerciales:

cierto(F,I+1) :- fluyente(inercia,F),
cierto(F,I),
not -cierto(F,I+1),
I < n.

-cierto(F,I+1) :- fluyente(inercia,F),
-cierto(F,I),
not cierto(F,I+1),
I < n.

%% Hipótesis del mundo cerrado para acciones:

-ocurre(A,I) :- accion(A), paso(I),
not ocurre(A,I).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Módulo de planificación usando regla de elección:

exito :- objetivo(I),
I <= n.
:- not exito.

1{ocurre(A,I): accion(A)}1 :- paso(I),
not objetivo(I),
I < n.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Estado inicial

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Objetivo:

%% Presentación:
#show ocurre/2.
</source>

Planificación: compra

2020-01-20T08:49:57Z

Mjoseh: Protegió «Planificación: compra» ([Editar=Solo administradores] (indefinido) [Trasladar=Solo administradores] (indefinido))

<source lang ="prolog">

%% Ejercicio de planificación: los siguientes predicados describen un
%% "mundo" que representa la acciones de una persona que compra
%% alimentos en supermercados.

%% Consideremos el problema de planificación siguiente:
%% Contexto:
%% (*) Tiendas: Mercadona vende café y Carrefour vende azúcar.
%% (*) Una persona está en una ubicación, que puede ser su casa o una tienda.
%% (*) Las acciones posibles son: ir, comprar.
%% (*) Estado inicial: está en su casa, sin café ni azúcar.
%% (*) Objetivo: tener café, azúcar y estar en casa.

%% ----------
%% Signatura:
%% ----------

%% ----------
%% Estáticos:
%% ----------

%% ----------
%% Fluyentes:
%% ----------

%% ---------
%% Acciones:
%% ---------

%%----------------------------------------
%% Codificación del sistema de descripción:
%%----------------------------------------

%% Hipótesis del mundo cerrado para fluyentes definidos:

-cierto(F,I) :- fluyente(definido,F), paso(I),
not cierto(F,I).

%% Axioma de inercia para fluyentes inerciales:

cierto(F,I+1) :- fluyente(inercia,F),
cierto(F,I),
not -cierto(F,I+1),
I < n.

-cierto(F,I+1) :- fluyente(inercia,F),
-cierto(F,I),
not cierto(F,I+1),
I < n.

%% Hipótesis del mundo cerrado para acciones:

-ocurre(A,I) :- accion(A), paso(I),
not ocurre(A,I).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Módulo de planificación usando regla de elección:

exito :- objetivo(I),
I <= n.
:- not exito.

1{ocurre(A,I): accion(A)}1 :- paso(I),
not objetivo(I),
I < n.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Estado inicial

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Objetivo:

%% Presentación:
#show ocurre/2.

</source>

Planificación: compra

2020-01-20T08:49:26Z

Mjoseh: Página creada con «<source lang ="prolog"> %% Ejercicio de planificación: los siguientes predicados describen un %% "mundo" que representa la acciones de una persona que compra %% alimento…»

<source lang ="prolog">

%% Ejercicio de planificación: los siguientes predicados describen un
%% "mundo" que representa la acciones de una persona que compra
%% alimentos en supermercados.

%% Consideremos el problema de planificación siguiente:
%% Contexto:
%% (*) Tiendas: Mercadona vende café y Carrefour vende azúcar.
%% (*) Una persona está en una ubicación, que puede ser su casa o una tienda.
%% (*) Las acciones posibles son: ir, comprar.
%% (*) Estado inicial: está en su casa, sin café ni azúcar.
%% (*) Objetivo: tener café, azúcar y estar en casa.

%% ----------
%% Signatura:
%% ----------

%% ----------
%% Estáticos:
%% ----------

%% ----------
%% Fluyentes:
%% ----------

%% ---------
%% Acciones:
%% ---------

%%----------------------------------------
%% Codificación del sistema de descripción:
%%----------------------------------------

%% Hipótesis del mundo cerrado para fluyentes definidos:

-cierto(F,I) :- fluyente(definido,F), paso(I),
not cierto(F,I).

%% Axioma de inercia para fluyentes inerciales:

cierto(F,I+1) :- fluyente(inercia,F),
cierto(F,I),
not -cierto(F,I+1),
I < n.

-cierto(F,I+1) :- fluyente(inercia,F),
-cierto(F,I),
not cierto(F,I+1),
I < n.

%% Hipótesis del mundo cerrado para acciones:

-ocurre(A,I) :- accion(A), paso(I),
not ocurre(A,I).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Módulo de planificación usando regla de elección:

exito :- objetivo(I),
I <= n.
:- not exito.

1{ocurre(A,I): accion(A)}1 :- paso(I),
not objetivo(I),
I < n.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Estado inicial

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Objetivo:

%% Presentación:
#show ocurre/2.

</source>

Ejercicios (19-20)

2020-01-20T08:48:22Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2020-01-20T08:45:18Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

Lógica computacional y teoría de modelos (2019-20)

2020-01-20T08:44:35Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios]]: Relaciones de ejercicios.

Lógica computacional y teoría de modelos (2019-20)

2020-01-07T11:37:17Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2020-01-07T11:36:57Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios]]: Relaciones de ejercicios.

Lógica computacional y teoría de modelos (2019-20)

2020-01-07T11:35:51Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2020-01-07T11:35:17Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios evaluables]]: Ejercicios evaluables.

Lógica computacional y teoría de modelos (2019-20)

2020-01-04T12:41:38Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2020-01-04T12:38:44Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Aplicaciones y casos de estudio]]: Aplicaciones y casos de estudio presentados en clase.

Lógica computacional y teoría de modelos (2019-20)

2019-12-18T10:12:18Z

Mjoseh:

Ejercicios evaluables 3

2019-12-18T10:11:39Z

Mjoseh:

La tercera relación de ejercicios evaluables consiste en la realización de los ejercicios siguientes, mediante "Answer Set programming", usando el sistama clingo. Se enviará a mjoseh@us.es y acordon@us.es antes del viernes 24 de enero de 2020 un fichero usuario_3.zip con los ficheros de los programas.

*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ProblemaViajante/viajante.lp Problema del viajante.]
** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ProblemaViajante/instanciaViajante_1.lp Instancia.]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/SurvoPuzzle/SurvoPuzzle.lp SurvoPuzzle.]
** Instancias:
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/SurvoPuzzle/SurvoPuzzle_inst_1.lp Instancia 1.]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/SurvoPuzzle/SurvoPuzzle_inst_2.lp Instancia 2.]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/SurvoPuzzle/SurvoPuzzle_inst_3.lp Instancia 3.]

Ejercicios evaluables (19-20)

2019-12-18T10:10:33Z

Mjoseh:

En esta sección se publicarán las relaciones de ejercicios que constituyen la evaluación de la asignatura.

* [[Ejercicios evaluables 1]]: Relación 1 de ejercicios evaluables.
* [[Ejercicios evaluables 2]]: Relación 2 de ejercicios evaluables.
* [[Ejercicios evaluables 3]]: Relación 3 de ejercicios evaluables.

Lógica computacional y teoría de modelos (2019-20)

2019-12-18T10:10:03Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios evaluables]]: Ejercicios evaluables.

Lógica computacional y teoría de modelos (2019-20)

2019-12-10T10:23:34Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2019-12-10T10:22:52Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios evaluables]]: Ejercicios evaluables.

Ejercicios evaluables 2

2019-12-10T10:22:30Z

Mjoseh:

La segunda relación de ejercicios evaluables consiste en la realización de los
ejercicios siguientes, mediante "Answer Set programming", usando el
sistama clingo. Se enviará a mjoseh@us.es y acordon@us.es antes del
viernes 20 de diciembre de 2019 un fichero usuario_2.zip con los ficheros
de los programas.

*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Ejercicio_5_4/Ej_5_4.lp Ejercicio 1.]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Ejercicio_5_5/Ej_5_5.lp Ejercicio 2.]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Ejercicio_5_9/Ej_5_9.lp Ejercicio 3.]

Lógica computacional y teoría de modelos (2019-20)

2019-12-10T10:20:57Z

Mjoseh:

Ejercicios evaluables (19-20)

2019-12-10T10:20:10Z

Mjoseh:

Lógica computacional y teoría de modelos (2019-20)

2019-12-10T10:19:23Z

Mjoseh:

Esta es la página principal de la asignatura "Lógica computacional y teoría de modelos" del [https://matematicas.us.es/en/titulaciones/master-u-matematicas Máster Universitario en Matemáticas] de la [http://www.us.es Universidad de Sevilla].

== Material para el curso ==
* [[Temas]]: Temas.
* [[Ejercicios (19-20)]]: Relaciones de ejercicios.
* [[Ejercicios evaluables (19-20)]]: Ejercicios evaluables.
* [[Aplicaciones y casos de estudio (19-20)]]: Aplicaciones y casos de estudio presentados en clase.
* [[Documentación]]: Cursos y libros recomendados.
* [[Sistemas]]: Sistemas utilizados.

* [[Ejercicios evaluables]]: Ejercicios evaluables.

Ejercicios evaluables 1

2019-11-18T08:55:15Z

Mjoseh:

La primera relación de ejercicios evaluables consiste en la realización de los
ejercicios siguientes, mediante "Answer Set programming", usando el
sistama clingo. Se enviará a mjoseh@us.es y acordon@us.es antes del
domingo 11 de diciembre de 2019 un fichero usuario_1.zip con los ficheros
de los programas y las instancias.

*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Agata/Agata.lp Who killed aunt Agata?.]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3.lp Coloreado de un grafo.]
** Instancias:
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_1.lp Ejemplo 1]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_2.lp Ejemplo 2]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_3.lp Ejemplo 3]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Reinas/n-reinas.lp Problema de las n reinas.]

Ejercicios evaluables 1

2019-11-17T18:43:13Z

Mjoseh:

La primera relación de ejercicios evaluables consiste en la realización de los
ejercicios siguientes, mediante "Answer Set programming", usando el
sistama clingo. Se enviará a mjoseh@us.es y acordon@us.es antes del
domingo 15 de diciembre de 2019 un fichero usuario_1.zip con los ficheros
de los programas y las instancias.

*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Agata/Agata.lp Who killed aunt Agata?.]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3.lp Coloreado de un grafo.]
** Instancias:
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_1.lp Ejemplo 1]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_2.lp Ejemplo 2]
*** [http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/ColoreadoGrafo/coloreadoGrafo_3_inst_3.lp Ejemplo 3]
*[http://www.cs.us.es/~mjoseh/cursos/LibroGelfond/Ejercicios_evaluables/Reinas/n-reinas.lp Problema de las n reinas.]